1SUMMARY = "Custom Matchbox session files for the Sato environment"
2HOMEPAGE = "http://www.matchbox-project.org/"
3BUGTRACKER = "http://bugzilla.yoctoproject.org/"
4
5LICENSE = "GPL-2.0-or-later"
6LIC_FILES_CHKSUM = "file://session;endline=3;md5=f8a5c5b9c279e52dc094d10e11c2be63"
7
8SECTION = "x11"
9RDEPENDS:${PN} = "formfactor matchbox-theme-sato matchbox-panel-2 matchbox-desktop matchbox-session gconf"
10PR = "r30"
11
12# This package is architecture specific because the session script is modified
13# based on the machine architecture.
14PACKAGE_ARCH = "${MACHINE_ARCH}"
15
16inherit features_check
17
18# The matchbox-theme-sato requires x11 in DISTRO_FEATURES
19REQUIRED_DISTRO_FEATURES = "x11"
20
21SRC_URI = "file://session \
22           file://index.theme"
23S = "${WORKDIR}"
24
25FILES:${PN} += "${datadir}/themes/Sato/index.theme"
26
27do_install() {
28	# This is the set of machine features that the script has markers for
29	FEATURES="acpi apm phone"
30	SCRIPT="${S}/sedder"
31	rm -f $SCRIPT
32	touch $SCRIPT
33	for FEAT in $FEATURES; do
34		if echo ${MACHINE_FEATURES} | awk "/$FEAT/ {exit 1}"; then
35			echo "/feature-$FEAT/d" >> $SCRIPT
36		fi
37	done
38
39	install -D ${S}/index.theme ${D}/${datadir}/themes/Sato/index.theme
40	install -d ${D}/${sysconfdir}/matchbox
41	sed -f "$SCRIPT" ${S}/session > ${D}/${sysconfdir}/matchbox/session
42        chmod +x ${D}/${sysconfdir}/matchbox/session
43}
44
45PACKAGE_WRITE_DEPS += "gconf-native"
46pkg_postinst:${PN} () {
47	set_value() {
48		#type, name, value
49		gconftool-2 --config-source=xml::$D${sysconfdir}/gconf/gconf.xml.defaults --direct --type $1 --set /desktop/poky/interface/$2 "$3"
50	}
51	set_value string theme Adwaita
52	set_value string matchbox_theme Sato
53	set_value string icon_theme Sato
54	set_value bool touchscreen true
55	set_value string font_name "Sans 9"
56}
57