xref: /openbmc/qemu/ui/meson.build (revision 9949b06e) 
1softmmu_ss.add(pixman)
2specific_ss.add(when: ['CONFIG_SOFTMMU'], if_true: pixman)   # for the include path
3specific_ss.add(when: ['CONFIG_SOFTMMU'], if_true: opengl)   # for the include path
4
5softmmu_ss.add(png)
6softmmu_ss.add(files(
7  'clipboard.c',
8  'console.c',
9  'cursor.c',
10  'input-keymap.c',
11  'input-legacy.c',
12  'input-barrier.c',
13  'input.c',
14  'kbd-state.c',
15  'keymaps.c',
16  'qemu-pixman.c',
17  'ui-qmp-cmds.c',
18  'util.c',
19))
20if dbus_display
21  softmmu_ss.add(files('dbus-module.c'))
22endif
23softmmu_ss.add([spice_headers, files('spice-module.c')])
24softmmu_ss.add(when: spice_protocol, if_true: files('vdagent.c'))
25
26softmmu_ss.add(when: 'CONFIG_LINUX', if_true: files(
27  'input-linux.c',
28  'udmabuf.c',
29))
30softmmu_ss.add(when: cocoa, if_true: files('cocoa.m'))
31
32vnc_ss = ss.source_set()
33vnc_ss.add(files(
34  'vnc.c',
35  'vnc-enc-zlib.c',
36  'vnc-enc-hextile.c',
37  'vnc-enc-tight.c',
38  'vnc-palette.c',
39  'vnc-enc-zrle.c',
40  'vnc-auth-vencrypt.c',
41  'vnc-ws.c',
42  'vnc-jobs.c',
43  'vnc-clipboard.c',
44))
45vnc_ss.add(zlib, jpeg, gnutls)
46vnc_ss.add(when: sasl, if_true: files('vnc-auth-sasl.c'))
47softmmu_ss.add_all(when: vnc, if_true: vnc_ss)
48softmmu_ss.add(when: vnc, if_false: files('vnc-stubs.c'))
49
50ui_modules = {}
51
52if curses.found()
53  curses_ss = ss.source_set()
54  curses_ss.add(when: [curses, iconv], if_true: [files('curses.c'), pixman])
55  ui_modules += {'curses' : curses_ss}
56endif
57
58softmmu_ss.add(opengl)
59if opengl.found()
60  opengl_ss = ss.source_set()
61  opengl_ss.add(gbm)
62  opengl_ss.add(when: [opengl, pixman],
63               if_true: files('shader.c', 'console-gl.c', 'egl-helpers.c', 'egl-context.c'))
64  ui_modules += {'opengl' : opengl_ss}
65endif
66
67if opengl.found() and gbm.found()
68  egl_headless_ss = ss.source_set()
69  egl_headless_ss.add(when: [opengl, gbm, pixman],
70                      if_true: files('egl-headless.c'))
71  ui_modules += {'egl-headless' : egl_headless_ss}
72endif
73
74if dbus_display
75  dbus_ss = ss.source_set()
76  dbus_display1 = custom_target('dbus-display gdbus-codegen',
77                                output: ['dbus-display1.h', 'dbus-display1.c'],
78                                input: files('dbus-display1.xml'),
79                                command: [gdbus_codegen, '@INPUT@',
80                                          '--glib-min-required', '2.64',
81                                          '--output-directory', meson.current_build_dir(),
82                                          '--interface-prefix', 'org.qemu.',
83                                          '--c-namespace', 'QemuDBus',
84                                          '--generate-c-code', '@BASENAME@'])
85  dbus_ss.add(when: [gio, pixman, opengl, gbm],
86              if_true: [files(
87                'dbus-chardev.c',
88                'dbus-clipboard.c',
89                'dbus-console.c',
90                'dbus-error.c',
91                'dbus-listener.c',
92                'dbus.c',
93              ), dbus_display1])
94  ui_modules += {'dbus' : dbus_ss}
95endif
96
97if gtk.found()
98  softmmu_ss.add(when: 'CONFIG_WIN32', if_true: files('win32-kbd-hook.c'))
99
100  gtk_ss = ss.source_set()
101  gtk_ss.add(gtk, vte, pixman, files('gtk.c'))
102  if have_gtk_clipboard
103    gtk_ss.add(files('gtk-clipboard.c'))
104  endif
105  gtk_ss.add(when: x11, if_true: files('x_keymap.c'))
106  gtk_ss.add(when: opengl, if_true: files('gtk-gl-area.c'))
107  gtk_ss.add(when: [x11, opengl], if_true: files('gtk-egl.c'))
108  ui_modules += {'gtk' : gtk_ss}
109endif
110
111if sdl.found()
112  softmmu_ss.add(when: 'CONFIG_WIN32', if_true: files('win32-kbd-hook.c'))
113
114  sdl_ss = ss.source_set()
115  sdl_ss.add(sdl, sdl_image, pixman, glib, files(
116    'sdl2-2d.c',
117    'sdl2-input.c',
118    'sdl2.c',
119  ))
120  sdl_ss.add(when: opengl, if_true: files('sdl2-gl.c'))
121  sdl_ss.add(when: x11, if_true: files('x_keymap.c'))
122  ui_modules += {'sdl' : sdl_ss}
123endif
124
125if spice.found()
126  spice_core_ss = ss.source_set()
127  spice_core_ss.add(spice, pixman, files(
128    'spice-core.c',
129    'spice-input.c',
130    'spice-display.c'
131  ))
132  ui_modules += {'spice-core' : spice_core_ss}
133endif
134
135if spice.found() and gio.found()
136  spice_ss = ss.source_set()
137  spice_ss.add(spice, gio, pixman, files('spice-app.c'))
138  ui_modules += {'spice-app': spice_ss}
139endif
140
141keymaps = [
142  ['atset1', 'qcode'],
143  ['linux', 'qcode'],
144  ['qcode', 'atset1'],
145  ['qcode', 'atset2'],
146  ['qcode', 'atset3'],
147  ['qcode', 'linux'],
148  ['qcode', 'qnum'],
149  ['qcode', 'sun'],
150  ['qnum', 'qcode'],
151  ['usb', 'qcode'],
152  ['win32', 'qcode'],
153  ['x11', 'qcode'],
154  ['xorgevdev', 'qcode'],
155  ['xorgkbd', 'qcode'],
156  ['xorgxquartz', 'qcode'],
157  ['xorgxwin', 'qcode'],
158  ['osx', 'qcode'],
159]
160
161if have_system or xkbcommon.found()
162  foreach e : keymaps
163    output = 'input-keymap-@0@-to-@1@.c.inc'.format(e[0], e[1])
164    genh += custom_target(output,
165                  output: output,
166                  capture: true,
167                  input: files('keycodemapdb/data/keymaps.csv'),
168                  command: [python, files('keycodemapdb/tools/keymap-gen'),
169                            'code-map',
170                            '--lang', 'glib2',
171                            '--varname', 'qemu_input_map_@0@_to_@1@'.format(e[0], e[1]),
172                            '@INPUT0@', e[0], e[1]])
173  endforeach
174endif
175
176subdir('shader')
177
178if have_system
179  subdir('icons')
180
181  install_data('qemu.desktop', install_dir: qemu_desktopdir)
182endif
183
184modules += {'ui': ui_modules}
185