1SUMMARY = "The implementation of SOME/IP"
2DESCRIPTION = "The vsomeip stack implements the http://some-ip.com/ \
3(Scalable service-Oriented MiddlewarE over IP (SOME/IP)) protocol."
4HOMEPAGE = "https://github.com/COVESA/vsomeip"
5SECTION = "net"
6
7LICENSE = "MPL-2.0"
8LIC_FILES_CHKSUM = "file://LICENSE;md5=9741c346eef56131163e13b9db1241b3"
9
10SRC_URI = "git://github.com/GENIVI/${BPN}.git;branch=master;protocol=https;name=vsomeip \
11           file://0001-Fix-pkgconfig-dir-for-multilib.patch \
12           file://0002-Install-example-configuration-files-to-etc-vsomeip.patch \
13           file://0003-Do-not-build-external-gtest.patch \
14           file://0004-Do-not-specify-PIE-flag-explicitly.patch \
15           file://0005-test-common-CMakeLists.txt-add-missing-link-with-dlt.patch \
16           file://0001-Update-to-C-17-560.patch \
17           file://0002-network_tests-Include-iomanip-system-header.patch \
18          "
19
20SRCREV = "02c199dff8aba814beebe3ca417fd991058fe90c"
21
22COMPATIBLE_HOST:mips = "null"
23COMPATIBLE_HOST:mips64 = "null"
24COMPATIBLE_HOST:powerpc = "null"
25COMPATIBLE_HOST:libc-musl = 'null'
26
27DEPENDS = "boost dlt-daemon googletest"
28
29S = "${WORKDIR}/git"
30
31inherit cmake pkgconfig
32
33EXTRA_OECMAKE = "-DINSTALL_LIB_DIR:PATH=${baselib} \
34                 -DINSTALL_CMAKE_DIR:PATH=${baselib}/cmake/vsomeip3 \
35                "
36
37# For vsomeip-test
38EXTRA_OECMAKE += "-DTEST_IP_MASTER=10.0.3.1 \
39                  -DTEST_IP_SLAVE=10.0.3.2 \
40                  -DTEST_IP_SLAVE_SECOND=10.0.3.3 \
41                  -DTEST_UID=1000 -DTEST_GID=1000 \
42                 "
43
44RDEPENDS:${PN}-test = "bash lsof"
45
46do_compile:append() {
47    cmake_runcmake_build --target examples
48    cmake_runcmake_build --target build_tests
49}
50
51do_install:append() {
52    install -d ${D}/opt/${PN}-test/examples
53    install -m 0755 ${B}/examples/*-sample ${D}/opt/${PN}-test/examples
54    install -d ${D}/opt/${PN}-test/examples/routingmanagerd
55    install -m 0755 ${B}/examples/routingmanagerd/routingmanagerd \
56        ${D}/opt/${PN}-test/examples/routingmanagerd
57
58    install -d ${D}/opt/${PN}-test/test/test/common
59    cp -rf ${S}/test/common/examples_policies \
60        ${D}/opt/${PN}-test/test/test/common/
61    install -m 0755 ${B}/test/common/libvsomeip_utilities.so \
62        ${D}/opt/${PN}-test/test/test/common/
63
64    for d in unit_tests network_tests; do
65        install -d ${D}/opt/${PN}-test/test/$d
66        cp -f ${B}/test/$d/*test* ${D}/opt/${PN}-test/test/$d
67    done
68}
69
70PACKAGES += "${PN}-test"
71
72FILES:${PN}-dbg += " \
73   /opt/${PN}-test/.debug/* \
74   "
75FILES:${PN}-test = " \
76   /opt/${PN}-test \
77   "
78