1libpldm_dep = dependency(
2    'libpldm',
3    default_options: ['oem-ibm=enabled'],
4)
5
6nlohmann_json_dep = dependency('nlohmann_json', include_type: 'system')
7
8python_inst = import('python').find_installation('python3')
9python_ver = python_inst.language_version()
10python_dep = python_inst.dependency()
11
12if cpp.has_header('CLI/CLI.hpp')
13    CLI11_dep = declare_dependency()
14else
15    CLI11_dep = dependency('CLI11')
16endif
17
18extra_sources = []
19extra_dependencies = []
20extra_args = []
21
22build_phal = get_option('phal').allowed()
23
24if build_phal
25    extra_sources += [
26        'sbe_ffdc_handler.cpp',
27        'fapi_data_process.cpp',
28        'phal_service_actions.cpp',
29    ]
30    extra_dependencies += [
31        dependency('libdt-api'),
32        cpp.find_library('pdbg'),
33        cpp.find_library('ekb'),
34        cpp.find_library('phal'),
35    ]
36    extra_args += [
37        '-DPEL_ENABLE_PHAL',
38    ]
39    log_manager_ext_args += [
40        '-DPEL_ENABLE_PHAL',
41    ]
42endif
43
44libpel_sources = files(
45    'ascii_string.cpp',
46    'bcd_time.cpp',
47    'callout.cpp',
48    'callouts.cpp',
49    'data_interface.cpp',
50    'device_callouts.cpp',
51    'extended_user_header.cpp',
52    'failing_mtms.cpp',
53    'fru_identity.cpp',
54    'generic.cpp',
55    'journal.cpp',
56    'json_utils.cpp',
57    'log_id.cpp',
58    'mru.cpp',
59    'mtms.cpp',
60    'pce_identity.cpp',
61    'pel.cpp',
62    'pel_rules.cpp',
63    'pel_values.cpp',
64    'private_header.cpp',
65    'registry.cpp',
66    'section_factory.cpp',
67    'service_indicators.cpp',
68    'severity.cpp',
69    'user_header.cpp',
70    'temporary_file.cpp',
71    '../../util.cpp',
72    extra_sources,
73)
74
75libpel_deps = [
76    conf_h_dep,
77    libpldm_dep,
78    nlohmann_json_dep,
79    sdbusplus_dep,
80    sdeventplus_dep,
81    pdi_dep,
82    phosphor_logging_dep,
83    extra_dependencies,
84]
85
86libpel_lib = static_library(
87    'pel',
88    libpel_sources,
89    'paths.cpp', # paths is separate because it is overridden during test.
90    include_directories: include_directories('../..', '../../gen'),
91    cpp_args: extra_args,
92    dependencies: [
93        libpel_deps,
94    ]
95)
96
97libpel_dep = declare_dependency(
98    include_directories: include_directories('.'),
99    link_with: libpel_lib,
100    dependencies: [
101        libpldm_dep,
102        nlohmann_json_dep,
103        sdbusplus_dep,
104        sdeventplus_dep,
105        pdi_dep,
106        phosphor_logging_dep,
107    ]
108)
109
110log_manager_ext_deps += [
111    libpel_dep,
112    libpldm_dep,
113    nlohmann_json_dep,
114]
115
116log_manager_ext_sources += files(
117    'entry_points.cpp',
118    'extended_user_data.cpp',
119    'host_notifier.cpp',
120    'manager.cpp',
121    'pel_entry.cpp',
122    'pldm_interface.cpp',
123    'repository.cpp',
124    'src.cpp',
125    'user_data.cpp',
126)
127
128install_data(
129    'registry/message_registry.json',
130    'registry/O_component_ids.json',
131    'registry/B_component_ids.json',
132    install_dir: get_option('datadir') / 'phosphor-logging/pels',
133)
134
135peltool_sources = files(
136    'extended_user_data.cpp',
137    'src.cpp',
138    'user_data.cpp',
139    'user_data_json.cpp',
140)
141
142peltool_deps = [
143    CLI11_dep,
144    conf_h_dep,
145    python_dep,
146]
147
148executable(
149    'peltool',
150    'tools/peltool.cpp',
151    peltool_sources,
152    cpp_args: [ '-DPELTOOL' ],
153    link_args: [ '-lpython' + python_ver ],
154    include_directories: include_directories('../..'),
155    dependencies: [
156        peltool_deps,
157        libpel_dep,
158    ],
159    install: true,
160)
161