1SUMMARY = "The implementation of SOME/IP"
2DESCRIPTION = "The vsomeip stack implements the http://some-ip.com/ \
3(Scalable service-Oriented MiddlewarE over IP (SOME/IP)) protocol."
4HOMEPAGE = "https://github.com/COVESA/vsomeip"
5SECTION = "net"
6
7LICENSE = "MPL-2.0"
8LIC_FILES_CHKSUM = "file://LICENSE;md5=9741c346eef56131163e13b9db1241b3"
9
10SRC_URI = "git://github.com/GENIVI/${BPN}.git;branch=master;protocol=https;name=vsomeip \
11           file://0001-Fix-pkgconfig-dir-for-multilib.patch \
12           file://0002-Install-example-configuration-files-to-etc-vsomeip.patch \
13           file://0003-Do-not-build-external-gtest.patch \
14           file://0004-Do-not-specify-PIE-flag-explicitly.patch \
15           file://0005-test-common-CMakeLists.txt-add-missing-link-with-dlt.patch \
16          "
17
18SRCREV = "02c199dff8aba814beebe3ca417fd991058fe90c"
19
20COMPATIBLE_HOST:mips = "null"
21COMPATIBLE_HOST:mips64 = "null"
22COMPATIBLE_HOST:powerpc = "null"
23COMPATIBLE_HOST:libc-musl = 'null'
24
25DEPENDS = "boost dlt-daemon googletest"
26
27S = "${WORKDIR}/git"
28
29inherit cmake pkgconfig
30
31EXTRA_OECMAKE = "-DINSTALL_LIB_DIR:PATH=${baselib} \
32                 -DINSTALL_CMAKE_DIR:PATH=${baselib}/cmake/vsomeip3 \
33                "
34
35# For vsomeip-test
36EXTRA_OECMAKE += "-DTEST_IP_MASTER=10.0.3.1 \
37                  -DTEST_IP_SLAVE=10.0.3.2 \
38                  -DTEST_IP_SLAVE_SECOND=10.0.3.3 \
39                  -DTEST_UID=1000 -DTEST_GID=1000 \
40                 "
41
42RDEPENDS:${PN}-test = "bash lsof"
43
44do_compile:append() {
45    cmake_runcmake_build --target examples
46    cmake_runcmake_build --target build_tests
47}
48
49do_install:append() {
50    install -d ${D}/opt/${PN}-test/examples
51    install -m 0755 ${B}/examples/*-sample ${D}/opt/${PN}-test/examples
52    install -d ${D}/opt/${PN}-test/examples/routingmanagerd
53    install -m 0755 ${B}/examples/routingmanagerd/routingmanagerd \
54        ${D}/opt/${PN}-test/examples/routingmanagerd
55
56    install -d ${D}/opt/${PN}-test/test/test/common
57    cp -rf ${S}/test/common/examples_policies \
58        ${D}/opt/${PN}-test/test/test/common/
59    install -m 0755 ${B}/test/common/libvsomeip_utilities.so \
60        ${D}/opt/${PN}-test/test/test/common/
61
62    for d in unit_tests network_tests; do
63        install -d ${D}/opt/${PN}-test/test/$d
64        cp -f ${B}/test/$d/*test* ${D}/opt/${PN}-test/test/$d
65    done
66}
67
68PACKAGES += "${PN}-test"
69
70FILES:${PN}-dbg += " \
71   /opt/${PN}-test/.debug/* \
72   "
73FILES:${PN}-test = " \
74   /opt/${PN}-test \
75   "
76