1project(
2  'phosphor-host-ipmid',
3  'cpp',
4  version: '0.1',
5  meson_version: '>=1.1.1',
6  default_options: [
7    'werror=true',
8    'warning_level=3',
9    'cpp_std=c++23',
10  ])
11
12# Setting up config data
13conf_data = configuration_data()
14
15# The name of the callout's forward association
16conf_data.set_quoted('CALLOUT_FWD_ASSOCIATION', 'callout')
17conf_data.set_quoted('BOARD_SENSOR', get_option('board-sensor'))
18conf_data.set_quoted('SYSTEM_SENSOR', get_option('system-sensor'))
19conf_data.set('IPMI_SMS_ATN_ACK_TIMEOUT_SECS', get_option('ipmi-sms-atn-ack-timeout-secs'))
20
21# Soft Power off related.
22if not get_option('softoff').disabled()
23  conf_data.set_quoted('SOFTOFF_BUSNAME', get_option('softoff-busname'))
24  conf_data.set_quoted('SOFTOFF_OBJPATH', get_option('softoff-objpath'))
25  conf_data.set('IPMI_HOST_SHUTDOWN_COMPLETE_TIMEOUT_SECS', get_option('ipmi-host-shutdown-complete-timeout-secs'))
26  conf_data.set_quoted('HOST_INBAND_REQUEST_DIR', get_option('host-inband-request-dir'))
27  conf_data.set_quoted('HOST_INBAND_REQUEST_FILE', get_option('host-inband-request-file'))
28endif
29
30conf_data.set_quoted('CONTROL_HOST_BUSNAME', get_option('control-host-busname'))
31conf_data.set_quoted('CONTROL_HOST_OBJ_MGR', get_option('control-host-obj-mgr'))
32conf_data.set_quoted('HOST_NAME', get_option('host-name'))
33conf_data.set_quoted('POWER_READING_SENSOR', get_option('power-reading-sensor'))
34conf_data.set_quoted('HOST_IPMI_LIB_PATH', get_option('host-ipmi-lib-path'))
35conf_data.set_quoted('FW_VER_REGEX', get_option('fw-ver-regex'))
36
37if get_option('shortname-remove-suffix').enabled()
38  conf_data.set_quoted('SHORTNAME_REMOVE_SUFFIX', '1')
39endif
40if get_option('shortname-replace-words').enabled()
41  conf_data.set_quoted('SHORTNAME_REPLACE_WORDS', '1')
42endif
43if get_option('open-power').allowed()
44  conf_data.set_quoted('OPEN_POWER_SUPPORT', '1')
45endif
46
47matches_map = get_option('matches-map')
48conf_data.set('MAJOR_MATCH_INDEX', matches_map[0])
49conf_data.set('MINOR_MATCH_INDEX', matches_map[1])
50conf_data.set('AUX_0_MATCH_INDEX', matches_map[2])
51conf_data.set('AUX_1_MATCH_INDEX', matches_map[3])
52conf_data.set('AUX_2_MATCH_INDEX', matches_map[4])
53conf_data.set('AUX_3_MATCH_INDEX', matches_map[5])
54
55conf_h = configure_file(
56  output: 'config.h',
57  configuration: conf_data)
58
59root = meson.current_source_dir()
60root_inc = include_directories('.', 'include')
61
62# Project Arguments
63cpp = meson.get_compiler('cpp')
64add_project_arguments(
65  cpp.get_supported_arguments([
66    '-DBOOST_ERROR_CODE_HEADER_ONLY',
67    '-DBOOST_SYSTEM_NO_DEPRECATED',
68    '-DBOOST_COROUTINES_NO_DEPRECATION_WARNING',
69    '-DBOOST_ASIO_DISABLE_THREADS',
70    '-DBOOST_ALL_NO_LIB',
71  ]),
72  language : 'cpp')
73
74if not get_option('get-dbus-active-software').disabled()
75  add_project_arguments(
76    cpp.get_supported_arguments([
77      '-DGET_DBUS_ACTIVE_SOFTWARE',
78    ]),
79    language : 'cpp')
80endif
81
82feature_map = {
83  'boot-flag-safe-mode-support': '-DENABLE_BOOT_FLAG_SAFE_MODE_SUPPORT',
84  'i2c-whitelist-check'        : '-DENABLE_I2C_WHITELIST_CHECK',
85  'update-functional-on-fail'  : '-DUPDATE_FUNCTIONAL_ON_FAIL',
86  'dynamic-sensors'            : '-DFEATURE_DYNAMIC_SENSORS',
87  'dynamic-sensors-write'      : '-DFEATURE_DYNAMIC_SENSORS_WRITE',
88  'entity-manager-decorators'  : '-DUSING_ENTITY_MANAGER_DECORATORS',
89  'hybrid-sensors'             : '-DFEATURE_HYBRID_SENSORS',
90  'sensors-cache'              : '-DFEATURE_SENSORS_CACHE',
91  'dynamic-storages-only'      : '-DFEATURE_DYNAMIC_STORAGES_ONLY',
92}
93
94foreach option_key, option_value : feature_map
95  if(get_option(option_key).enabled())
96    summary(option_key,option_value, section : 'Enabled Features')
97    add_project_arguments(option_value,language:'cpp')
98  endif
99endforeach
100
101add_project_arguments(
102  cpp.get_supported_arguments([
103    '-Wno-psabi',
104    '-Wno-missing-field-initializers',
105    '-Wno-pedantic',
106    '-Wno-non-virtual-dtor'
107  ]),
108  language: 'cpp')
109
110# Dependencies
111phosphor_logging_dep = dependency('phosphor-logging')
112phosphor_dbus_interfaces_dep = dependency('phosphor-dbus-interfaces')
113sdeventplus_dep = dependency('sdeventplus')
114systemd = dependency('systemd')
115crypto = dependency('libcrypto', version : '>=1.0.2g')
116pam = cpp.find_library('pam', required: true)
117mapper = dependency('libmapper')
118boost_coroutine = cpp.find_library('boost_coroutine', required: true)
119sdbusplus_dep = dependency('sdbusplus')
120stdplus_dep = dependency('stdplus')
121
122if cpp.has_header_symbol(
123        'nlohmann/json.hpp',
124        'nlohmann::json::string_t',
125        required:false)
126    nlohmann_json_dep = declare_dependency()
127else
128    nlohmann_json_dep = dependency('nlohmann-json')
129endif
130
131generated_src = []
132
133# Subfolders
134subdir('libipmid')
135subdir('include')
136subdir('user_channel')
137subdir('scripts')
138
139if not get_option('softoff').disabled()
140  subdir('xyz/openbmc_project/Ipmi/Internal/SoftPowerOff')
141  subdir('softoff')
142endif
143
144# whitelist
145if not get_option('ipmi-whitelist').disabled()
146  generate_whitelist_script = files('generate_whitelist_create.sh')
147
148  whitelist_conf = get_option('whitelist-conf')
149  ipmiwhitelist = run_command( \
150    'bash', \
151    generate_whitelist_script, \
152    whitelist_conf)
153
154  whitelist_pre = declare_dependency(
155    include_directories: root_inc,
156    dependencies: [
157      crypto,
158      ipmid_dep,
159      phosphor_dbus_interfaces_dep,
160      phosphor_logging_dep,
161      sdbusplus_dep,
162    ],
163  )
164
165  whitelist_lib = library(
166    'whitelist',
167    'whitelist-filter.cpp',
168    'ipmiwhitelist.cpp',
169    implicit_include_directories: false,
170    dependencies: whitelist_pre,
171    version: meson.project_version(),
172    override_options: ['b_lundef=false'],
173    install: true,
174    install_dir: get_option('libdir') / 'ipmid-providers')
175endif
176
177# libsysintfcmds
178sysintfcmds_pre = declare_dependency(
179  include_directories: root_inc,
180  dependencies: [
181    channellayer_dep,
182    crypto,
183    mapper,
184    nlohmann_json_dep,
185    phosphor_dbus_interfaces_dep,
186    phosphor_logging_dep,
187    sdbusplus_dep,
188    ipmid_dep,
189  ])
190
191sysintfcmds_lib = library(
192  'sysintfcmds',
193  'systemintfcmds.cpp',
194  'host-interface.cpp',
195  implicit_include_directories: false,
196  dependencies: sysintfcmds_pre,
197  version: meson.project_version(),
198  override_options: ['b_lundef=false'],
199  install: true,
200  install_dir: get_option('libdir') / 'ipmid-providers')
201
202# ipmid
203ipmid_pre = [
204  sdbusplus_dep,
205  stdplus_dep,
206  phosphor_logging_dep,
207  phosphor_dbus_interfaces_dep,
208  boost_coroutine,
209  crypto,
210  ipmid_dep,
211  channellayer_dep,
212  mapper,
213]
214
215transportoem_src = []
216if not get_option('transport-oem').disabled()
217  transportoem_src = ['transporthandler_oem.cpp']
218endif
219
220storage_cmds_src = []
221if get_option('dynamic-sensors').disabled() and not get_option('dynamic-storages-only').disabled()
222  storage_cmds_src = ['dbus-sdr/storagecommands.cpp', 'dbus-sdr/sdrutils.cpp']
223endif
224
225openpower_cmds_src = []
226if get_option('open-power').allowed()
227  openpower_cmds_src = [ 'storageaddsel.cpp' ]
228endif
229
230libipmi20_src = [
231  'app/channel.cpp',
232  'app/watchdog.cpp',
233  'app/watchdog_service.cpp',
234  'apphandler.cpp',
235  'sys_info_param.cpp',
236  'sensorhandler.cpp',
237  'storagehandler.cpp',
238  'chassishandler.cpp',
239  'dcmihandler.cpp',
240  'ipmisensor.cpp',
241  'transporthandler.cpp',
242  'globalhandler.cpp',
243  'groupext.cpp',
244  'selutility.cpp',
245  'ipmi_fru_info_area.cpp',
246  'read_fru_data.cpp',
247  'sensordatahandler.cpp',
248  'user_channel/channelcommands.cpp',
249  generated_src,
250  transportoem_src,
251  storage_cmds_src,
252  openpower_cmds_src,
253  conf_h,
254]
255
256ipmi20_lib = library(
257  'ipmi20',
258  libipmi20_src,
259  dependencies: [ipmid_pre, nlohmann_json_dep],
260  include_directories: root_inc,
261  install: true,
262  install_dir: get_option('libdir') / 'ipmid-providers',
263  version: meson.project_version(),
264  override_options: ['b_lundef=false'])
265
266libipmi20_dep = declare_dependency(
267  dependencies: ipmid_pre,
268  include_directories: root_inc,
269  link_with: ipmi20_lib)
270
271# ipmid binary
272executable(
273  'ipmid',
274  'ipmid-new.cpp',
275  'host-cmd-manager.cpp',
276  'settings.cpp',
277  implicit_include_directories: false,
278  dependencies: [libipmi20_dep],
279  include_directories: root_inc,
280  export_dynamic: true,
281  install: true,
282  install_dir: get_option('bindir'))
283
284# Dynamic Sensor Stack
285subdir('dbus-sdr')
286
287if not get_option('dynamic-sensors').disabled() or not get_option('tests').disabled()
288  library(
289    'dynamiccmds',
290    dbus_sdr_src,
291    implicit_include_directories: false,
292    dependencies: dbus_sdr_pre,
293    version: meson.project_version(),
294    override_options: ['b_lundef=false'],
295    install: true,
296    install_dir: get_option('libdir') / 'ipmid-providers')
297endif
298
299if not get_option('tests').disabled()
300  subdir('test')
301endif
302
303install_subdir(
304  'user_channel',
305  install_dir: get_option('includedir'),
306  strip_directory: false,
307  exclude_files: '*.cpp')
308