xref: /openbmc/linux/arch/s390/kernel/mcount.S (revision f36e7c9845d998d1e4100b46cec9c678bff69a24)
1/* SPDX-License-Identifier: GPL-2.0 */
2/*
3 * Copyright IBM Corp. 2008, 2009
4 *
5 */
6
7#include <linux/linkage.h>
8#include <asm/asm-offsets.h>
9#include <asm/ftrace.h>
10#include <asm/nospec-insn.h>
11#include <asm/ptrace.h>
12#include <asm/export.h>
13
14	GEN_BR_THUNK %r1
15	GEN_BR_THUNK %r14
16
17	.section .kprobes.text, "ax"
18
19ENTRY(ftrace_stub)
20	BR_EX	%r14
21ENDPROC(ftrace_stub)
22
23#define STACK_FRAME_SIZE	(STACK_FRAME_OVERHEAD + __PT_SIZE)
24#define STACK_PTREGS		(STACK_FRAME_OVERHEAD)
25#define STACK_PTREGS_GPRS	(STACK_PTREGS + __PT_GPRS)
26#define STACK_PTREGS_PSW	(STACK_PTREGS + __PT_PSW)
27#define STACK_PTREGS_ORIG_GPR2	(STACK_PTREGS + __PT_ORIG_GPR2)
28#ifdef __PACK_STACK
29/* allocate just enough for r14, r15 and backchain */
30#define TRACED_FUNC_FRAME_SIZE	24
31#else
32#define TRACED_FUNC_FRAME_SIZE	STACK_FRAME_OVERHEAD
33#endif
34
35	.macro	ftrace_regs_entry, allregs=0
36	stg	%r14,(__SF_GPRS+8*8)(%r15)	# save traced function caller
37
38	.if \allregs == 1
39	lghi	%r14,0				# save condition code
40	ipm	%r14				# don't put any instructions
41	sllg	%r14,%r14,16			# clobbering CC before this point
42	.endif
43
44	lgr	%r1,%r15
45	# allocate stack frame for ftrace_caller to contain traced function
46	aghi	%r15,-TRACED_FUNC_FRAME_SIZE
47	stg	%r1,__SF_BACKCHAIN(%r15)
48	stg	%r0,(__SF_GPRS+8*8)(%r15)
49	stg	%r15,(__SF_GPRS+9*8)(%r15)
50	# allocate pt_regs and stack frame for ftrace_trace_function
51	aghi	%r15,-STACK_FRAME_SIZE
52	stg	%r1,(STACK_PTREGS_GPRS+15*8)(%r15)
53	xc	STACK_PTREGS_ORIG_GPR2(8,%r15),STACK_PTREGS_ORIG_GPR2(%r15)
54
55	.if \allregs == 1
56	stg	%r14,(STACK_PTREGS_PSW)(%r15)
57	stosm	(STACK_PTREGS_PSW)(%r15),0
58	.endif
59
60	lg	%r14,(__SF_GPRS+8*8)(%r1)	# restore original return address
61	aghi	%r1,-TRACED_FUNC_FRAME_SIZE
62	stg	%r1,__SF_BACKCHAIN(%r15)
63	stg	%r0,(STACK_PTREGS_PSW+8)(%r15)
64	stmg	%r2,%r14,(STACK_PTREGS_GPRS+2*8)(%r15)
65	.endm
66
67SYM_CODE_START(ftrace_regs_caller)
68	ftrace_regs_entry	1
69	j	ftrace_common
70SYM_CODE_END(ftrace_regs_caller)
71
72SYM_CODE_START(ftrace_caller)
73	ftrace_regs_entry	0
74	j	ftrace_common
75SYM_CODE_END(ftrace_caller)
76
77SYM_CODE_START(ftrace_common)
78#ifdef CONFIG_HAVE_MARCH_Z196_FEATURES
79	aghik	%r2,%r0,-MCOUNT_INSN_SIZE
80	lgrl	%r4,function_trace_op
81	lgrl	%r1,ftrace_func
82#else
83	lgr	%r2,%r0
84	aghi	%r2,-MCOUNT_INSN_SIZE
85	larl	%r4,function_trace_op
86	lg	%r4,0(%r4)
87	larl	%r1,ftrace_func
88	lg	%r1,0(%r1)
89#endif
90	lgr	%r3,%r14
91	la	%r5,STACK_PTREGS(%r15)
92	BASR_EX	%r14,%r1
93#ifdef CONFIG_FUNCTION_GRAPH_TRACER
94# The j instruction gets runtime patched to a nop instruction.
95# See ftrace_enable_ftrace_graph_caller.
96SYM_INNER_LABEL(ftrace_graph_caller, SYM_L_GLOBAL)
97	j	.Lftrace_graph_caller_end
98	lmg	%r2,%r3,(STACK_PTREGS_GPRS+14*8)(%r15)
99	lg	%r4,(STACK_PTREGS_PSW+8)(%r15)
100	brasl	%r14,prepare_ftrace_return
101	stg	%r2,(STACK_PTREGS_GPRS+14*8)(%r15)
102.Lftrace_graph_caller_end:
103#endif
104	lg	%r0,(STACK_PTREGS_PSW+8)(%r15)
105#ifdef CONFIG_HAVE_MARCH_Z196_FEATURES
106	ltg	%r1,STACK_PTREGS_ORIG_GPR2(%r15)
107	locgrz	%r1,%r0
108#else
109	lg	%r1,STACK_PTREGS_ORIG_GPR2(%r15)
110	ltgr	%r1,%r1
111	jnz	0f
112	lgr	%r1,%r0
113#endif
1140:	lmg	%r2,%r15,(STACK_PTREGS_GPRS+2*8)(%r15)
115	BR_EX	%r1
116SYM_CODE_END(ftrace_common)
117
118#ifdef CONFIG_FUNCTION_GRAPH_TRACER
119
120SYM_FUNC_START(return_to_handler)
121	stmg	%r2,%r5,32(%r15)
122	lgr	%r1,%r15
123	aghi	%r15,-STACK_FRAME_OVERHEAD
124	stg	%r1,__SF_BACKCHAIN(%r15)
125	brasl	%r14,ftrace_return_to_handler
126	aghi	%r15,STACK_FRAME_OVERHEAD
127	lgr	%r14,%r2
128	lmg	%r2,%r5,32(%r15)
129	BR_EX	%r14
130SYM_FUNC_END(return_to_handler)
131
132#endif
133