xref: /openbmc/u-boot/board/ti/am335x/u-boot.lds (revision e11ef3d2) 
1/*
2 * Copyright (c) 2004-2008 Texas Instruments
3 *
4 * (C) Copyright 2002
5 * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
6 *
7 * See file CREDITS for list of people who contributed to this
8 * project.
9 *
10 * This program is free software; you can redistribute it and/or
11 * modify it under the terms of the GNU General Public License as
12 * published by the Free Software Foundation; either version 2 of
13 * the License, or (at your option) any later version.
14 *
15 * This program is distributed in the hope that it will be useful,
16 * but WITHOUT ANY WARRANTY; without even the implied warranty of
17 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18 * GNU General Public License for more details.
19 *
20 * You should have received a copy of the GNU General Public License
21 * along with this program; if not, write to the Free Software
22 * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
23 * MA 02111-1307 USA
24 */
25
26OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
27OUTPUT_ARCH(arm)
28ENTRY(_start)
29SECTIONS
30{
31	. = 0x00000000;
32
33	. = ALIGN(4);
34	.text :
35	{
36		*(.__image_copy_start)
37		*(.vectors)
38		CPUDIR/start.o (.text*)
39		board/ti/am335x/built-in.o (.text*)
40	}
41
42	/* This needs to come before *(.text*) */
43	.__efi_runtime_start : {
44		*(.__efi_runtime_start)
45	}
46
47	.efi_runtime : {
48		*(.text.efi_runtime*)
49		*(.rodata.efi_runtime*)
50		*(.data.efi_runtime*)
51	}
52
53	.__efi_runtime_stop : {
54		*(.__efi_runtime_stop)
55	}
56
57	.text_rest :
58	{
59		*(.text*)
60	}
61
62	. = ALIGN(4);
63	.rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
64
65	. = ALIGN(4);
66	.data : {
67		*(.data*)
68	}
69
70	. = ALIGN(4);
71
72	. = .;
73
74	. = ALIGN(4);
75	.u_boot_list : {
76		KEEP(*(SORT(.u_boot_list*)));
77	}
78
79	. = ALIGN(4);
80
81	.efi_runtime_rel_start :
82	{
83		*(.__efi_runtime_rel_start)
84	}
85
86	.efi_runtime_rel : {
87		*(.rel*.efi_runtime)
88		*(.rel*.efi_runtime.*)
89	}
90
91	.efi_runtime_rel_stop :
92	{
93		*(.__efi_runtime_rel_stop)
94	}
95
96	. = ALIGN(4);
97
98	.image_copy_end :
99	{
100		*(.__image_copy_end)
101	}
102
103	.rel_dyn_start :
104	{
105		*(.__rel_dyn_start)
106	}
107
108	.rel.dyn : {
109		*(.rel*)
110	}
111
112	.rel_dyn_end :
113	{
114		*(.__rel_dyn_end)
115	}
116
117	.hash : { *(.hash*) }
118
119	.end :
120	{
121		*(.__end)
122	}
123
124	_image_binary_end = .;
125
126	/*
127	 * Deprecated: this MMU section is used by pxa at present but
128	 * should not be used by new boards/CPUs.
129	 */
130	. = ALIGN(4096);
131	.mmutable : {
132		*(.mmutable)
133	}
134
135/*
136 * Compiler-generated __bss_start and __bss_end, see arch/arm/lib/bss.c
137 * __bss_base and __bss_limit are for linker only (overlay ordering)
138 */
139
140	.bss_start __rel_dyn_start (OVERLAY) : {
141		KEEP(*(.__bss_start));
142		__bss_base = .;
143	}
144
145	.bss __bss_base (OVERLAY) : {
146		*(.bss*)
147		 . = ALIGN(4);
148		 __bss_limit = .;
149	}
150
151	.bss_end __bss_limit (OVERLAY) : {
152		KEEP(*(.__bss_end));
153	}
154
155	.dynsym _image_binary_end : { *(.dynsym) }
156	.dynbss : { *(.dynbss) }
157	.dynstr : { *(.dynstr*) }
158	.dynamic : { *(.dynamic*) }
159	.gnu.hash : { *(.gnu.hash) }
160	.plt : { *(.plt*) }
161	.interp : { *(.interp*) }
162	.gnu : { *(.gnu*) }
163	.ARM.exidx : { *(.ARM.exidx*) }
164}
165