xref: /openbmc/qemu/trace/meson.build (revision 9921e3d3) 
1specific_ss.add(files('control-target.c'))
2
3trace_events_files = []
4foreach dir : [ '.' ] + trace_events_subdirs
5  trace_events_file = meson.source_root() / dir / 'trace-events'
6  trace_events_files += [ trace_events_file ]
7  group_name = dir == '.' ? 'root' : dir.underscorify()
8  group = '--group=' + group_name
9  fmt = '@0@-' + group_name + '.@1@'
10
11  trace_h = custom_target(fmt.format('trace', 'h'),
12                          output: fmt.format('trace', 'h'),
13                          input: trace_events_file,
14                          command: [ tracetool, group, '--format=h', '@INPUT@' ],
15                          capture: true)
16  genh += trace_h
17  trace_c = custom_target(fmt.format('trace', 'c'),
18                          output: fmt.format('trace', 'c'),
19                          input: trace_events_file,
20                          command: [ tracetool, group, '--format=c', '@INPUT@' ],
21                          capture: true)
22  if 'CONFIG_TRACE_UST' in config_host
23    trace_ust_h = custom_target(fmt.format('trace-ust', 'h'),
24                                output: fmt.format('trace-ust', 'h'),
25                                input: trace_events_file,
26                                command: [ tracetool, group, '--format=ust-events-h', '@INPUT@' ],
27                                capture: true)
28    trace_ss.add(trace_ust_h, lttng, urcubp)
29    genh += trace_ust_h
30  endif
31  trace_ss.add(trace_h, trace_c)
32  if 'CONFIG_TRACE_DTRACE' in config_host
33    trace_dtrace = custom_target(fmt.format('trace-dtrace', 'dtrace'),
34                                 output: fmt.format('trace-dtrace', 'dtrace'),
35                                 input: trace_events_file,
36                                 command: [ tracetool, group, '--format=d', '@INPUT@' ],
37                                 capture: true)
38    trace_dtrace_h = custom_target(fmt.format('trace-dtrace', 'h'),
39                                   output: fmt.format('trace-dtrace', 'h'),
40                                   input: trace_dtrace,
41                                   command: [ 'dtrace', '-o', '@OUTPUT@', '-h', '-s', '@INPUT@' ])
42    trace_dtrace_o = custom_target(fmt.format('trace-dtrace', 'o'),
43                                   output: fmt.format('trace-dtrace', 'o'),
44                                   input: trace_dtrace,
45                                   command: [ 'dtrace', '-o', '@OUTPUT@', '-G', '-s', '@INPUT@' ])
46
47    trace_ss.add(trace_dtrace_h, trace_dtrace_o)
48    genh += trace_dtrace_h
49  endif
50endforeach
51
52trace_events_all = custom_target('trace-events-all',
53                                 output: 'trace-events-all',
54                                 input: trace_events_files,
55                                 command: [ 'cat', '@INPUT@' ],
56                                 capture: true,
57                                 install: true,
58                                 install_dir: config_host['qemu_datadir'])
59
60foreach d : [
61  ['generated-tcg-tracers.h', 'tcg-h'],
62  ['generated-helpers.c', 'tcg-helper-c'],
63  ['generated-helpers.h', 'tcg-helper-h'],
64  ['generated-helpers-wrappers.h', 'tcg-helper-wrapper-h'],
65]
66  gen = custom_target(d[0],
67                output: d[0],
68                input: meson.source_root() / 'trace-events',
69                command: [ tracetool, '--group=root', '--format=@0@'.format(d[1]), '@INPUT@' ],
70                build_by_default: true, # to be removed when added to a target
71                capture: true)
72  specific_ss.add(gen)
73endforeach
74
75if 'CONFIG_TRACE_UST' in config_host
76  trace_ust_all_h = custom_target('trace-ust-all.h',
77                                  output: 'trace-ust-all.h',
78                                  input: trace_events_files,
79                                  command: [ tracetool, '--group=all', '--format=ust-events-h', '@INPUT@' ],
80                                  capture: true)
81  trace_ust_all_c = custom_target('trace-ust-all.c',
82                                  output: 'trace-ust-all.c',
83                                  input: trace_events_files,
84                                  command: [ tracetool, '--group=all', '--format=ust-events-c', '@INPUT@' ],
85                                  capture: true)
86  trace_ss.add(trace_ust_all_h, trace_ust_all_c)
87  genh += trace_ust_all_h
88endif
89
90trace_ss.add(when: 'CONFIG_TRACE_SIMPLE', if_true: files('simple.c'))
91trace_ss.add(when: 'CONFIG_TRACE_FTRACE', if_true: files('ftrace.c'))
92trace_ss.add(files('control.c'))
93trace_ss.add(files('qmp.c'))
94