1FILESEXTRAPATHS:prepend:gbmc := "${THISDIR}/${PN}:"
2
3SRC_URI:append:gbmc = " \
4  file://serial-to-bmc@.service \
5  file://serial-to-host@.service.in \
6  file://host-console-journal.service.in \
7  file://host-console-filtered.sh \
8  "
9
10SYSTEMD_SERVICE:${PN}:append:gbmc = " serial-to-bmc@.service"
11SYSTEMD_SERVICE:${PN}:append:gbmc= " serial-to-host@.service"
12
13# Remove the default ssh package config
14PACKAGECONFIG:remove:gbmc = "ssh"
15
16OBMC_CONSOLE_FRONT_TTY ?= ""
17
18RDEPENDS:${PN}:append:gbmc = " bash"
19
20FILES:${PN}:append:gbmc = " ${systemd_system_unitdir}/host-console-journal.service"
21
22do_install:append:gbmc() {
23  install -d ${D}${systemd_system_unitdir}
24  install -m 0644 ${WORKDIR}/serial-to-bmc@.service \
25    ${D}${systemd_system_unitdir}
26
27  sed "s,@HOST_TTY@,${OBMC_CONSOLE_HOST_TTY}," \
28    ${WORKDIR}/serial-to-host@.service.in \
29    >${D}${systemd_system_unitdir}/serial-to-host@.service
30
31  sed 's,@HOST_TTY@,${OBMC_CONSOLE_HOST_TTY},' \
32    ${WORKDIR}/host-console-journal.service.in \
33    >${D}${systemd_system_unitdir}/host-console-journal.service
34
35  install -d ${D}${bindir}
36  install -m0755 ${WORKDIR}/host-console-filtered.sh ${D}${bindir}/
37}
38
39pkg_postinst:${PN}:append:gbmc () {
40  if [ -n "${OBMC_CONSOLE_FRONT_TTY}" ]; then
41    systemctl --root=$D enable serial-to-host@${OBMC_CONSOLE_FRONT_TTY}.service
42  fi
43}
44