1DEPENDS:append:p10bmc = " cli11"
2DEPENDS:append:p10bmc = " nlohmann-json"
3DEPENDS:append:p10bmc = " phosphor-dbus-interfaces"
4DEPENDS:append:p10bmc = " libgpiod"
5
6FILESEXTRAPATHS:prepend := "${THISDIR}/${PN}:"
7
8SYSTEMD_SERVICE:${PN}:append:p10bmc = " system-vpd.service"
9SYSTEMD_SERVICE:${PN}:append:p10bmc = " wait-vpd-parsers.service"
10SYSTEMD_SERVICE:${PN}:append:p10bmc = " vpd-manager.service"
11PACKAGECONFIG:append:p10bmc = " ibm_system"
12
13FILES:${PN}:append:p10bmc = " ${datadir}/vpd/*.json"
14
15do_install:append:p10bmc() {
16        # Remove files that are used by openpower-read-vpd
17        DEST=${D}${inventory_envdir}
18        rm ${DEST}/inventory
19        rm ${D}/${nonarch_base_libdir}/udev/rules.d/70-op-vpd.rules
20}
21
22do_install:append:witherspoon() {
23        DEST=${D}${inventory_envdir}
24        printf "\nEEPROM=/sys/devices/platform/ahb/1e780000.apb/1e780000.apb:bus@1e78a000/1e78a400.i2c/i2c-11/11-0051/eeprom" >> ${DEST}/inventory
25}
26
27pkg_postinst:${PN}:p10bmc() {
28    mkdir -p $D$systemd_system_unitdir/obmc-chassis-poweroff@0.target.wants
29    LINK="$D$systemd_system_unitdir/obmc-chassis-poweroff@0.target.wants/wait-vpd-parsers.service"
30    TARGET="../wait-vpd-parsers.service"
31    ln -s $TARGET $LINK
32}
33pkg_prerm:${PN}:p10bmc() {
34    LINK="$D$systemd_system_unitdir/obmc-chassis-poweroff@0.target.wants/wait-vpd-parsers.service"
35    rm $LINK
36}