xref: /openbmc/u-boot/arch/mips/cpu/u-boot.lds (revision f77d4410) 
1/* SPDX-License-Identifier: GPL-2.0+ */
2/*
3 * (C) Copyright 2003
4 * Wolfgang Denk Engineering, <wd@denx.de>
5 */
6
7OUTPUT_ARCH(mips)
8ENTRY(_start)
9SECTIONS
10{
11	. = 0x00000000;
12
13	. = ALIGN(4);
14	.text : {
15		__text_start = .;
16		*(.text*)
17		__text_end = .;
18	}
19
20	. = ALIGN(4);
21	.rodata : {
22		*(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
23	}
24
25	. = ALIGN(4);
26	.data : {
27		*(.data*)
28	}
29
30	. = ALIGN(4);
31	.sdata : {
32		*(.sdata*)
33	}
34
35	. = ALIGN(4);
36	.u_boot_list : {
37		KEEP(*(SORT(.u_boot_list*)));
38	}
39
40	. = ALIGN(4);
41	__image_copy_end = .;
42	__init_end = .;
43
44	/*
45	 * .rel must come last so that the mips-relocs tool can shrink
46	 * the section size & the PT_LOAD program header filesz.
47	 */
48	.rel : {
49		__rel_start = .;
50		BYTE(0x0)
51		. += (32 * 1024) - 1;
52	}
53
54	_end = .;
55
56	.bss __rel_start (OVERLAY) : {
57		__bss_start = .;
58		*(.sbss.*)
59		*(.bss.*)
60		*(COMMON)
61		. = ALIGN(4);
62		__bss_end = .;
63	}
64
65	.dynsym _end : {
66		*(.dynsym)
67	}
68
69	.dynbss : {
70		*(.dynbss)
71	}
72
73	.dynstr : {
74		*(.dynstr)
75	}
76
77	.dynamic : {
78		*(.dynamic)
79	}
80
81	.plt : {
82		*(.plt)
83	}
84
85	.interp : {
86		*(.interp)
87	}
88
89	.gnu : {
90		*(.gnu*)
91	}
92
93	.MIPS.stubs : {
94		*(.MIPS.stubs)
95	}
96
97	.hash : {
98		*(.hash)
99	}
100}
101