1libpldm_dep = dependency(
2    'libpldm',
3    default_options: ['oem-ibm=enabled'],
4)
5
6nlohmann_json_dep = dependency('nlohmann_json', include_type: 'system')
7
8python_inst = import('python').find_installation('python3')
9python_ver = python_inst.language_version()
10python_dep = python_inst.dependency()
11
12if cpp.has_header('CLI/CLI.hpp')
13    CLI11_dep = declare_dependency()
14else
15    CLI11_dep = dependency('CLI11')
16endif
17
18extra_sources = []
19extra_dependencies = []
20extra_args = []
21
22build_phal = get_option('phal').allowed()
23
24if build_phal
25    extra_sources += [
26        'sbe_ffdc_handler.cpp',
27        'fapi_data_process.cpp',
28        'phal_service_actions.cpp',
29    ]
30    extra_dependencies += [
31        dependency('libdt-api'),
32        cpp.find_library('pdbg'),
33        cpp.find_library('ekb'),
34        cpp.find_library('phal'),
35    ]
36    extra_args += [
37        '-DPEL_ENABLE_PHAL',
38    ]
39    log_manager_ext_args += [
40        '-DPEL_ENABLE_PHAL',
41    ]
42endif
43
44libpel_sources = files(
45    'ascii_string.cpp',
46    'bcd_time.cpp',
47    'callout.cpp',
48    'callouts.cpp',
49    'data_interface.cpp',
50    'device_callouts.cpp',
51    'extended_user_header.cpp',
52    'failing_mtms.cpp',
53    'fru_identity.cpp',
54    'generic.cpp',
55    'journal.cpp',
56    'json_utils.cpp',
57    'log_id.cpp',
58    'mru.cpp',
59    'mtms.cpp',
60    'pce_identity.cpp',
61    'pel.cpp',
62    'pel_rules.cpp',
63    'pel_values.cpp',
64    'private_header.cpp',
65    'registry.cpp',
66    'section_factory.cpp',
67    'service_indicators.cpp',
68    'severity.cpp',
69    'user_header.cpp',
70    'temporary_file.cpp',
71    extra_sources,
72)
73
74libpel_deps = [
75    conf_h_dep,
76    libpldm_dep,
77    nlohmann_json_dep,
78    sdbusplus_dep,
79    sdeventplus_dep,
80    pdi_dep,
81    phosphor_logging_dep,
82    extra_dependencies,
83]
84
85libpel_lib = static_library(
86    'pel',
87    libpel_sources,
88    'paths.cpp', # paths is separate because it is overridden during test.
89    include_directories: include_directories('../..', '../../gen'),
90    cpp_args: extra_args,
91    dependencies: [
92        libpel_deps,
93    ]
94)
95
96libpel_dep = declare_dependency(
97    include_directories: include_directories('.'),
98    link_with: libpel_lib,
99    dependencies: [
100        libpldm_dep,
101        nlohmann_json_dep,
102        sdbusplus_dep,
103        sdeventplus_dep,
104        pdi_dep,
105        phosphor_logging_dep,
106    ]
107)
108
109log_manager_ext_deps += [
110    libpel_dep,
111    libpldm_dep,
112    nlohmann_json_dep,
113]
114
115log_manager_ext_sources += files(
116    'entry_points.cpp',
117    'extended_user_data.cpp',
118    'host_notifier.cpp',
119    'manager.cpp',
120    'pel_entry.cpp',
121    'pldm_interface.cpp',
122    'repository.cpp',
123    'src.cpp',
124    'user_data.cpp',
125)
126
127install_data(
128    'registry/message_registry.json',
129    'registry/O_component_ids.json',
130    'registry/B_component_ids.json',
131    install_dir: get_option('datadir') / 'phosphor-logging/pels',
132)
133
134peltool_sources = files(
135    'extended_user_data.cpp',
136    'src.cpp',
137    'user_data.cpp',
138    'user_data_json.cpp',
139)
140
141peltool_deps = [
142    CLI11_dep,
143    conf_h_dep,
144    python_dep,
145]
146
147executable(
148    'peltool',
149    'tools/peltool.cpp',
150    peltool_sources,
151    cpp_args: [ '-DPELTOOL' ],
152    link_args: [ '-lpython' + python_ver ],
153    include_directories: include_directories('../..'),
154    dependencies: [
155        peltool_deps,
156        libpel_dep,
157    ],
158    install: true,
159)
160