xref: /openbmc/linux/arch/s390/kernel/mcount.S (revision 1a5e3f262e0310365cf7b5c8b8fc3a6e94a19cb7)
1/* SPDX-License-Identifier: GPL-2.0 */
2/*
3 * Copyright IBM Corp. 2008, 2009
4 *
5 */
6
7#include <linux/linkage.h>
8#include <asm/asm-offsets.h>
9#include <asm/ftrace.h>
10#include <asm/nospec-insn.h>
11#include <asm/ptrace.h>
12#include <asm/export.h>
13
14	GEN_BR_THUNK %r1
15	GEN_BR_THUNK %r14
16
17	.section .kprobes.text, "ax"
18
19ENTRY(ftrace_stub)
20	BR_EX	%r14
21ENDPROC(ftrace_stub)
22
23#define STACK_FRAME_SIZE	(STACK_FRAME_OVERHEAD + __PT_SIZE)
24#define STACK_PTREGS		(STACK_FRAME_OVERHEAD)
25#define STACK_PTREGS_GPRS	(STACK_PTREGS + __PT_GPRS)
26#define STACK_PTREGS_PSW	(STACK_PTREGS + __PT_PSW)
27#define STACK_PTREGS_ORIG_GPR2	(STACK_PTREGS + __PT_ORIG_GPR2)
28#define STACK_PTREGS_FLAGS	(STACK_PTREGS + __PT_FLAGS)
29/* packed stack: allocate just enough for r14, r15 and backchain */
30#define TRACED_FUNC_FRAME_SIZE	24
31
32	.macro	ftrace_regs_entry, allregs=0
33	stg	%r14,(__SF_GPRS+8*8)(%r15)	# save traced function caller
34
35	.if \allregs == 1
36	# save psw mask
37	# don't put any instructions clobbering CC before this point
38#ifdef CONFIG_HAVE_MARCH_Z10_FEATURES
39	epsw	%r1,%r14
40	risbg	%r14,%r1,0,31,32
41#else
42	epsw	%r14,%r1
43	sllg	%r14,%r14,32
44	lr	%r14,%r1
45#endif
46	.endif
47
48	lgr	%r1,%r15
49	# allocate stack frame for ftrace_caller to contain traced function
50	aghi	%r15,-TRACED_FUNC_FRAME_SIZE
51	stg	%r1,__SF_BACKCHAIN(%r15)
52	stg	%r0,(__SF_GPRS+8*8)(%r15)
53	stg	%r15,(__SF_GPRS+9*8)(%r15)
54	# allocate pt_regs and stack frame for ftrace_trace_function
55	aghi	%r15,-STACK_FRAME_SIZE
56	stg	%r1,(STACK_PTREGS_GPRS+15*8)(%r15)
57	xc	STACK_PTREGS_ORIG_GPR2(8,%r15),STACK_PTREGS_ORIG_GPR2(%r15)
58
59	.if \allregs == 1
60	stg	%r14,(STACK_PTREGS_PSW)(%r15)
61#ifdef CONFIG_HAVE_MARCH_Z10_FEATURES
62	mvghi	STACK_PTREGS_FLAGS(%r15),_PIF_FTRACE_FULL_REGS
63#else
64	lghi	%r14,_PIF_FTRACE_FULL_REGS
65	stg	%r14,STACK_PTREGS_FLAGS(%r15)
66#endif
67	.else
68	xc	STACK_PTREGS_FLAGS(8,%r15),STACK_PTREGS_FLAGS(%r15)
69	.endif
70
71	lg	%r14,(__SF_GPRS+8*8)(%r1)	# restore original return address
72	aghi	%r1,-TRACED_FUNC_FRAME_SIZE
73	stg	%r1,__SF_BACKCHAIN(%r15)
74	stg	%r0,(STACK_PTREGS_PSW+8)(%r15)
75	stmg	%r2,%r14,(STACK_PTREGS_GPRS+2*8)(%r15)
76	.endm
77
78SYM_CODE_START(ftrace_regs_caller)
79	ftrace_regs_entry	1
80	j	ftrace_common
81SYM_CODE_END(ftrace_regs_caller)
82
83SYM_CODE_START(ftrace_caller)
84	ftrace_regs_entry	0
85	j	ftrace_common
86SYM_CODE_END(ftrace_caller)
87
88SYM_CODE_START(ftrace_common)
89#ifdef CONFIG_HAVE_MARCH_Z196_FEATURES
90	aghik	%r2,%r0,-MCOUNT_INSN_SIZE
91	lgrl	%r4,function_trace_op
92	lgrl	%r1,ftrace_func
93#else
94	lgr	%r2,%r0
95	aghi	%r2,-MCOUNT_INSN_SIZE
96	larl	%r4,function_trace_op
97	lg	%r4,0(%r4)
98	larl	%r1,ftrace_func
99	lg	%r1,0(%r1)
100#endif
101	lgr	%r3,%r14
102	la	%r5,STACK_PTREGS(%r15)
103	BASR_EX	%r14,%r1
104#ifdef CONFIG_FUNCTION_GRAPH_TRACER
105# The j instruction gets runtime patched to a nop instruction.
106# See ftrace_enable_ftrace_graph_caller.
107SYM_INNER_LABEL(ftrace_graph_caller, SYM_L_GLOBAL)
108	j	.Lftrace_graph_caller_end
109	lmg	%r2,%r3,(STACK_PTREGS_GPRS+14*8)(%r15)
110	lg	%r4,(STACK_PTREGS_PSW+8)(%r15)
111	brasl	%r14,prepare_ftrace_return
112	stg	%r2,(STACK_PTREGS_GPRS+14*8)(%r15)
113.Lftrace_graph_caller_end:
114#endif
115	lg	%r0,(STACK_PTREGS_PSW+8)(%r15)
116#ifdef CONFIG_HAVE_MARCH_Z196_FEATURES
117	ltg	%r1,STACK_PTREGS_ORIG_GPR2(%r15)
118	locgrz	%r1,%r0
119#else
120	lg	%r1,STACK_PTREGS_ORIG_GPR2(%r15)
121	ltgr	%r1,%r1
122	jnz	0f
123	lgr	%r1,%r0
124#endif
1250:	lmg	%r2,%r15,(STACK_PTREGS_GPRS+2*8)(%r15)
126	BR_EX	%r1
127SYM_CODE_END(ftrace_common)
128
129#ifdef CONFIG_FUNCTION_GRAPH_TRACER
130
131SYM_FUNC_START(return_to_handler)
132	stmg	%r2,%r5,32(%r15)
133	lgr	%r1,%r15
134	aghi	%r15,-STACK_FRAME_OVERHEAD
135	stg	%r1,__SF_BACKCHAIN(%r15)
136	brasl	%r14,ftrace_return_to_handler
137	aghi	%r15,STACK_FRAME_OVERHEAD
138	lgr	%r14,%r2
139	lmg	%r2,%r5,32(%r15)
140	BR_EX	%r14
141SYM_FUNC_END(return_to_handler)
142
143#endif
144