xref: /openbmc/qemu/tests/unit/meson.build (revision 1d2cb5a8) 
1
2testblock = declare_dependency(dependencies: [block], sources: 'iothread.c')
3
4tests = {
5  'check-block-qdict': [],
6  'check-qdict': [],
7  'check-qnum': [],
8  'check-qstring': [],
9  'check-qlist': [],
10  'check-qnull': [],
11  'check-qobject': [],
12  'check-qjson': [],
13  'check-qlit': [],
14  'test-qobject-output-visitor': [testqapi],
15  'test-clone-visitor': [testqapi],
16  'test-qobject-input-visitor': [testqapi],
17  'test-forward-visitor': [testqapi],
18  'test-string-input-visitor': [testqapi],
19  'test-string-output-visitor': [testqapi],
20  'test-opts-visitor': [testqapi],
21  'test-visitor-serialization': [testqapi],
22  'test-bitmap': [],
23  # all code tested by test-x86-cpuid is inside topology.h
24  'test-x86-cpuid': [],
25  'test-cutils': [],
26  'test-div128': [],
27  'test-shift128': [],
28  'test-mul64': [],
29  # all code tested by test-int128 is inside int128.h
30  'test-int128': [],
31  'rcutorture': [],
32  'test-rcu-list': [],
33  'test-rcu-simpleq': [],
34  'test-rcu-tailq': [],
35  'test-rcu-slist': [],
36  'test-qdist': [],
37  'test-qht': [],
38  'test-bitops': [],
39  'test-bitcnt': [],
40  'test-qgraph': ['../qtest/libqos/qgraph.c'],
41  'check-qom-interface': [qom],
42  'check-qom-proplist': [qom],
43  'test-qemu-opts': [],
44  'test-keyval': [testqapi],
45  'test-logging': [],
46  'test-uuid': [],
47  'ptimer-test': ['ptimer-test-stubs.c', meson.project_source_root() / 'hw/core/ptimer.c'],
48  'test-qapi-util': [],
49  'test-interval-tree': [],
50}
51
52if have_system or have_tools
53  tests += {
54    'test-qmp-event': [testqapi],
55  }
56
57  if seccomp.found()
58    tests += {'test-seccomp': ['../../softmmu/qemu-seccomp.c', seccomp]}
59  endif
60endif
61
62if have_block
63  tests += {
64    'test-coroutine': [testblock],
65    'test-aio': [testblock],
66    'test-aio-multithread': [testblock],
67    'test-throttle': [testblock],
68    'test-thread-pool': [testblock],
69    'test-hbitmap': [testblock],
70    'test-bdrv-drain': [testblock],
71    'test-bdrv-graph-mod': [testblock],
72    'test-blockjob': [testblock],
73    'test-blockjob-txn': [testblock],
74    'test-block-backend': [testblock],
75    'test-block-iothread': [testblock],
76    'test-write-threshold': [testblock],
77    'test-crypto-hash': [crypto],
78    'test-crypto-hmac': [crypto],
79    'test-crypto-cipher': [crypto],
80    'test-crypto-akcipher': [crypto],
81    'test-crypto-secret': [crypto, keyutils],
82    'test-crypto-der': [crypto],
83    'test-authz-simple': [authz],
84    'test-authz-list': [authz],
85    'test-authz-listfile': [authz],
86    'test-io-task': [testblock],
87    'test-io-channel-socket': ['socket-helpers.c', 'io-channel-helpers.c', io],
88    'test-io-channel-file': ['io-channel-helpers.c', io],
89    'test-io-channel-command': ['io-channel-helpers.c', io],
90    'test-io-channel-buffer': ['io-channel-helpers.c', io],
91    'test-io-channel-null': [io],
92    'test-crypto-ivgen': [io],
93    'test-crypto-afsplit': [io],
94    'test-crypto-block': [io],
95  }
96  if gnutls.found() and \
97     tasn1.found() and \
98     'CONFIG_POSIX' in config_host
99    tests += {
100      'test-crypto-tlscredsx509': ['crypto-tls-x509-helpers.c', 'pkix_asn1_tab.c',
101                                   tasn1, crypto, gnutls],
102      'test-crypto-tlssession': ['crypto-tls-x509-helpers.c', 'pkix_asn1_tab.c', 'crypto-tls-psk-helpers.c',
103                                 tasn1, crypto, gnutls],
104      'test-io-channel-tls': ['io-channel-helpers.c', 'crypto-tls-x509-helpers.c', 'pkix_asn1_tab.c',
105                              tasn1, io, crypto, gnutls]}
106  endif
107  if pam.found()
108    tests += {'test-authz-pam': [authz]}
109  endif
110  if xts == 'private'
111    tests += {'test-crypto-xts': [crypto, io]}
112  endif
113  if 'CONFIG_POSIX' in config_host
114    tests += {'test-image-locking': [testblock]}
115  endif
116  if config_host_data.get('CONFIG_REPLICATION')
117    tests += {'test-replication': [testblock]}
118  endif
119  if nettle.found() or gcrypt.found()
120    tests += {'test-crypto-pbkdf': [io]}
121  endif
122  if config_host_data.get('CONFIG_EPOLL_CREATE1')
123    tests += {'test-fdmon-epoll': [testblock]}
124  endif
125endif
126
127if have_system
128  tests += {
129    'test-iov': [],
130    'test-qmp-cmds': [testqapi],
131    'test-xbzrle': [migration],
132    'test-timed-average': [],
133    'test-util-sockets': ['socket-helpers.c'],
134    'test-base64': [],
135    'test-bufferiszero': [],
136    'test-smp-parse': [qom, meson.project_source_root() / 'hw/core/machine-smp.c'],
137    'test-vmstate': [migration, io],
138    'test-yank': ['socket-helpers.c', qom, io, chardev]
139  }
140  if config_host_data.get('CONFIG_INOTIFY1')
141    tests += {'test-util-filemonitor': []}
142  endif
143
144  # Some tests: test-char, test-qdev-global-props, and test-qga,
145  # are not runnable under TSan due to a known issue.
146  # https://github.com/google/sanitizers/issues/1116
147  if 'CONFIG_TSAN' not in config_host
148    if 'CONFIG_POSIX' in config_host
149        tests += {
150          'test-char': ['socket-helpers.c', qom, io, chardev]
151        }
152    endif
153
154    tests += {
155      'test-qdev-global-props': [qom, hwcore]
156    }
157  endif
158endif
159
160if have_ga and targetos == 'linux'
161  tests += {'test-qga': ['../qtest/libqmp.c']}
162  test_deps += {'test-qga': qga}
163endif
164
165test_env = environment()
166test_env.set('G_TEST_SRCDIR', meson.current_source_dir())
167test_env.set('G_TEST_BUILDDIR', meson.current_build_dir())
168
169slow_tests = {
170  'test-crypto-tlscredsx509': 45,
171  'test-crypto-tlssession': 45
172}
173
174foreach test_name, extra: tests
175  src = [test_name + '.c']
176  deps = [qemuutil]
177  if extra.length() > 0
178    # use a sourceset to quickly separate sources and deps
179    test_ss = ss.source_set()
180    test_ss.add(extra)
181    src += test_ss.all_sources()
182    deps += test_ss.all_dependencies()
183  endif
184  exe = executable(test_name, src, genh, dependencies: deps)
185
186  test(test_name, exe,
187       depends: test_deps.get(test_name, []),
188       env: test_env,
189       args: ['--tap', '-k'],
190       protocol: 'tap',
191       timeout: slow_tests.get(test_name, 30),
192       priority: slow_tests.get(test_name, 30),
193       suite: ['unit'])
194endforeach
195