xref: /openbmc/u-boot/arch/x86/cpu/u-boot-64.lds (revision c74dda8b) 
1/*
2 * (C) Copyright 2002
3 * Daniel Engström, Omicron Ceti AB, daniel@omicron.se.
4 *
5 * SPDX-License-Identifier:	GPL-2.0+
6 */
7
8#include <config.h>
9OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
10OUTPUT_ARCH(i386:x86-64)
11ENTRY(_start)
12
13SECTIONS
14{
15#ifndef CONFIG_CMDLINE
16	/DISCARD/ : { *(.u_boot_list_2_cmd_*) }
17#endif
18
19	. = CONFIG_SYS_TEXT_BASE;	/* Location of bootcode in flash */
20	__text_start = .;
21	.text  : { *(.text*); }
22
23	. = ALIGN(4);
24
25	. = ALIGN(4);
26	.u_boot_list : {
27		KEEP(*(SORT(.u_boot_list*)));
28	}
29
30	. = ALIGN(4);
31	.rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
32
33	. = ALIGN(4);
34	.data : { *(.data*) }
35
36	. = ALIGN(4);
37	.hash : { *(.hash*) }
38
39	. = ALIGN(4);
40	.got : { *(.got*) }
41
42	. = ALIGN(4);
43	__data_end = .;
44	__init_end = .;
45
46	. = ALIGN(4);
47	.dynsym : { *(.dynsym*) }
48
49	. = ALIGN(4);
50	__rel_dyn_start = .;
51	.rela.dyn : {
52		*(.rela*)
53	}
54	__rel_dyn_end = .;
55	. = ALIGN(4);
56
57	.dynamic : { *(.dynamic) }
58
59	. = ALIGN(4);
60	_end = .;
61
62	.bss __rel_dyn_start (OVERLAY) : {
63		__bss_start = .;
64		*(.bss)
65		*(COM*)
66		. = ALIGN(4);
67		__bss_end = .;
68	}
69
70	/DISCARD/ : { *(.dynsym) }
71	/DISCARD/ : { *(.dynstr*) }
72	/DISCARD/ : { *(.dynamic*) }
73	/DISCARD/ : { *(.plt*) }
74	/DISCARD/ : { *(.interp*) }
75	/DISCARD/ : { *(.gnu*) }
76}
77