xref: /openbmc/u-boot/arch/arm/cpu/u-boot.lds (revision e77e65df) 
1/*
2 * Copyright (c) 2004-2008 Texas Instruments
3 *
4 * (C) Copyright 2002
5 * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
6 *
7 * SPDX-License-Identifier:	GPL-2.0+
8 */
9
10#include <config.h>
11
12OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
13OUTPUT_ARCH(arm)
14ENTRY(_start)
15SECTIONS
16{
17	. = 0x00000000;
18
19	. = ALIGN(4);
20	.text :
21	{
22		*(.__image_copy_start)
23		*(.vectors)
24		CPUDIR/start.o (.text*)
25		*(.text*)
26	}
27
28#if defined(CONFIG_ARMV7_NONSEC) || defined(CONFIG_ARMV7_VIRT) || defined(CONFIG_ARMV7_PSCI)
29
30#ifndef CONFIG_ARMV7_SECURE_BASE
31#define CONFIG_ARMV7_SECURE_BASE
32#endif
33
34	.__secure_start : {
35		. = ALIGN(0x1000);
36		*(.__secure_start)
37	}
38
39	.secure_text CONFIG_ARMV7_SECURE_BASE :
40		AT(ADDR(.__secure_start) + SIZEOF(.__secure_start))
41	{
42		*(._secure.text)
43	}
44
45	. = LOADADDR(.__secure_start) +
46		SIZEOF(.__secure_start) +
47		SIZEOF(.secure_text);
48
49	__secure_end_lma = .;
50	.__secure_end : AT(__secure_end_lma) {
51		*(.__secure_end)
52		LONG(0x1d1071c);	/* Must output something to reset LMA */
53	}
54#endif
55
56	. = ALIGN(4);
57	.rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
58
59	. = ALIGN(4);
60	.data : {
61		*(.data*)
62	}
63
64	. = ALIGN(4);
65
66	. = .;
67
68	. = ALIGN(4);
69	.u_boot_list : {
70		KEEP(*(SORT(.u_boot_list*)));
71	}
72
73	. = ALIGN(4);
74
75	.image_copy_end :
76	{
77		*(.__image_copy_end)
78	}
79
80	.rel_dyn_start :
81	{
82		*(.__rel_dyn_start)
83	}
84
85	.rel.dyn : {
86		*(.rel*)
87	}
88
89	.rel_dyn_end :
90	{
91		*(.__rel_dyn_end)
92	}
93
94	.end :
95	{
96		*(.__end)
97	}
98
99	_image_binary_end = .;
100
101	/*
102	 * Deprecated: this MMU section is used by pxa at present but
103	 * should not be used by new boards/CPUs.
104	 */
105	. = ALIGN(4096);
106	.mmutable : {
107		*(.mmutable)
108	}
109
110/*
111 * Compiler-generated __bss_start and __bss_end, see arch/arm/lib/bss.c
112 * __bss_base and __bss_limit are for linker only (overlay ordering)
113 */
114
115	.bss_start __rel_dyn_start (OVERLAY) : {
116		KEEP(*(.__bss_start));
117		__bss_base = .;
118	}
119
120	.bss __bss_base (OVERLAY) : {
121		*(.bss*)
122		 . = ALIGN(4);
123		 __bss_limit = .;
124	}
125
126	.bss_end __bss_limit (OVERLAY) : {
127		KEEP(*(.__bss_end));
128	}
129
130	.dynsym _image_binary_end : { *(.dynsym) }
131	.dynbss : { *(.dynbss) }
132	.dynstr : { *(.dynstr*) }
133	.dynamic : { *(.dynamic*) }
134	.plt : { *(.plt*) }
135	.interp : { *(.interp*) }
136	.gnu.hash : { *(.gnu.hash) }
137	.gnu : { *(.gnu*) }
138	.ARM.exidx : { *(.ARM.exidx*) }
139	.gnu.linkonce.armexidx : { *(.gnu.linkonce.armexidx.*) }
140}
141