1FILESEXTRAPATHS:prepend := "${THISDIR}/${PN}:"
2
3PACKAGECONFIG:append = " host-gpio"
4
5SRC_URI += " \
6    file://host-control \
7    file://chassis-control \
8    file://ncplite-chassis-poweroff@.service \
9    file://ncplite-chassis-poweron@.service \
10    file://ncplite-host-off@.service \
11    file://ncplite-host-force-reset@.service \
12    "
13
14RDEPENDS:${PN}:append = " bash"
15
16DBUS_PACKAGES:append = "${PN}-ncplite"
17PACKAGE_BEFORE_PN += "${PN}-ncplite"
18SYSTEMD_PACKAGES += "${PN}-ncplite"
19
20SYSTEMD_SERVICE:${PN}-ncplite += "ncplite-chassis-poweron@.service"
21SYSTEMD_SERVICE:${PN}-ncplite += "ncplite-chassis-poweroff@.service"
22SYSTEMD_SERVICE:${PN}-ncplite += "ncplite-host-off@.service"
23SYSTEMD_SERVICE:${PN}-ncplite += "ncplite-host-force-reset@.service"
24
25# Chassis power on
26CHASSIS_POWERON_SVC = "ncplite-chassis-poweron@.service"
27CHASSIS_POWERON_INSTMPL = "ncplite-chassis-poweron@{0}.service"
28CHASSIS_POWERON_TGTFMT = "obmc-chassis-poweron@{0}.target"
29CHASSIS_POWERON_FMT = "../${CHASSIS_POWERON_SVC}:${CHASSIS_POWERON_TGTFMT}.requires/${CHASSIS_POWERON_INSTMPL}"
30SYSTEMD_LINK:${PN}-ncplite += "${@compose_list_zip(d, 'CHASSIS_POWERON_FMT', 'OBMC_CHASSIS_INSTANCES')}"
31
32# Chassis power off
33CHASSIS_POWEROFF_SVC = "ncplite-chassis-poweroff@.service"
34CHASSIS_POWEROFF_INSTMPL = "ncplite-chassis-poweroff@{0}.service"
35CHASSIS_POWEROFF_TGTFMT = "obmc-chassis-poweroff@{0}.target"
36CHASSIS_POWEROFF_FMT = "../${CHASSIS_POWEROFF_SVC}:${CHASSIS_POWEROFF_TGTFMT}.requires/${CHASSIS_POWEROFF_INSTMPL}"
37SYSTEMD_LINK:${PN}-ncplite += "${@compose_list_zip(d, 'CHASSIS_POWEROFF_FMT', 'OBMC_CHASSIS_INSTANCES')}"
38
39# Host off
40HOST_OFF_SVC = "ncplite-host-off@.service"
41HOST_OFF_INSTMPL = "ncplite-host-off@{0}.service"
42HOST_OFF_TGTFMT = "obmc-host-shutdown@{0}.target"
43HOST_OFF_FMT = "../${HOST_OFF_SVC}:${HOST_OFF_TGTFMT}.requires/${HOST_OFF_INSTMPL}"
44SYSTEMD_LINK:${PN}-ncplite += "${@compose_list_zip(d, 'HOST_OFF_FMT', 'OBMC_HOST_INSTANCES')}"
45
46# Host force reboot
47HOST_FORCE_RESET_SVC = "ncplite-host-force-reset@.service"
48HOST_FORCE_RESET_INSTMPL = "ncplite-host-force-reset@{0}.service"
49HOST_FORCE_RESET_TGTFMT = "obmc-host-force-warm-reboot@{0}.target"
50HOST_FORCE_RESET_TARGET_FMT = "../${HOST_FORCE_RESET_SVC}:${HOST_FORCE_RESET_TGTFMT}.requires/${HOST_FORCE_RESET_INSTMPL}"
51SYSTEMD_LINK:${PN}-ncplite += "${@compose_list_zip(d, 'HOST_FORCE_RESET_TARGET_FMT', 'OBMC_HOST_INSTANCES')}"
52
53# Chassis hard power off require host off in our machine
54CHASSIS_HARD_POWEROFF_TGTFMT = "obmc-chassis-hard-poweroff@{0}.target"
55CHASSIS_HOST_OFF_FMT = "../${HOST_OFF_SVC}:${CHASSIS_HARD_POWEROFF_TGTFMT}.requires/${HOST_OFF_INSTMPL}"
56SYSTEMD_LINK:${PN}-ncplite += "${@compose_list_zip(d, 'CHASSIS_HOST_OFF_FMT', 'OBMC_CHASSIS_INSTANCES')}"
57
58do_install:append() {
59    install -d ${D}${sbindir}
60    install -m 0744 ${UNPACKDIR}/host-control ${D}${sbindir}/
61    install -m 0744 ${UNPACKDIR}/chassis-control ${D}${sbindir}/
62}
63
64FILES:${PN} += "${systemd_system_unitdir}/*"
65