xref: /openbmc/linux/arch/s390/kernel/mcount.S (revision 42b01a553a56d9bc7c75b700fd274f1ec4a3763f)
1/* SPDX-License-Identifier: GPL-2.0 */
2/*
3 * Copyright IBM Corp. 2008, 2009
4 *
5 */
6
7#include <linux/linkage.h>
8#include <asm/asm-offsets.h>
9#include <asm/ftrace.h>
10#include <asm/nospec-insn.h>
11#include <asm/ptrace.h>
12#include <asm/export.h>
13
14	GEN_BR_THUNK %r1
15	GEN_BR_THUNK %r14
16
17	.section .kprobes.text, "ax"
18
19ENTRY(ftrace_stub)
20	BR_EX	%r14
21ENDPROC(ftrace_stub)
22
23#define STACK_FRAME_SIZE	(STACK_FRAME_OVERHEAD + __PT_SIZE)
24#define STACK_PTREGS		(STACK_FRAME_OVERHEAD)
25#define STACK_PTREGS_GPRS	(STACK_PTREGS + __PT_GPRS)
26#define STACK_PTREGS_PSW	(STACK_PTREGS + __PT_PSW)
27#define STACK_PTREGS_ORIG_GPR2	(STACK_PTREGS + __PT_ORIG_GPR2)
28#define STACK_PTREGS_FLAGS	(STACK_PTREGS + __PT_FLAGS)
29/* packed stack: allocate just enough for r14, r15 and backchain */
30#define TRACED_FUNC_FRAME_SIZE	24
31
32	.macro	ftrace_regs_entry, allregs=0
33	stg	%r14,(__SF_GPRS+8*8)(%r15)	# save traced function caller
34
35	.if \allregs == 1
36	lghi	%r14,0				# save condition code
37	ipm	%r14				# don't put any instructions
38	sllg	%r14,%r14,16			# clobbering CC before this point
39	.endif
40
41	lgr	%r1,%r15
42	# allocate stack frame for ftrace_caller to contain traced function
43	aghi	%r15,-TRACED_FUNC_FRAME_SIZE
44	stg	%r1,__SF_BACKCHAIN(%r15)
45	stg	%r0,(__SF_GPRS+8*8)(%r15)
46	stg	%r15,(__SF_GPRS+9*8)(%r15)
47	# allocate pt_regs and stack frame for ftrace_trace_function
48	aghi	%r15,-STACK_FRAME_SIZE
49	stg	%r1,(STACK_PTREGS_GPRS+15*8)(%r15)
50	xc	STACK_PTREGS_ORIG_GPR2(8,%r15),STACK_PTREGS_ORIG_GPR2(%r15)
51
52	.if \allregs == 1
53	stg	%r14,(STACK_PTREGS_PSW)(%r15)
54	stosm	(STACK_PTREGS_PSW)(%r15),0
55#ifdef CONFIG_HAVE_MARCH_Z10_FEATURES
56	mvghi	STACK_PTREGS_FLAGS(%r15),_PIF_FTRACE_FULL_REGS
57#else
58	lghi	%r14,_PIF_FTRACE_FULL_REGS
59	stg	%r14,STACK_PTREGS_FLAGS(%r15)
60#endif
61	.else
62	xc	STACK_PTREGS_FLAGS(8,%r15),STACK_PTREGS_FLAGS(%r15)
63	.endif
64
65	lg	%r14,(__SF_GPRS+8*8)(%r1)	# restore original return address
66	aghi	%r1,-TRACED_FUNC_FRAME_SIZE
67	stg	%r1,__SF_BACKCHAIN(%r15)
68	stg	%r0,(STACK_PTREGS_PSW+8)(%r15)
69	stmg	%r2,%r14,(STACK_PTREGS_GPRS+2*8)(%r15)
70	.endm
71
72SYM_CODE_START(ftrace_regs_caller)
73	ftrace_regs_entry	1
74	j	ftrace_common
75SYM_CODE_END(ftrace_regs_caller)
76
77SYM_CODE_START(ftrace_caller)
78	ftrace_regs_entry	0
79	j	ftrace_common
80SYM_CODE_END(ftrace_caller)
81
82SYM_CODE_START(ftrace_common)
83#ifdef CONFIG_HAVE_MARCH_Z196_FEATURES
84	aghik	%r2,%r0,-MCOUNT_INSN_SIZE
85	lgrl	%r4,function_trace_op
86	lgrl	%r1,ftrace_func
87#else
88	lgr	%r2,%r0
89	aghi	%r2,-MCOUNT_INSN_SIZE
90	larl	%r4,function_trace_op
91	lg	%r4,0(%r4)
92	larl	%r1,ftrace_func
93	lg	%r1,0(%r1)
94#endif
95	lgr	%r3,%r14
96	la	%r5,STACK_PTREGS(%r15)
97	BASR_EX	%r14,%r1
98#ifdef CONFIG_FUNCTION_GRAPH_TRACER
99# The j instruction gets runtime patched to a nop instruction.
100# See ftrace_enable_ftrace_graph_caller.
101SYM_INNER_LABEL(ftrace_graph_caller, SYM_L_GLOBAL)
102	j	.Lftrace_graph_caller_end
103	lmg	%r2,%r3,(STACK_PTREGS_GPRS+14*8)(%r15)
104	lg	%r4,(STACK_PTREGS_PSW+8)(%r15)
105	brasl	%r14,prepare_ftrace_return
106	stg	%r2,(STACK_PTREGS_GPRS+14*8)(%r15)
107.Lftrace_graph_caller_end:
108#endif
109	lg	%r0,(STACK_PTREGS_PSW+8)(%r15)
110#ifdef CONFIG_HAVE_MARCH_Z196_FEATURES
111	ltg	%r1,STACK_PTREGS_ORIG_GPR2(%r15)
112	locgrz	%r1,%r0
113#else
114	lg	%r1,STACK_PTREGS_ORIG_GPR2(%r15)
115	ltgr	%r1,%r1
116	jnz	0f
117	lgr	%r1,%r0
118#endif
1190:	lmg	%r2,%r15,(STACK_PTREGS_GPRS+2*8)(%r15)
120	BR_EX	%r1
121SYM_CODE_END(ftrace_common)
122
123#ifdef CONFIG_FUNCTION_GRAPH_TRACER
124
125SYM_FUNC_START(return_to_handler)
126	stmg	%r2,%r5,32(%r15)
127	lgr	%r1,%r15
128	aghi	%r15,-STACK_FRAME_OVERHEAD
129	stg	%r1,__SF_BACKCHAIN(%r15)
130	brasl	%r14,ftrace_return_to_handler
131	aghi	%r15,STACK_FRAME_OVERHEAD
132	lgr	%r14,%r2
133	lmg	%r2,%r5,32(%r15)
134	BR_EX	%r14
135SYM_FUNC_END(return_to_handler)
136
137#endif
138