xref: /openbmc/u-boot/arch/arm/cpu/u-boot.lds (revision 7ca6f363) 
1/*
2 * Copyright (c) 2004-2008 Texas Instruments
3 *
4 * (C) Copyright 2002
5 * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
6 *
7 * SPDX-License-Identifier:	GPL-2.0+
8 */
9
10OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
11OUTPUT_ARCH(arm)
12ENTRY(_start)
13SECTIONS
14{
15	. = 0x00000000;
16
17	. = ALIGN(4);
18	.text :
19	{
20		*(.__image_copy_start)
21		CPUDIR/start.o (.text*)
22		*(.text*)
23	}
24
25	. = ALIGN(4);
26	.rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
27
28	. = ALIGN(4);
29	.data : {
30		*(.data*)
31	}
32
33	. = ALIGN(4);
34
35	. = .;
36
37	. = ALIGN(4);
38	.u_boot_list : {
39		KEEP(*(SORT(.u_boot_list*)));
40	}
41
42	. = ALIGN(4);
43
44	.image_copy_end :
45	{
46		*(.__image_copy_end)
47	}
48
49	.rel_dyn_start :
50	{
51		*(.__rel_dyn_start)
52	}
53
54	.rel.dyn : {
55		*(.rel*)
56	}
57
58	.rel_dyn_end :
59	{
60		*(.__rel_dyn_end)
61	}
62
63	.end :
64	{
65		*(.__end)
66	}
67
68	_image_binary_end = .;
69
70	/*
71	 * Deprecated: this MMU section is used by pxa at present but
72	 * should not be used by new boards/CPUs.
73	 */
74	. = ALIGN(4096);
75	.mmutable : {
76		*(.mmutable)
77	}
78
79/*
80 * Compiler-generated __bss_start and __bss_end, see arch/arm/lib/bss.c
81 * __bss_base and __bss_limit are for linker only (overlay ordering)
82 */
83
84	.bss_start __rel_dyn_start (OVERLAY) : {
85		KEEP(*(.__bss_start));
86		__bss_base = .;
87	}
88
89	.bss __bss_base (OVERLAY) : {
90		*(.bss*)
91		 . = ALIGN(4);
92		 __bss_limit = .;
93	}
94
95	.bss_end __bss_limit (OVERLAY) : {
96		KEEP(*(.__bss_end));
97	}
98
99	.dynsym _image_binary_end : { *(.dynsym) }
100	.dynbss : { *(.dynbss) }
101	.dynstr : { *(.dynstr*) }
102	.dynamic : { *(.dynamic*) }
103	.plt : { *(.plt*) }
104	.interp : { *(.interp*) }
105	.gnu : { *(.gnu*) }
106	.ARM.exidx : { *(.ARM.exidx*) }
107	.gnu.linkonce.armexidx : { *(.gnu.linkonce.armexidx.*) }
108}
109