xref: /openbmc/u-boot/arch/arm/cpu/arm920t/start.S (revision 4e3349b6) 
1/*
2 *  armboot - Startup Code for ARM920 CPU-core
3 *
4 *  Copyright (c) 2001	Marius Gröger <mag@sysgo.de>
5 *  Copyright (c) 2002	Alex Züpke <azu@sysgo.de>
6 *  Copyright (c) 2002	Gary Jennejohn <garyj@denx.de>
7 *
8 * See file CREDITS for list of people who contributed to this
9 * project.
10 *
11 * This program is free software; you can redistribute it and/or
12 * modify it under the terms of the GNU General Public License as
13 * published by the Free Software Foundation; either version 2 of
14 * the License, or (at your option) any later version.
15 *
16 * This program is distributed in the hope that it will be useful,
17 * but WITHOUT ANY WARRANTY; without even the implied warranty of
18 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
19 * GNU General Public License for more details.
20 *
21 * You should have received a copy of the GNU General Public License
22 * along with this program; if not, write to the Free Software
23 * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
24 * MA 02111-1307 USA
25 */
26
27#include <asm-offsets.h>
28#include <common.h>
29#include <config.h>
30
31/*
32 *************************************************************************
33 *
34 * Jump vector table as in table 3.1 in [1]
35 *
36 *************************************************************************
37 */
38
39
40.globl _start
41_start:	b	start_code
42	ldr	pc, _undefined_instruction
43	ldr	pc, _software_interrupt
44	ldr	pc, _prefetch_abort
45	ldr	pc, _data_abort
46	ldr	pc, _not_used
47	ldr	pc, _irq
48	ldr	pc, _fiq
49
50_undefined_instruction:	.word undefined_instruction
51_software_interrupt:	.word software_interrupt
52_prefetch_abort:	.word prefetch_abort
53_data_abort:		.word data_abort
54_not_used:		.word not_used
55_irq:			.word irq
56_fiq:			.word fiq
57
58	.balignl 16,0xdeadbeef
59
60
61/*
62 *************************************************************************
63 *
64 * Startup Code (called from the ARM reset exception vector)
65 *
66 * do important init only if we don't start from memory!
67 * relocate armboot to ram
68 * setup stack
69 * jump to second stage
70 *
71 *************************************************************************
72 */
73
74.globl _TEXT_BASE
75_TEXT_BASE:
76	.word	CONFIG_SYS_TEXT_BASE
77
78/*
79 * These are defined in the board-specific linker script.
80 * Subtracting _start from them lets the linker put their
81 * relative position in the executable instead of leaving
82 * them null.
83 */
84.globl _bss_start_ofs
85_bss_start_ofs:
86	.word __bss_start - _start
87
88.globl _bss_end_ofs
89_bss_end_ofs:
90	.word __bss_end__ - _start
91
92.globl _end_ofs
93_end_ofs:
94	.word _end - _start
95
96#ifdef CONFIG_USE_IRQ
97/* IRQ stack memory (calculated at run-time) */
98.globl IRQ_STACK_START
99IRQ_STACK_START:
100	.word	0x0badc0de
101
102/* IRQ stack memory (calculated at run-time) */
103.globl FIQ_STACK_START
104FIQ_STACK_START:
105	.word 0x0badc0de
106#endif
107
108/* IRQ stack memory (calculated at run-time) + 8 bytes */
109.globl IRQ_STACK_START_IN
110IRQ_STACK_START_IN:
111	.word	0x0badc0de
112
113/*
114 * the actual start code
115 */
116
117start_code:
118	/*
119	 * set the cpu to SVC32 mode
120	 */
121	mrs	r0, cpsr
122	bic	r0, r0, #0x1f
123	orr	r0, r0, #0xd3
124	msr	cpsr, r0
125
126#if	defined(CONFIG_AT91RM9200DK) || defined(CONFIG_AT91RM9200EK)
127	/*
128	 * relocate exception table
129	 */
130	ldr	r0, =_start
131	ldr	r1, =0x0
132	mov	r2, #16
133copyex:
134	subs	r2, r2, #1
135	ldr	r3, [r0], #4
136	str	r3, [r1], #4
137	bne	copyex
138#endif
139
140#ifdef CONFIG_S3C24X0
141	/* turn off the watchdog */
142
143# if defined(CONFIG_S3C2400)
144#  define pWTCON	0x15300000
145#  define INTMSK	0x14400008	/* Interrupt-Controller base addresses */
146#  define CLKDIVN	0x14800014	/* clock divisor register */
147#else
148#  define pWTCON	0x53000000
149#  define INTMSK	0x4A000008	/* Interrupt-Controller base addresses */
150#  define INTSUBMSK	0x4A00001C
151#  define CLKDIVN	0x4C000014	/* clock divisor register */
152# endif
153
154	ldr	r0, =pWTCON
155	mov	r1, #0x0
156	str	r1, [r0]
157
158	/*
159	 * mask all IRQs by setting all bits in the INTMR - default
160	 */
161	mov	r1, #0xffffffff
162	ldr	r0, =INTMSK
163	str	r1, [r0]
164# if defined(CONFIG_S3C2410)
165	ldr	r1, =0x3ff
166	ldr	r0, =INTSUBMSK
167	str	r1, [r0]
168# endif
169
170	/* FCLK:HCLK:PCLK = 1:2:4 */
171	/* default FCLK is 120 MHz ! */
172	ldr	r0, =CLKDIVN
173	mov	r1, #3
174	str	r1, [r0]
175#endif	/* CONFIG_S3C24X0 */
176
177	/*
178	 * we do sys-critical inits only at reboot,
179	 * not when booting from ram!
180	 */
181#ifndef CONFIG_SKIP_LOWLEVEL_INIT
182	bl	cpu_init_crit
183#endif
184
185/* Set stackpointer in internal RAM to call board_init_f */
186call_board_init_f:
187	ldr	sp, =(CONFIG_SYS_INIT_SP_ADDR)
188	bic	sp, sp, #7 /* 8-byte alignment for ABI compliance */
189	ldr	r0,=0x00000000
190	bl	board_init_f
191
192/*------------------------------------------------------------------------------*/
193
194/*
195 * void relocate_code (addr_sp, gd, addr_moni)
196 *
197 * This "function" does not return, instead it continues in RAM
198 * after relocating the monitor code.
199 *
200 */
201	.globl	relocate_code
202relocate_code:
203	mov	r4, r0	/* save addr_sp */
204	mov	r5, r1	/* save addr of gd */
205	mov	r6, r2	/* save addr of destination */
206
207	/* Set up the stack						    */
208stack_setup:
209	mov	sp, r4
210
211	adr	r0, _start
212	cmp	r0, r6
213	beq	clear_bss		/* skip relocation */
214	mov	r1, r6			/* r1 <- scratch for copy_loop */
215	ldr	r3, _bss_start_ofs
216	add	r2, r0, r3		/* r2 <- source end address	    */
217
218copy_loop:
219	ldmia	r0!, {r9-r10}		/* copy from source address [r0]    */
220	stmia	r1!, {r9-r10}		/* copy to   target address [r1]    */
221	cmp	r0, r2			/* until source end address [r2]    */
222	blo	copy_loop
223
224#ifndef CONFIG_SPL_BUILD
225	/*
226	 * fix .rel.dyn relocations
227	 */
228	ldr	r0, _TEXT_BASE		/* r0 <- Text base */
229	sub	r9, r6, r0		/* r9 <- relocation offset */
230	ldr	r10, _dynsym_start_ofs	/* r10 <- sym table ofs */
231	add	r10, r10, r0		/* r10 <- sym table in FLASH */
232	ldr	r2, _rel_dyn_start_ofs	/* r2 <- rel dyn start ofs */
233	add	r2, r2, r0		/* r2 <- rel dyn start in FLASH */
234	ldr	r3, _rel_dyn_end_ofs	/* r3 <- rel dyn end ofs */
235	add	r3, r3, r0		/* r3 <- rel dyn end in FLASH */
236fixloop:
237	ldr	r0, [r2]		/* r0 <- location to fix up, IN FLASH! */
238	add	r0, r0, r9		/* r0 <- location to fix up in RAM */
239	ldr	r1, [r2, #4]
240	and	r7, r1, #0xff
241	cmp	r7, #23			/* relative fixup? */
242	beq	fixrel
243	cmp	r7, #2			/* absolute fixup? */
244	beq	fixabs
245	/* ignore unknown type of fixup */
246	b	fixnext
247fixabs:
248	/* absolute fix: set location to (offset) symbol value */
249	mov	r1, r1, LSR #4		/* r1 <- symbol index in .dynsym */
250	add	r1, r10, r1		/* r1 <- address of symbol in table */
251	ldr	r1, [r1, #4]		/* r1 <- symbol value */
252	add	r1, r1, r9		/* r1 <- relocated sym addr */
253	b	fixnext
254fixrel:
255	/* relative fix: increase location by offset */
256	ldr	r1, [r0]
257	add	r1, r1, r9
258fixnext:
259	str	r1, [r0]
260	add	r2, r2, #8		/* each rel.dyn entry is 8 bytes */
261	cmp	r2, r3
262	blo	fixloop
263#endif
264
265clear_bss:
266#ifndef CONFIG_SPL_BUILD
267	ldr	r0, _bss_start_ofs
268	ldr	r1, _bss_end_ofs
269	mov	r4, r6			/* reloc addr */
270	add	r0, r0, r4
271	add	r1, r1, r4
272	mov	r2, #0x00000000		/* clear			    */
273
274clbss_l:cmp	r0, r1			/* clear loop... */
275	bhs	clbss_e			/* if reached end of bss, exit */
276	str	r2, [r0]
277	add	r0, r0, #4
278	b	clbss_l
279clbss_e:
280
281	bl coloured_LED_init
282	bl red_led_on
283#endif
284
285/*
286 * We are done. Do not return, instead branch to second part of board
287 * initialization, now running from RAM.
288 */
289#ifdef CONFIG_NAND_SPL
290	ldr     r0, _nand_boot_ofs
291	mov	pc, r0
292
293_nand_boot_ofs:
294	.word nand_boot
295#else
296	ldr	r0, _board_init_r_ofs
297	adr	r1, _start
298	add	lr, r0, r1
299	add	lr, lr, r9
300	/* setup parameters for board_init_r */
301	mov	r0, r5		/* gd_t */
302	mov	r1, r6		/* dest_addr */
303	/* jump to it ... */
304	mov	pc, lr
305
306_board_init_r_ofs:
307	.word board_init_r - _start
308#endif
309
310_rel_dyn_start_ofs:
311	.word __rel_dyn_start - _start
312_rel_dyn_end_ofs:
313	.word __rel_dyn_end - _start
314_dynsym_start_ofs:
315	.word __dynsym_start - _start
316
317/*
318 *************************************************************************
319 *
320 * CPU_init_critical registers
321 *
322 * setup important registers
323 * setup memory timing
324 *
325 *************************************************************************
326 */
327
328
329#ifndef CONFIG_SKIP_LOWLEVEL_INIT
330cpu_init_crit:
331	/*
332	 * flush v4 I/D caches
333	 */
334	mov	r0, #0
335	mcr	p15, 0, r0, c7, c7, 0	/* flush v3/v4 cache */
336	mcr	p15, 0, r0, c8, c7, 0	/* flush v4 TLB */
337
338	/*
339	 * disable MMU stuff and caches
340	 */
341	mrc	p15, 0, r0, c1, c0, 0
342	bic	r0, r0, #0x00002300	@ clear bits 13, 9:8 (--V- --RS)
343	bic	r0, r0, #0x00000087	@ clear bits 7, 2:0 (B--- -CAM)
344	orr	r0, r0, #0x00000002	@ set bit 2 (A) Align
345	orr	r0, r0, #0x00001000	@ set bit 12 (I) I-Cache
346	mcr	p15, 0, r0, c1, c0, 0
347
348	/*
349	 * before relocating, we have to setup RAM timing
350	 * because memory timing is board-dependend, you will
351	 * find a lowlevel_init.S in your board directory.
352	 */
353	mov	ip, lr
354
355	bl	lowlevel_init
356
357	mov	lr, ip
358	mov	pc, lr
359#endif /* CONFIG_SKIP_LOWLEVEL_INIT */
360
361/*
362 *************************************************************************
363 *
364 * Interrupt handling
365 *
366 *************************************************************************
367 */
368
369@
370@ IRQ stack frame.
371@
372#define S_FRAME_SIZE	72
373
374#define S_OLD_R0	68
375#define S_PSR		64
376#define S_PC		60
377#define S_LR		56
378#define S_SP		52
379
380#define S_IP		48
381#define S_FP		44
382#define S_R10		40
383#define S_R9		36
384#define S_R8		32
385#define S_R7		28
386#define S_R6		24
387#define S_R5		20
388#define S_R4		16
389#define S_R3		12
390#define S_R2		8
391#define S_R1		4
392#define S_R0		0
393
394#define MODE_SVC	0x13
395#define I_BIT		0x80
396
397/*
398 * use bad_save_user_regs for abort/prefetch/undef/swi ...
399 * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
400 */
401
402	.macro	bad_save_user_regs
403	sub	sp, sp, #S_FRAME_SIZE
404	stmia	sp, {r0 - r12}			@ Calling r0-r12
405	ldr	r2, IRQ_STACK_START_IN
406	ldmia	r2, {r2 - r3}			@ get pc, cpsr
407	add	r0, sp, #S_FRAME_SIZE		@ restore sp_SVC
408
409	add	r5, sp, #S_SP
410	mov	r1, lr
411	stmia	r5, {r0 - r3}			@ save sp_SVC, lr_SVC, pc, cpsr
412	mov	r0, sp
413	.endm
414
415	.macro	irq_save_user_regs
416	sub	sp, sp, #S_FRAME_SIZE
417	stmia	sp, {r0 - r12}			@ Calling r0-r12
418	add	r7, sp, #S_PC
419	stmdb	r7, {sp, lr}^			@ Calling SP, LR
420	str	lr, [r7, #0]			@ Save calling PC
421	mrs	r6, spsr
422	str	r6, [r7, #4]			@ Save CPSR
423	str	r0, [r7, #8]			@ Save OLD_R0
424	mov	r0, sp
425	.endm
426
427	.macro	irq_restore_user_regs
428	ldmia	sp, {r0 - lr}^			@ Calling r0 - lr
429	mov	r0, r0
430	ldr	lr, [sp, #S_PC]			@ Get PC
431	add	sp, sp, #S_FRAME_SIZE
432	/* return & move spsr_svc into cpsr */
433	subs	pc, lr, #4
434	.endm
435
436	.macro get_bad_stack
437	ldr	r13, IRQ_STACK_START_IN		@ setup our mode stack
438
439	str	lr, [r13]			@ save caller lr / spsr
440	mrs	lr, spsr
441	str	lr, [r13, #4]
442
443	mov	r13, #MODE_SVC			@ prepare SVC-Mode
444	@ msr	spsr_c, r13
445	msr	spsr, r13
446	mov	lr, pc
447	movs	pc, lr
448	.endm
449
450	.macro get_irq_stack			@ setup IRQ stack
451	ldr	sp, IRQ_STACK_START
452	.endm
453
454	.macro get_fiq_stack			@ setup FIQ stack
455	ldr	sp, FIQ_STACK_START
456	.endm
457
458/*
459 * exception handlers
460 */
461	.align  5
462undefined_instruction:
463	get_bad_stack
464	bad_save_user_regs
465	bl	do_undefined_instruction
466
467	.align	5
468software_interrupt:
469	get_bad_stack
470	bad_save_user_regs
471	bl	do_software_interrupt
472
473	.align	5
474prefetch_abort:
475	get_bad_stack
476	bad_save_user_regs
477	bl	do_prefetch_abort
478
479	.align	5
480data_abort:
481	get_bad_stack
482	bad_save_user_regs
483	bl	do_data_abort
484
485	.align	5
486not_used:
487	get_bad_stack
488	bad_save_user_regs
489	bl	do_not_used
490
491#ifdef CONFIG_USE_IRQ
492
493	.align	5
494irq:
495	get_irq_stack
496	irq_save_user_regs
497	bl	do_irq
498	irq_restore_user_regs
499
500	.align	5
501fiq:
502	get_fiq_stack
503	/* someone ought to write a more effiction fiq_save_user_regs */
504	irq_save_user_regs
505	bl	do_fiq
506	irq_restore_user_regs
507
508#else
509
510	.align	5
511irq:
512	get_bad_stack
513	bad_save_user_regs
514	bl	do_irq
515
516	.align	5
517fiq:
518	get_bad_stack
519	bad_save_user_regs
520	bl	do_fiq
521
522#endif
523