xref: /openbmc/qemu/trace/meson.build (revision 740b1759) 
1specific_ss.add(files('control-target.c'))
2
3trace_events_files = []
4foreach dir : [ '.' ] + trace_events_subdirs
5  trace_events_file = meson.source_root() / dir / 'trace-events'
6  trace_events_files += [ trace_events_file ]
7  group_name = dir == '.' ? 'root' : dir.underscorify()
8  group = '--group=' + group_name
9  fmt = '@0@-' + group_name + '.@1@'
10
11  trace_h = custom_target(fmt.format('trace', 'h'),
12                          output: fmt.format('trace', 'h'),
13                          input: trace_events_file,
14                          command: [ tracetool, group, '--format=h', '@INPUT@' ],
15                          capture: true)
16  genh += trace_h
17  trace_c = custom_target(fmt.format('trace', 'c'),
18                          output: fmt.format('trace', 'c'),
19                          input: trace_events_file,
20                          command: [ tracetool, group, '--format=c', '@INPUT@' ],
21                          capture: true)
22  if 'CONFIG_TRACE_UST' in config_host
23    trace_ust_h = custom_target(fmt.format('trace-ust', 'h'),
24                                output: fmt.format('trace-ust', 'h'),
25                                input: trace_events_file,
26                                command: [ tracetool, group, '--format=ust-events-h', '@INPUT@' ],
27                                capture: true)
28    trace_ss.add(trace_ust_h, lttng, urcubp)
29    genh += trace_ust_h
30  endif
31  trace_ss.add(trace_h, trace_c)
32  if 'CONFIG_TRACE_DTRACE' in config_host
33    trace_dtrace = custom_target(fmt.format('trace-dtrace', 'dtrace'),
34                                 output: fmt.format('trace-dtrace', 'dtrace'),
35                                 input: trace_events_file,
36                                 command: [ tracetool, group, '--format=d', '@INPUT@' ],
37                                 capture: true)
38    trace_dtrace_h = custom_target(fmt.format('trace-dtrace', 'h'),
39                                   output: fmt.format('trace-dtrace', 'h'),
40                                   input: trace_dtrace,
41                                   command: [ 'dtrace', '-o', '@OUTPUT@', '-h', '-s', '@INPUT@' ])
42    trace_ss.add(trace_dtrace_h)
43    if host_machine.system() != 'darwin'
44      trace_dtrace_o = custom_target(fmt.format('trace-dtrace', 'o'),
45                                     output: fmt.format('trace-dtrace', 'o'),
46                                     input: trace_dtrace,
47                                     command: [ 'dtrace', '-o', '@OUTPUT@', '-G', '-s', '@INPUT@' ])
48      trace_ss.add(trace_dtrace_o)
49    endif
50
51    genh += trace_dtrace_h
52  endif
53endforeach
54
55trace_events_all = custom_target('trace-events-all',
56                                 output: 'trace-events-all',
57                                 input: trace_events_files,
58                                 command: [ 'cat', '@INPUT@' ],
59                                 capture: true,
60                                 install: true,
61                                 install_dir: qemu_datadir)
62
63foreach d : [
64  ['generated-tcg-tracers.h', 'tcg-h'],
65  ['generated-helpers.c', 'tcg-helper-c'],
66  ['generated-helpers.h', 'tcg-helper-h'],
67  ['generated-helpers-wrappers.h', 'tcg-helper-wrapper-h'],
68]
69  gen = custom_target(d[0],
70                output: d[0],
71                input: meson.source_root() / 'trace-events',
72                command: [ tracetool, '--group=root', '--format=@0@'.format(d[1]), '@INPUT@' ],
73                capture: true)
74  specific_ss.add(gen)
75endforeach
76
77if 'CONFIG_TRACE_UST' in config_host
78  trace_ust_all_h = custom_target('trace-ust-all.h',
79                                  output: 'trace-ust-all.h',
80                                  input: trace_events_files,
81                                  command: [ tracetool, '--group=all', '--format=ust-events-h', '@INPUT@' ],
82                                  capture: true)
83  trace_ust_all_c = custom_target('trace-ust-all.c',
84                                  output: 'trace-ust-all.c',
85                                  input: trace_events_files,
86                                  command: [ tracetool, '--group=all', '--format=ust-events-c', '@INPUT@' ],
87                                  capture: true)
88  trace_ss.add(trace_ust_all_h, trace_ust_all_c)
89  genh += trace_ust_all_h
90endif
91
92trace_ss.add(when: 'CONFIG_TRACE_SIMPLE', if_true: files('simple.c'))
93trace_ss.add(when: 'CONFIG_TRACE_FTRACE', if_true: files('ftrace.c'))
94trace_ss.add(files('control.c'))
95trace_ss.add(files('qmp.c'))
96