xref: /openbmc/u-boot/arch/arc/cpu/u-boot.lds (revision 0649cd0d) 
1/*
2 * Copyright (C) 2013-2014 Synopsys, Inc. All rights reserved.
3 *
4 * SPDX-License-Identifier:	GPL-2.0+
5 */
6
7#include <config.h>
8
9OUTPUT_FORMAT("elf32-littlearc", "elf32-littlearc", "elf32-littlearc")
10OUTPUT_ARCH(arc)
11ENTRY(_start)
12SECTIONS
13{
14	. = CONFIG_SYS_TEXT_BASE;
15	__image_copy_start = .;
16	__text_start = .;
17	.text :	{
18		arch/arc/lib/start.o (.text*)
19		*(.text*)
20	}
21	__text_end = .;
22
23	. = ALIGN(1024);
24	__ivt_start = .;
25	.ivt :
26	{
27		*(.ivt)
28	}
29	__ivt_end = .;
30
31	. = ALIGN(4);
32	.rodata : {
33		*(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
34	}
35
36	. = ALIGN(4);
37	.data : {
38		*(.data*)
39	}
40
41	. = ALIGN(4);
42	.u_boot_list : {
43		KEEP(*(SORT(.u_boot_list*)));
44	}
45
46	. = ALIGN(4);
47	__rel_dyn_start = .;
48	.rela.dyn : {
49		*(.rela.dyn)
50	}
51	__rel_dyn_end = .;
52
53	. = ALIGN(4);
54	__bss_start = .;
55	.bss : {
56		*(.bss*)
57	}
58	__bss_end = .;
59
60	. = ALIGN(4);
61	__image_copy_end = .;
62	__init_end = .;
63}
64