xref: /openbmc/telemetry/meson.build (revision 32859b63) 
1project(
2    'Telemetry',
3    'cpp',
4    meson_version: '>=0.54.3',
5    default_options: [
6        'buildtype=debugoptimized',
7        'cpp_std=c++17',
8        # TODO: Without RTTI telemetry does not build using Boost 1.74.0
9        # https://github.com/chriskohlhoff/asio/issues/533
10        #'cpp_rtti=false',
11        'warning_level=3',
12        'werror=true',
13        'b_lto=true',
14    ],
15    license: 'Apache-2.0',
16)
17
18cpp = meson.get_compiler('cpp')
19add_project_arguments(
20    cpp.get_supported_arguments([
21        '-DBOOST_ASIO_DISABLE_THREADS',
22        '-DBOOST_ALL_NO_LIB',
23        '-DBOOST_SYSTEM_NO_DEPRECATED',
24        '-DBOOST_ASIO_NO_DEPRECATED',
25        '-DBOOST_NO_RTTI',
26        '-DBOOST_NO_TYPEID',
27        # TODO: Removed below arg after upgrade to Boost 1.75
28        '-DBOOST_ALLOW_DEPRECATED_HEADERS',
29        '-Wno-unused-parameter',
30    ]),
31    language: 'cpp'
32)
33
34boost = dependency(
35    'boost',
36    version: '>=1.74.0',
37    required: false,
38    modules: ['coroutine'])
39assert(boost.found(),
40       'Missing Boost 1.74.0 or higher, as WA you can set BOOST_ROOT ' +
41       'environemt to point at boost build. To build a boost you can use ' +
42       'script ./scripts/boost_build_1.74.0.sh')
43
44phosphor_logging = dependency('phosphor-logging', required: false)
45if not phosphor_logging.found()
46    subproject('phosphor-logging', required: false)
47    phosphor_logging = declare_dependency(
48        include_directories: 'subprojects/phosphor-logging'
49    )
50endif
51
52sdbusplus = dependency('sdbusplus', fallback: ['sdbusplus', 'sdbusplus_dep'])
53systemd = dependency('systemd')
54
55if cpp.has_header('nlohmann/json.hpp')
56    nlohmann_json = declare_dependency()
57else
58    nlohmann_json = dependency('nlohmann_json',
59                               fallback: ['nlohmann', 'nlohmann_json_dep'])
60endif
61
62add_project_arguments(
63    '-DTELEMETRY_MAX_REPORTS=' + get_option('max-reports').to_string(),
64    '-DTELEMETRY_MAX_READING_PARAMS=' +
65        get_option('max-reading-parameters').to_string(),
66    '-DTELEMETRY_MIN_INTERVAL=' + get_option('min-interval').to_string(),
67    '-DTELEMETRY_MAX_TRIGGERS=' + get_option('max-triggers').to_string(),
68    '-DTELEMETRY_MAX_REPORT_NAME_LENGTH=' +
69        get_option('max-report-name-length').to_string(),
70    language: 'cpp'
71)
72
73executable(
74    'telemetry',
75    [
76        'src/discrete_threshold.cpp',
77        'src/main.cpp',
78        'src/metric.cpp',
79        'src/numeric_threshold.cpp',
80        'src/on_change_threshold.cpp',
81        'src/persistent_json_storage.cpp',
82        'src/report.cpp',
83        'src/report_factory.cpp',
84        'src/report_manager.cpp',
85        'src/sensor.cpp',
86        'src/sensor_cache.cpp',
87        'src/trigger.cpp',
88        'src/trigger_actions.cpp',
89        'src/trigger_factory.cpp',
90        'src/trigger_manager.cpp',
91    ],
92    dependencies: [
93        boost,
94        nlohmann_json,
95        sdbusplus,
96        phosphor_logging,
97    ],
98    include_directories: 'src',
99    install: true,
100    install_dir: get_option('prefix') / get_option('bindir'),
101    pie: true,
102)
103
104configure_file(
105    input: 'xyz.openbmc_project.Telemetry.service.in',
106    output: 'xyz.openbmc_project.Telemetry.service',
107    configuration: {
108        'bindir': get_option('prefix') / get_option('bindir'),
109    },
110    install: true,
111    install_dir: systemd.get_pkgconfig_variable('systemdsystemunitdir'),
112)
113
114if get_option('buildtest')
115    subdir('tests')
116endif
117