1SUMMARY = "GNOME Display Manager"
2LICENSE="GPL-2.0-only"
3LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
4
5DEPENDS = " \
6    accountsservice \
7    audit \
8    dconf-native \
9    gtk+3 \
10    keyutils \
11    libcanberra \
12    libgudev \
13    libpam \
14    xserver-xorg \
15"
16
17REQUIRED_DISTRO_FEATURES = "x11 systemd pam polkit gobject-introspection-data"
18GIR_MESON_OPTION = ""
19
20
21inherit gnomebase gsettings pkgconfig gobject-introspection gettext systemd useradd itstool gnome-help features_check
22
23SRC_URI[archive.sha256sum] = "8d6cb52176eca48b6bbf1cfe2fdae08d9677b5a0f2bca600dee4604de0dd1efc"
24
25EXTRA_OEMESON = " \
26    -Dplymouth=disabled \
27    -Ddefault-pam-config=openembedded \
28    -Dpam-mod-dir=${base_libdir}/security \
29"
30
31do_install:prepend() {
32    sed -i -e 's|${B}/||g' ${B}/daemon/gdm-session-worker-enum-types.c
33    sed -i -e 's|${B}/||g' ${B}/daemon/gdm-session-worker-enum-types.h
34    sed -i -e 's|${B}/||g' ${B}/daemon/gdm-session-enum-types.c
35    sed -i -e 's|${B}/||g' ${B}/daemon/gdm-session-enum-types.h
36}
37
38do_install:append() {
39    rm -rf ${D}/run ${D}${localstatedir}/run
40}
41
42USERADD_PACKAGES = "${PN}"
43USERADD_PARAM:${PN} = "--system --no-create-home --home ${localstatedir}/lib/gdm --user-group gdm"
44
45SYSTEMD_SERVICE:${PN} = "${BPN}.service"
46
47# Some gnome components - as gnome-panel and gnome-shell (!!) - require gdm
48# components. To allow gnome-images using different display-manager, split them
49# out into a seperate package.
50PACKAGE_BEFORE_PN = "${PN}-base"
51FILES:${PN}-base = " \
52    ${datadir}/glib-2.0 \
53    ${datadir}/gnome-session \
54    ${libdir}/lib*${SOLIBS} \
55    ${libdir}/girepository-1.0 \
56"
57
58CONFFILES:${PN} += "${sysconfdir}/gdm/custom.conf"
59FILES:${PN} += " \
60    ${datadir}/dconf \
61    ${base_libdir}/security/pam_gdm.so \
62    ${localstatedir} \
63    ${systemd_unitdir} ${systemd_user_unitdir} \
64"
65
66RDEPENDS:${PN} += "${PN}-base"
67