xref: /openbmc/linux/arch/s390/kernel/mcount.S (revision 4efd417f298bc23bc8b6ac5db5ff79af5ec92ac5)
1/* SPDX-License-Identifier: GPL-2.0 */
2/*
3 * Copyright IBM Corp. 2008, 2009
4 *
5 */
6
7#include <linux/linkage.h>
8#include <asm/asm-offsets.h>
9#include <asm/ftrace.h>
10#include <asm/nospec-insn.h>
11#include <asm/ptrace.h>
12#include <asm/export.h>
13
14	GEN_BR_THUNK %r1
15	GEN_BR_THUNK %r14
16
17	.section .kprobes.text, "ax"
18
19ENTRY(ftrace_stub)
20	BR_EX	%r14
21ENDPROC(ftrace_stub)
22
23#define STACK_FRAME_SIZE	(STACK_FRAME_OVERHEAD + __PT_SIZE)
24#define STACK_PTREGS		(STACK_FRAME_OVERHEAD)
25#define STACK_PTREGS_GPRS	(STACK_PTREGS + __PT_GPRS)
26#define STACK_PTREGS_PSW	(STACK_PTREGS + __PT_PSW)
27#define STACK_PTREGS_ORIG_GPR2	(STACK_PTREGS + __PT_ORIG_GPR2)
28#define STACK_PTREGS_FLAGS	(STACK_PTREGS + __PT_FLAGS)
29/* packed stack: allocate just enough for r14, r15 and backchain */
30#define TRACED_FUNC_FRAME_SIZE	24
31
32	.macro	ftrace_regs_entry, allregs=0
33	stg	%r14,(__SF_GPRS+8*8)(%r15)	# save traced function caller
34
35	.if \allregs == 1
36	# save psw mask
37	# don't put any instructions clobbering CC before this point
38	epsw	%r1,%r14
39	risbg	%r14,%r1,0,31,32
40	.endif
41
42	lgr	%r1,%r15
43	# allocate stack frame for ftrace_caller to contain traced function
44	aghi	%r15,-TRACED_FUNC_FRAME_SIZE
45	stg	%r1,__SF_BACKCHAIN(%r15)
46	stg	%r0,(__SF_GPRS+8*8)(%r15)
47	stg	%r15,(__SF_GPRS+9*8)(%r15)
48	# allocate pt_regs and stack frame for ftrace_trace_function
49	aghi	%r15,-STACK_FRAME_SIZE
50	stg	%r1,(STACK_PTREGS_GPRS+15*8)(%r15)
51	xc	STACK_PTREGS_ORIG_GPR2(8,%r15),STACK_PTREGS_ORIG_GPR2(%r15)
52
53	.if \allregs == 1
54	stg	%r14,(STACK_PTREGS_PSW)(%r15)
55	mvghi	STACK_PTREGS_FLAGS(%r15),_PIF_FTRACE_FULL_REGS
56	.else
57	xc	STACK_PTREGS_FLAGS(8,%r15),STACK_PTREGS_FLAGS(%r15)
58	.endif
59
60	lg	%r14,(__SF_GPRS+8*8)(%r1)	# restore original return address
61	aghi	%r1,-TRACED_FUNC_FRAME_SIZE
62	stg	%r1,__SF_BACKCHAIN(%r15)
63	stg	%r0,(STACK_PTREGS_PSW+8)(%r15)
64	stmg	%r2,%r14,(STACK_PTREGS_GPRS+2*8)(%r15)
65	.endm
66
67SYM_CODE_START(ftrace_regs_caller)
68	ftrace_regs_entry	1
69	j	ftrace_common
70SYM_CODE_END(ftrace_regs_caller)
71
72SYM_CODE_START(ftrace_caller)
73	ftrace_regs_entry	0
74	j	ftrace_common
75SYM_CODE_END(ftrace_caller)
76
77SYM_CODE_START(ftrace_common)
78#ifdef CONFIG_HAVE_MARCH_Z196_FEATURES
79	aghik	%r2,%r0,-MCOUNT_INSN_SIZE
80	lgrl	%r4,function_trace_op
81	lgrl	%r1,ftrace_func
82#else
83	lgr	%r2,%r0
84	aghi	%r2,-MCOUNT_INSN_SIZE
85	larl	%r4,function_trace_op
86	lg	%r4,0(%r4)
87	larl	%r1,ftrace_func
88	lg	%r1,0(%r1)
89#endif
90	lgr	%r3,%r14
91	la	%r5,STACK_PTREGS(%r15)
92	BASR_EX	%r14,%r1
93#ifdef CONFIG_FUNCTION_GRAPH_TRACER
94# The j instruction gets runtime patched to a nop instruction.
95# See ftrace_enable_ftrace_graph_caller.
96SYM_INNER_LABEL(ftrace_graph_caller, SYM_L_GLOBAL)
97	j	.Lftrace_graph_caller_end
98	lmg	%r2,%r3,(STACK_PTREGS_GPRS+14*8)(%r15)
99	lg	%r4,(STACK_PTREGS_PSW+8)(%r15)
100	brasl	%r14,prepare_ftrace_return
101	stg	%r2,(STACK_PTREGS_GPRS+14*8)(%r15)
102.Lftrace_graph_caller_end:
103#endif
104	lg	%r0,(STACK_PTREGS_PSW+8)(%r15)
105#ifdef CONFIG_HAVE_MARCH_Z196_FEATURES
106	ltg	%r1,STACK_PTREGS_ORIG_GPR2(%r15)
107	locgrz	%r1,%r0
108#else
109	lg	%r1,STACK_PTREGS_ORIG_GPR2(%r15)
110	ltgr	%r1,%r1
111	jnz	0f
112	lgr	%r1,%r0
113#endif
1140:	lmg	%r2,%r15,(STACK_PTREGS_GPRS+2*8)(%r15)
115	BR_EX	%r1
116SYM_CODE_END(ftrace_common)
117
118#ifdef CONFIG_FUNCTION_GRAPH_TRACER
119
120SYM_FUNC_START(return_to_handler)
121	stmg	%r2,%r5,32(%r15)
122	lgr	%r1,%r15
123	aghi	%r15,-STACK_FRAME_OVERHEAD
124	stg	%r1,__SF_BACKCHAIN(%r15)
125	brasl	%r14,ftrace_return_to_handler
126	aghi	%r15,STACK_FRAME_OVERHEAD
127	lgr	%r14,%r2
128	lmg	%r2,%r5,32(%r15)
129	BR_EX	%r14
130SYM_FUNC_END(return_to_handler)
131
132#endif
133