1libpldm_dep = dependency(
2    'libpldm',
3    default_options: ['oem-ibm=enabled'],
4)
5
6nlohmann_json_dep = dependency('nlohmann_json', include_type: 'system')
7
8python_inst = import('python').find_installation('python3')
9python_ver = python_inst.language_version()
10python_dep = python_inst.dependency()
11
12if cpp.has_header('CLI/CLI.hpp')
13    CLI11_dep = declare_dependency()
14else
15    CLI11_dep = dependency('CLI11')
16endif
17
18extra_sources = []
19extra_dependencies = []
20extra_args = []
21
22build_phal = get_option('phal').allowed()
23
24if build_phal
25    extra_sources += [
26        'sbe_ffdc_handler.cpp',
27        'fapi_data_process.cpp',
28        'phal_service_actions.cpp',
29    ]
30    extra_dependencies += [
31        dependency('libdt-api'),
32        cpp.find_library('pdbg'),
33        cpp.find_library('ekb'),
34        cpp.find_library('phal'),
35    ]
36    extra_args += [
37        '-DPEL_ENABLE_PHAL',
38    ]
39    log_manager_ext_args += [
40        '-DPEL_ENABLE_PHAL',
41    ]
42endif
43
44libpel_sources = files(
45    'ascii_string.cpp',
46    'bcd_time.cpp',
47    'callout.cpp',
48    'callouts.cpp',
49    'data_interface.cpp',
50    'device_callouts.cpp',
51    'extended_user_header.cpp',
52    'failing_mtms.cpp',
53    'fru_identity.cpp',
54    'generic.cpp',
55    'journal.cpp',
56    'json_utils.cpp',
57    'log_id.cpp',
58    'mru.cpp',
59    'mtms.cpp',
60    'pce_identity.cpp',
61    'pel.cpp',
62    'pel_rules.cpp',
63    'pel_values.cpp',
64    'private_header.cpp',
65    'registry.cpp',
66    'section_factory.cpp',
67    'service_indicators.cpp',
68    'severity.cpp',
69    'user_header.cpp',
70    'temporary_file.cpp',
71    '../../paths.cpp',
72    '../../util.cpp',
73    extra_sources,
74)
75
76libpel_deps = [
77    conf_h_dep,
78    libpldm_dep,
79    nlohmann_json_dep,
80    sdbusplus_dep,
81    sdeventplus_dep,
82    pdi_dep,
83    phosphor_logging_dep,
84    extra_dependencies,
85]
86
87libpel_lib = static_library(
88    'pel',
89    libpel_sources,
90    'pel_paths.cpp', # paths is separate because it is overridden during test.
91    include_directories: include_directories('../..', '../../gen'),
92    cpp_args: extra_args,
93    dependencies: [
94        libpel_deps,
95    ]
96)
97
98libpel_dep = declare_dependency(
99    include_directories: include_directories('.'),
100    link_with: libpel_lib,
101    dependencies: [
102        libpldm_dep,
103        nlohmann_json_dep,
104        sdbusplus_dep,
105        sdeventplus_dep,
106        pdi_dep,
107        phosphor_logging_dep,
108    ]
109)
110
111log_manager_ext_deps += [
112    libpel_dep,
113    libpldm_dep,
114    nlohmann_json_dep,
115]
116
117log_manager_ext_sources += files(
118    'entry_points.cpp',
119    'extended_user_data.cpp',
120    'host_notifier.cpp',
121    'manager.cpp',
122    'pel_entry.cpp',
123    'pldm_interface.cpp',
124    'repository.cpp',
125    'src.cpp',
126    'user_data.cpp',
127)
128
129install_data(
130    'registry/message_registry.json',
131    'registry/O_component_ids.json',
132    'registry/B_component_ids.json',
133    install_dir: get_option('datadir') / 'phosphor-logging/pels',
134)
135
136peltool_sources = files(
137    'extended_user_data.cpp',
138    'src.cpp',
139    'user_data.cpp',
140    'user_data_json.cpp',
141)
142
143peltool_deps = [
144    CLI11_dep,
145    conf_h_dep,
146    python_dep,
147]
148
149executable(
150    'peltool',
151    'tools/peltool.cpp',
152    peltool_sources,
153    cpp_args: [ '-DPELTOOL' ],
154    link_args: [ '-lpython' + python_ver ],
155    include_directories: include_directories('../..'),
156    dependencies: [
157        peltool_deps,
158        libpel_dep,
159    ],
160    install: true,
161)
162