1/*
2 * (C) Copyright 2002
3 *
4 * SPDX-License-Identifier:	GPL-2.0+
5 */
6
7MEMORY
8{
9	flash : ORIGIN = CONFIG_SPL_TEXT_BASE,
10		LENGTH = CONFIG_SPL_MAX_SIZE
11	sdram : ORIGIN = CONFIG_SPL_BSS_START_ADDR,
12		LENGTH = CONFIG_SPL_BSS_MAX_SIZE
13}
14
15OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
16OUTPUT_ARCH(arm)
17ENTRY(_start)
18SECTIONS
19{
20	. = ALIGN(4);
21	.text :
22	{
23		__image_copy_start = .;
24		*(.vectors)
25		CPUDIR/start.o (.text*)
26		*(.text*)
27	} > flash
28
29	. = ALIGN(4);
30	.data : { *(SORT_BY_ALIGNMENT(.data*)) } > flash
31
32	. = ALIGN(4);
33	.rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) } > flash
34
35	. = ALIGN(4);
36
37	.u_boot_list : {
38		KEEP(*(SORT(.u_boot_list*)));
39	} > flash
40
41	. = ALIGN(4);
42
43	.image_copy_end :
44	{
45		*(.__image_copy_end)
46	}
47
48#ifndef CONFIG_SPL_SKIP_RELOCATE
49	.rel_dyn_start :
50	{
51		*(.__rel_dyn_start)
52	} > flash
53
54	.rel.dyn : {
55		*(.rel*)
56	} > flash
57
58	.rel_dyn_end :
59	{
60		*(.__rel_dyn_end)
61	} > flash
62#endif
63
64	. = ALIGN(4);
65
66	.end_align : { *(.end_align*) } > flash
67	__spl_flash_end = .;
68
69	_image_binary_end = .;
70
71	.bss : {
72		. = ALIGN(4);
73		__bss_start = .;
74		*(.bss*)
75		. = ALIGN(4);
76		__bss_end = .;
77	} > sdram
78}
79