xref: /openbmc/telemetry/meson.build (revision 934201f7) 
1project(
2    'Telemetry',
3    'cpp',
4    meson_version: '>=0.57.0',
5    default_options: [
6        'buildtype=debugoptimized',
7        'cpp_std=c++20',
8        # TODO: Without RTTI telemetry does not build using Boost 1.74.0
9        # https://github.com/chriskohlhoff/asio/issues/533
10        #'cpp_rtti=false',
11        'warning_level=3',
12        'werror=true',
13        'b_lto=true',
14    ],
15    license: 'Apache-2.0',
16)
17
18summary({'Fast build with link-time optimizer disabled':
19            not get_option('b_lto')}, section: 'General')
20
21cpp = meson.get_compiler('cpp')
22add_project_arguments(
23    cpp.get_supported_arguments([
24        '-DBOOST_ASIO_DISABLE_THREADS',
25        '-DBOOST_ALL_NO_LIB',
26        '-DBOOST_SYSTEM_NO_DEPRECATED',
27        '-DBOOST_ASIO_NO_DEPRECATED',
28        '-DBOOST_NO_RTTI',
29        '-DBOOST_NO_TYPEID',
30        # TODO: Removed below arg after upgrade to Boost 1.75
31        '-DBOOST_ALLOW_DEPRECATED_HEADERS',
32        '-Wno-unused-parameter',
33    ]),
34    language: 'cpp'
35)
36
37boost = dependency(
38    'boost',
39    version: '>=1.74.0',
40    required: false,
41    modules: ['coroutine'])
42assert(boost.found(),
43       'Missing Boost 1.74.0 or higher, as WA you can set BOOST_ROOT ' +
44       'environemt to point at boost build. To build a boost you can use ' +
45       'script ./scripts/boost_build_1.74.0.sh')
46
47phosphor_logging = dependency('phosphor-logging', required: false)
48if not phosphor_logging.found()
49    subproject('phosphor-logging', required: false)
50    phosphor_logging = declare_dependency(
51        include_directories: 'subprojects/phosphor-logging'
52    )
53endif
54
55sdbusplus = dependency('sdbusplus', fallback: ['sdbusplus', 'sdbusplus_dep'])
56systemd = dependency('systemd')
57
58if cpp.has_header('nlohmann/json.hpp')
59    nlohmann_json = declare_dependency()
60else
61    nlohmann_json = dependency('nlohmann_json',
62                               fallback: ['nlohmann', 'nlohmann_json_dep'])
63endif
64
65add_project_arguments(
66    '-DTELEMETRY_MAX_REPORTS=' + get_option('max-reports').to_string(),
67    '-DTELEMETRY_MAX_READING_PARAMS=' +
68        get_option('max-reading-parameters').to_string(),
69    '-DTELEMETRY_MIN_INTERVAL=' + get_option('min-interval').to_string(),
70    '-DTELEMETRY_MAX_TRIGGERS=' + get_option('max-triggers').to_string(),
71    '-DTELEMETRY_MAX_REPORT_NAME_LENGTH=' +
72        get_option('max-report-name-length').to_string(),
73    language: 'cpp'
74)
75
76executable(
77    'telemetry',
78    [
79        'src/details/collection_function.cpp',
80        'src/discrete_threshold.cpp',
81        'src/main.cpp',
82        'src/metric.cpp',
83        'src/numeric_threshold.cpp',
84        'src/on_change_threshold.cpp',
85        'src/persistent_json_storage.cpp',
86        'src/report.cpp',
87        'src/report_factory.cpp',
88        'src/report_manager.cpp',
89        'src/sensor.cpp',
90        'src/sensor_cache.cpp',
91        'src/trigger.cpp',
92        'src/trigger_actions.cpp',
93        'src/trigger_factory.cpp',
94        'src/trigger_manager.cpp',
95        'src/types/report_types.cpp',
96        'src/utils/conversion_trigger.cpp',
97    ],
98    dependencies: [
99        boost,
100        nlohmann_json,
101        sdbusplus,
102        phosphor_logging,
103    ],
104    include_directories: 'src',
105    install: true,
106    install_dir: get_option('prefix') / get_option('bindir'),
107    pie: true,
108)
109
110configure_file(
111    input: 'xyz.openbmc_project.Telemetry.service.in',
112    output: 'xyz.openbmc_project.Telemetry.service',
113    configuration: {
114        'bindir': get_option('prefix') / get_option('bindir'),
115    },
116    install: true,
117    install_dir: systemd.get_pkgconfig_variable('systemdsystemunitdir'),
118)
119
120if get_option('buildtest')
121    subdir('tests')
122endif
123