xref: /openbmc/qemu/ui/meson.build (revision c85cad81) 
1system_ss.add(pixman)
2specific_ss.add(when: ['CONFIG_SYSTEM_ONLY'], if_true: pixman)   # for the include path
3specific_ss.add(when: ['CONFIG_SYSTEM_ONLY'], if_true: opengl)   # for the include path
4
5system_ss.add(png)
6system_ss.add(files(
7  'clipboard.c',
8  'console.c',
9  'cursor.c',
10  'input-keymap.c',
11  'input-legacy.c',
12  'input-barrier.c',
13  'input.c',
14  'kbd-state.c',
15  'keymaps.c',
16  'qemu-pixman.c',
17  'ui-hmp-cmds.c',
18  'ui-qmp-cmds.c',
19  'util.c',
20))
21if dbus_display
22  system_ss.add(files('dbus-module.c'))
23endif
24system_ss.add([spice_headers, files('spice-module.c')])
25system_ss.add(when: spice_protocol, if_true: files('vdagent.c'))
26
27system_ss.add(when: 'CONFIG_LINUX', if_true: files(
28  'input-linux.c',
29  'udmabuf.c',
30))
31system_ss.add(when: cocoa, if_true: files('cocoa.m'))
32
33vnc_ss = ss.source_set()
34vnc_ss.add(files(
35  'vnc.c',
36  'vnc-enc-zlib.c',
37  'vnc-enc-hextile.c',
38  'vnc-enc-tight.c',
39  'vnc-palette.c',
40  'vnc-enc-zrle.c',
41  'vnc-auth-vencrypt.c',
42  'vnc-ws.c',
43  'vnc-jobs.c',
44  'vnc-clipboard.c',
45))
46vnc_ss.add(zlib, jpeg, gnutls)
47vnc_ss.add(when: sasl, if_true: files('vnc-auth-sasl.c'))
48system_ss.add_all(when: vnc, if_true: vnc_ss)
49system_ss.add(when: vnc, if_false: files('vnc-stubs.c'))
50
51ui_modules = {}
52
53if curses.found()
54  curses_ss = ss.source_set()
55  curses_ss.add(when: [curses, iconv], if_true: [files('curses.c'), pixman])
56  ui_modules += {'curses' : curses_ss}
57endif
58
59system_ss.add(opengl)
60if opengl.found()
61  opengl_ss = ss.source_set()
62  opengl_ss.add(gbm)
63  opengl_ss.add(when: [opengl, pixman],
64               if_true: files('shader.c', 'console-gl.c', 'egl-helpers.c', 'egl-context.c'))
65  ui_modules += {'opengl' : opengl_ss}
66endif
67
68if opengl.found() and gbm.found()
69  egl_headless_ss = ss.source_set()
70  egl_headless_ss.add(when: [opengl, gbm, pixman],
71                      if_true: files('egl-headless.c'))
72  ui_modules += {'egl-headless' : egl_headless_ss}
73endif
74
75if dbus_display
76  dbus_ss = ss.source_set()
77  dbus_display1 = custom_target('dbus-display gdbus-codegen',
78                                output: ['dbus-display1.h', 'dbus-display1.c'],
79                                input: files('dbus-display1.xml'),
80                                command: [gdbus_codegen, '@INPUT@',
81                                          '--glib-min-required', '2.64',
82                                          '--output-directory', meson.current_build_dir(),
83                                          '--interface-prefix', 'org.qemu.',
84                                          '--c-namespace', 'QemuDBus',
85                                          '--generate-c-code', '@BASENAME@'])
86  dbus_display1_lib = static_library('dbus-display1', dbus_display1, dependencies: gio)
87  dbus_display1_dep = declare_dependency(link_with: dbus_display1_lib, include_directories: include_directories('.'))
88  dbus_ss.add(when: [gio, pixman, dbus_display1_dep],
89              if_true: [files(
90                'dbus-chardev.c',
91                'dbus-clipboard.c',
92                'dbus-console.c',
93                'dbus-error.c',
94                'dbus-listener.c',
95                'dbus.c',
96              ), opengl, gbm])
97  ui_modules += {'dbus' : dbus_ss}
98endif
99
100if gtk.found()
101  system_ss.add(when: 'CONFIG_WIN32', if_true: files('win32-kbd-hook.c'))
102
103  gtk_ss = ss.source_set()
104  gtk_ss.add(gtk, vte, pixman, files('gtk.c'))
105  if have_gtk_clipboard
106    gtk_ss.add(files('gtk-clipboard.c'))
107  endif
108  gtk_ss.add(when: x11, if_true: files('x_keymap.c'))
109  gtk_ss.add(when: opengl, if_true: files('gtk-gl-area.c'))
110  gtk_ss.add(when: [x11, opengl], if_true: files('gtk-egl.c'))
111  ui_modules += {'gtk' : gtk_ss}
112endif
113
114if sdl.found()
115  system_ss.add(when: 'CONFIG_WIN32', if_true: files('win32-kbd-hook.c'))
116
117  sdl_ss = ss.source_set()
118  sdl_ss.add(sdl, sdl_image, pixman, glib, files(
119    'sdl2-2d.c',
120    'sdl2-input.c',
121    'sdl2.c',
122  ))
123  sdl_ss.add(when: opengl, if_true: files('sdl2-gl.c'))
124  sdl_ss.add(when: x11, if_true: files('x_keymap.c'))
125  ui_modules += {'sdl' : sdl_ss}
126endif
127
128if spice.found()
129  spice_core_ss = ss.source_set()
130  spice_core_ss.add(spice, pixman, files(
131    'spice-core.c',
132    'spice-input.c',
133    'spice-display.c'
134  ))
135  ui_modules += {'spice-core' : spice_core_ss}
136endif
137
138if spice.found() and gio.found()
139  spice_ss = ss.source_set()
140  spice_ss.add(spice, gio, pixman, files('spice-app.c'))
141  ui_modules += {'spice-app': spice_ss}
142endif
143
144keymaps = [
145  ['atset1', 'qcode'],
146  ['linux', 'qcode'],
147  ['qcode', 'atset1'],
148  ['qcode', 'atset2'],
149  ['qcode', 'atset3'],
150  ['qcode', 'linux'],
151  ['qcode', 'qnum'],
152  ['qcode', 'sun'],
153  ['qnum', 'qcode'],
154  ['usb', 'qcode'],
155  ['win32', 'qcode'],
156  ['x11', 'qcode'],
157  ['xorgevdev', 'qcode'],
158  ['xorgkbd', 'qcode'],
159  ['xorgxquartz', 'qcode'],
160  ['xorgxwin', 'qcode'],
161  ['osx', 'qcode'],
162]
163
164if have_system or xkbcommon.found()
165  keycodemapdb_proj = subproject('keycodemapdb', required: true)
166  foreach e : keymaps
167    output = 'input-keymap-@0@-to-@1@.c.inc'.format(e[0], e[1])
168    genh += custom_target(output,
169                  output: output,
170                  capture: true,
171                  input: keycodemapdb_proj.get_variable('keymaps_csv'),
172                  command: [python, keycodemapdb_proj.get_variable('keymap_gen').full_path(),
173                            'code-map', '--lang', 'glib2',
174                            '--varname', 'qemu_input_map_@0@_to_@1@'.format(e[0], e[1]),
175                            '@INPUT0@', e[0], e[1]])
176  endforeach
177endif
178
179subdir('shader')
180
181if have_system
182  subdir('icons')
183
184  install_data('qemu.desktop', install_dir: qemu_desktopdir)
185endif
186
187modules += {'ui': ui_modules}
188