xref: /openbmc/qemu/tests/qtest/meson.build (revision a158c63b) 
1slow_qtests = {
2  'aspeed_smc-test': 360,
3  'bios-tables-test' : 610,
4  'cdrom-test' : 610,
5  'device-introspect-test' : 720,
6  'migration-test' : 480,
7  'npcm7xx_pwm-test': 300,
8  'npcm7xx_watchdog_timer-test': 120,
9  'qom-test' : 900,
10  'test-hmp' : 240,
11  'pxe-test': 610,
12  'prom-env-test': 360,
13  'boot-serial-test': 360,
14  'qos-test': 120,
15  'vmgenid-test': 610,
16}
17
18qtests_generic = [
19  'cdrom-test',
20  'device-introspect-test',
21  'machine-none-test',
22  'qmp-test',
23  'qmp-cmd-test',
24  'qom-test',
25  'test-hmp',
26  'qos-test',
27  'readconfig-test',
28  'netdev-socket',
29]
30if enable_modules
31  qtests_generic += [ 'modules-test' ]
32endif
33
34qtests_pci = \
35  (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : []) +                  \
36  (config_all_devices.has_key('CONFIG_IVSHMEM_DEVICE') ? ['ivshmem-test'] : [])
37
38qtests_cxl = \
39  (config_all_devices.has_key('CONFIG_CXL') ? ['cxl-test'] : [])
40
41# FIXME: Get rid of get_option('default_devices') here and check
42#        for the availability of the default NICs in the tests
43qtests_filter = \
44  (get_option('default_devices') and slirp.found() ? ['test-netfilter'] : []) + \
45  (get_option('default_devices') and host_os != 'windows' ? ['test-filter-mirror'] : []) + \
46  (get_option('default_devices') and host_os != 'windows' ? ['test-filter-redirector'] : [])
47
48qtests_i386 = \
49  (slirp.found() ? ['pxe-test'] : []) + \
50  qtests_filter + \
51  (have_tools ? ['ahci-test'] : []) +                                                       \
52  (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +           \
53  (config_all_devices.has_key('CONFIG_SGA') ? ['boot-serial-test'] : []) +                  \
54  (config_all_devices.has_key('CONFIG_ISA_IPMI_KCS') ? ['ipmi-kcs-test'] : []) +            \
55  (host_os == 'linux' and                                                                  \
56   config_all_devices.has_key('CONFIG_ISA_IPMI_BT') and
57   config_all_devices.has_key('CONFIG_IPMI_EXTERN') ? ['ipmi-bt-test'] : []) +              \
58  (config_all_devices.has_key('CONFIG_WDT_IB700') ? ['wdt_ib700-test'] : []) +              \
59  (config_all_devices.has_key('CONFIG_PVPANIC_ISA') ? ['pvpanic-test'] : []) +              \
60  (config_all_devices.has_key('CONFIG_PVPANIC_PCI') ? ['pvpanic-pci-test'] : []) +          \
61  (config_all_devices.has_key('CONFIG_HDA') ? ['intel-hda-test'] : []) +                    \
62  (config_all_devices.has_key('CONFIG_I82801B11') ? ['i82801b11-test'] : []) +             \
63  (config_all_devices.has_key('CONFIG_IOH3420') ? ['ioh3420-test'] : []) +                  \
64  (config_all_devices.has_key('CONFIG_LPC_ICH9') ? ['lpc-ich9-test'] : []) +              \
65  (config_all_devices.has_key('CONFIG_USB_UHCI') ? ['usb-hcd-uhci-test'] : []) +            \
66  (config_all_devices.has_key('CONFIG_USB_UHCI') and                                        \
67   config_all_devices.has_key('CONFIG_USB_EHCI') ? ['usb-hcd-ehci-test'] : []) +            \
68  (config_all_devices.has_key('CONFIG_USB_XHCI_NEC') ? ['usb-hcd-xhci-test'] : []) +        \
69  (config_all_devices.has_key('CONFIG_TPM_CRB') ? ['tpm-crb-test'] : []) +                  \
70  (config_all_devices.has_key('CONFIG_TPM_CRB') ? ['tpm-crb-swtpm-test'] : []) +            \
71  (config_all_devices.has_key('CONFIG_TPM_TIS_ISA') ? ['tpm-tis-test'] : []) +              \
72  (config_all_devices.has_key('CONFIG_TPM_TIS_ISA') ? ['tpm-tis-swtpm-test'] : []) +        \
73  (config_all_devices.has_key('CONFIG_RTL8139_PCI') ? ['rtl8139-test'] : []) +              \
74  (config_all_devices.has_key('CONFIG_E1000E_PCI_EXPRESS') ? ['fuzz-e1000e-test'] : []) +   \
75  (config_all_devices.has_key('CONFIG_MEGASAS_SCSI_PCI') ? ['fuzz-megasas-test'] : []) +    \
76  (config_all_devices.has_key('CONFIG_LSI_SCSI_PCI') ? ['fuzz-lsi53c895a-test'] : []) +     \
77  (config_all_devices.has_key('CONFIG_VIRTIO_SCSI') ? ['fuzz-virtio-scsi-test'] : []) +     \
78  (config_all_devices.has_key('CONFIG_SB16') ? ['fuzz-sb16-test'] : []) +                   \
79  (config_all_devices.has_key('CONFIG_SDHCI_PCI') ? ['fuzz-sdcard-test'] : []) +            \
80  (config_all_devices.has_key('CONFIG_ESP_PCI') ? ['am53c974-test'] : []) +                 \
81  (host_os != 'windows' and                                                                \
82   config_all_devices.has_key('CONFIG_ACPI_ERST') ? ['erst-test'] : []) +                   \
83  (config_all_devices.has_key('CONFIG_PCIE_PORT') and                                       \
84   config_all_devices.has_key('CONFIG_VIRTIO_NET') and                                      \
85   config_all_devices.has_key('CONFIG_Q35') and                                             \
86   config_all_devices.has_key('CONFIG_VIRTIO_PCI') and                                      \
87   slirp.found() ? ['virtio-net-failover'] : []) +                                          \
88  (unpack_edk2_blobs and                                                                    \
89   config_all_devices.has_key('CONFIG_HPET') and                                            \
90   config_all_devices.has_key('CONFIG_PARALLEL') ? ['bios-tables-test'] : []) +             \
91  qtests_pci +                                                                              \
92  qtests_cxl +                                                                              \
93  ['fdc-test',
94   'ide-test',
95   'hd-geo-test',
96   'boot-order-test',
97   'rtc-test',
98   'i440fx-test',
99   'fw_cfg-test',
100   'device-plug-test',
101   'drive_del-test',
102   'tco-test',
103   'cpu-plug-test',
104   'q35-test',
105   'vmgenid-test',
106   'migration-test',
107   'test-x86-cpuid-compat',
108   'numa-test'
109  ]
110
111if dbus_display
112  qtests_i386 += ['dbus-display-test']
113endif
114
115dbus_daemon = find_program('dbus-daemon', required: false)
116if dbus_daemon.found() and gdbus_codegen.found()
117  # Temporarily disabled due to Patchew failures:
118  #qtests_i386 += ['dbus-vmstate-test']
119  dbus_vmstate1 = custom_target('dbus-vmstate description',
120                                output: ['dbus-vmstate1.h', 'dbus-vmstate1.c'],
121                                input: meson.project_source_root() / 'backends/dbus-vmstate1.xml',
122                                command: [gdbus_codegen, '@INPUT@',
123                                          '--interface-prefix', 'org.qemu',
124                                          '--generate-c-code', '@BASENAME@']).to_list()
125else
126  dbus_vmstate1 = []
127endif
128
129qtests_x86_64 = qtests_i386
130
131qtests_alpha = ['boot-serial-test'] + \
132  qtests_filter + \
133  (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
134
135qtests_avr = [ 'boot-serial-test' ]
136
137qtests_hppa = ['boot-serial-test'] + \
138  qtests_filter + \
139  (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
140
141qtests_m68k = ['boot-serial-test'] + \
142  qtests_filter
143
144qtests_microblaze = ['boot-serial-test'] + \
145  qtests_filter
146
147qtests_microblazeel = qtests_microblaze
148
149qtests_mips = \
150  qtests_filter + \
151  (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
152  (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
153
154qtests_mipsel = qtests_mips
155qtests_mips64 = qtests_mips
156qtests_mips64el = qtests_mips
157
158qtests_ppc = \
159  qtests_filter + \
160  (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
161  (config_all_devices.has_key('CONFIG_M48T59') ? ['m48t59-test'] : []) +                     \
162  (config_all_accel.has_key('CONFIG_TCG') ? ['prom-env-test'] : []) +                              \
163  (config_all_accel.has_key('CONFIG_TCG') ? ['boot-serial-test'] : []) +                           \
164  ['boot-order-test']
165
166qtests_ppc64 = \
167  qtests_ppc + \
168  (config_all_devices.has_key('CONFIG_PSERIES') ? ['device-plug-test'] : []) +               \
169  (config_all_devices.has_key('CONFIG_POWERNV') ? ['pnv-xscom-test'] : []) +                 \
170  (config_all_devices.has_key('CONFIG_POWERNV') ? ['pnv-host-i2c-test'] : []) +              \
171  (config_all_devices.has_key('CONFIG_PSERIES') ? ['rtas-test'] : []) +                      \
172  (slirp.found() ? ['pxe-test'] : []) +              \
173  (config_all_devices.has_key('CONFIG_USB_UHCI') ? ['usb-hcd-uhci-test'] : []) +             \
174  (config_all_devices.has_key('CONFIG_USB_XHCI_NEC') ? ['usb-hcd-xhci-test'] : []) +         \
175  qtests_pci + ['migration-test', 'numa-test', 'cpu-plug-test', 'drive_del-test']
176
177qtests_sh4 = (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : [])
178qtests_sh4eb = (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : [])
179
180qtests_sparc = ['prom-env-test', 'm48t59-test', 'boot-serial-test'] + \
181  qtests_filter
182
183qtests_sparc64 = \
184  (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
185  qtests_filter + \
186  ['prom-env-test', 'boot-serial-test']
187
188qtests_npcm7xx = \
189  ['npcm7xx_adc-test',
190   'npcm7xx_gpio-test',
191   'npcm7xx_pwm-test',
192   'npcm7xx_rng-test',
193   'npcm7xx_sdhci-test',
194   'npcm7xx_smbus-test',
195   'npcm7xx_timer-test',
196   'npcm7xx_watchdog_timer-test',
197   'npcm_gmac-test'] + \
198   (slirp.found() ? ['npcm7xx_emc-test'] : [])
199qtests_aspeed = \
200  ['aspeed_hace-test',
201   'aspeed_smc-test',
202   'aspeed_gpio-test']
203
204qtests_stm32l4x5 = \
205  ['stm32l4x5_exti-test',
206   'stm32l4x5_syscfg-test',
207   'stm32l4x5_rcc-test',
208   'stm32l4x5_gpio-test']
209
210qtests_arm = \
211  (config_all_devices.has_key('CONFIG_MPS2') ? ['sse-timer-test'] : []) + \
212  (config_all_devices.has_key('CONFIG_CMSDK_APB_DUALTIMER') ? ['cmsdk-apb-dualtimer-test'] : []) + \
213  (config_all_devices.has_key('CONFIG_CMSDK_APB_TIMER') ? ['cmsdk-apb-timer-test'] : []) + \
214  (config_all_devices.has_key('CONFIG_CMSDK_APB_WATCHDOG') ? ['cmsdk-apb-watchdog-test'] : []) + \
215  (config_all_devices.has_key('CONFIG_PFLASH_CFI02') and
216   config_all_devices.has_key('CONFIG_MUSICPAL') ? ['pflash-cfi02-test'] : []) + \
217  (config_all_devices.has_key('CONFIG_ASPEED_SOC') ? qtests_aspeed : []) + \
218  (config_all_devices.has_key('CONFIG_NPCM7XX') ? qtests_npcm7xx : []) + \
219  (config_all_devices.has_key('CONFIG_GENERIC_LOADER') ? ['hexloader-test'] : []) + \
220  (config_all_devices.has_key('CONFIG_TPM_TIS_I2C') ? ['tpm-tis-i2c-test'] : []) + \
221  (config_all_devices.has_key('CONFIG_VEXPRESS') ? ['test-arm-mptimer'] : []) + \
222  (config_all_devices.has_key('CONFIG_MICROBIT') ? ['microbit-test'] : []) + \
223  (config_all_devices.has_key('CONFIG_STM32L4X5_SOC') ? qtests_stm32l4x5 : []) + \
224  (config_all_devices.has_key('CONFIG_FSI_APB2OPB_ASPEED') ? ['aspeed_fsi-test'] : []) + \
225  ['arm-cpu-features',
226   'boot-serial-test']
227
228# TODO: once aarch64 TCG is fixed on ARM 32 bit host, make bios-tables-test unconditional
229qtests_aarch64 = \
230  (cpu != 'arm' and unpack_edk2_blobs ? ['bios-tables-test'] : []) +                            \
231  (config_all_accel.has_key('CONFIG_TCG') and config_all_devices.has_key('CONFIG_TPM_TIS_SYSBUS') ?            \
232    ['tpm-tis-device-test', 'tpm-tis-device-swtpm-test'] : []) +                                         \
233  (config_all_devices.has_key('CONFIG_XLNX_ZYNQMP_ARM') ? ['xlnx-can-test', 'fuzz-xlnx-dp-test'] : []) + \
234  (config_all_devices.has_key('CONFIG_XLNX_VERSAL') ? ['xlnx-canfd-test', 'xlnx-versal-trng-test'] : []) + \
235  (config_all_devices.has_key('CONFIG_RASPI') ? ['bcm2835-dma-test', 'bcm2835-i2c-test'] : []) +  \
236  (config_all_accel.has_key('CONFIG_TCG') and                                            \
237   config_all_devices.has_key('CONFIG_TPM_TIS_I2C') ? ['tpm-tis-i2c-test'] : []) + \
238  ['arm-cpu-features',
239   'numa-test',
240   'boot-serial-test',
241   'migration-test']
242
243qtests_s390x = \
244  qtests_filter + \
245  ['boot-serial-test',
246   'drive_del-test',
247   'device-plug-test',
248   'virtio-ccw-test',
249   'cpu-plug-test',
250   'migration-test']
251
252qtests_riscv32 = \
253  (config_all_devices.has_key('CONFIG_SIFIVE_E_AON') ? ['sifive-e-aon-watchdog-test'] : [])
254
255qos_test_ss = ss.source_set()
256qos_test_ss.add(
257  'ac97-test.c',
258  'adm1272-test.c',
259  'adm1266-test.c',
260  'ds1338-test.c',
261  'e1000-test.c',
262  'eepro100-test.c',
263  'es1370-test.c',
264  'ipoctal232-test.c',
265  'lsm303dlhc-mag-test.c',
266  'isl_pmbus_vr-test.c',
267  'max34451-test.c',
268  'megasas-test.c',
269  'ne2000-test.c',
270  'tulip-test.c',
271  'nvme-test.c',
272  'pca9552-test.c',
273  'pci-test.c',
274  'pcnet-test.c',
275  'sdhci-test.c',
276  'spapr-phb-test.c',
277  'tmp105-test.c',
278  'emc141x-test.c',
279  'usb-hcd-ohci-test.c',
280  'virtio-test.c',
281  'virtio-blk-test.c',
282  'virtio-net-test.c',
283  'virtio-rng-test.c',
284  'virtio-scsi-test.c',
285  'virtio-iommu-test.c',
286  'vmxnet3-test.c',
287  'igb-test.c',
288  'ufs-test.c',
289)
290
291if config_all_devices.has_key('CONFIG_VIRTIO_SERIAL')
292  qos_test_ss.add(files('virtio-serial-test.c'))
293endif
294
295if host_os != 'windows'
296  qos_test_ss.add(files('e1000e-test.c'))
297endif
298if have_virtfs
299  qos_test_ss.add(files('virtio-9p-test.c'))
300endif
301if have_vhost_user
302  qos_test_ss.add(files('vhost-user-test.c'))
303endif
304if have_tools and have_vhost_user_blk_server
305  qos_test_ss.add(files('vhost-user-blk-test.c'))
306endif
307
308tpmemu_files = ['tpm-emu.c', 'tpm-util.c', 'tpm-tests.c']
309
310migration_files = [files('migration-helpers.c')]
311if gnutls.found()
312  migration_files += [files('../unit/crypto-tls-psk-helpers.c'), gnutls]
313
314  if tasn1.found()
315    migration_files += [files('../unit/crypto-tls-x509-helpers.c',
316                              '../unit/pkix_asn1_tab.c'), tasn1]
317  endif
318endif
319
320qtests = {
321  'bios-tables-test': [io, 'boot-sector.c', 'acpi-utils.c', 'tpm-emu.c'],
322  'cdrom-test': files('boot-sector.c'),
323  'dbus-vmstate-test': files('migration-helpers.c') + dbus_vmstate1,
324  'erst-test': files('erst-test.c'),
325  'ivshmem-test': [rt, '../../contrib/ivshmem-server/ivshmem-server.c'],
326  'migration-test': migration_files,
327  'pxe-test': files('boot-sector.c'),
328  'qos-test': [chardev, io, qos_test_ss.apply({}).sources()],
329  'tpm-crb-swtpm-test': [io, tpmemu_files],
330  'tpm-crb-test': [io, tpmemu_files],
331  'tpm-tis-swtpm-test': [io, tpmemu_files, 'tpm-tis-util.c'],
332  'tpm-tis-test': [io, tpmemu_files, 'tpm-tis-util.c'],
333  'tpm-tis-i2c-test': [io, tpmemu_files, 'qtest_aspeed.c'],
334  'tpm-tis-device-swtpm-test': [io, tpmemu_files, 'tpm-tis-util.c'],
335  'tpm-tis-device-test': [io, tpmemu_files, 'tpm-tis-util.c'],
336  'virtio-net-failover': files('migration-helpers.c'),
337  'vmgenid-test': files('boot-sector.c', 'acpi-utils.c'),
338  'netdev-socket': files('netdev-socket.c', '../unit/socket-helpers.c'),
339}
340
341if vnc.found()
342  gvnc = dependency('gvnc-1.0', method: 'pkg-config', required: false)
343  if gvnc.found()
344    qtests += {'vnc-display-test': [gvnc]}
345    qtests_generic += [ 'vnc-display-test' ]
346  endif
347endif
348
349if dbus_display
350  qtests += {'dbus-display-test': [dbus_display1_dep, gio]}
351endif
352
353qtest_executables = {}
354foreach dir : target_dirs
355  if not dir.endswith('-softmmu')
356    continue
357  endif
358
359  target_base = dir.split('-')[0]
360  qtest_emulator = emulators['qemu-system-' + target_base]
361  target_qtests = get_variable('qtests_' + target_base, []) + qtests_generic
362
363  test_deps = roms
364  qtest_env = environment()
365  if have_tools
366    qtest_env.set('QTEST_QEMU_IMG', './qemu-img')
367    test_deps += [qemu_img]
368  endif
369  qtest_env.set('G_TEST_DBUS_DAEMON', meson.project_source_root() / 'tests/dbus-vmstate-daemon.sh')
370  qtest_env.set('QTEST_QEMU_BINARY', './qemu-system-' + target_base)
371  if have_tools and have_vhost_user_blk_server
372    qtest_env.set('QTEST_QEMU_STORAGE_DAEMON_BINARY', './storage-daemon/qemu-storage-daemon')
373    test_deps += [qsd]
374  endif
375
376  qtest_env.set('PYTHON', python.full_path())
377
378  foreach test : target_qtests
379    # Executables are shared across targets, declare them only the first time we
380    # encounter them
381    if not qtest_executables.has_key(test)
382      src = [test + '.c']
383      deps = [qemuutil, qos]
384      if test in qtests
385        # use a sourceset to quickly separate sources and deps
386        test_ss = ss.source_set()
387        test_ss.add(qtests[test])
388        src += test_ss.all_sources()
389        deps += test_ss.all_dependencies()
390      endif
391      qtest_executables += {
392        test: executable(test, src, dependencies: deps)
393      }
394    endif
395    test('qtest-@0@/@1@'.format(target_base, test),
396         qtest_executables[test],
397         depends: [test_deps, qtest_emulator, emulator_modules],
398         env: qtest_env,
399         args: ['--tap', '-k'],
400         protocol: 'tap',
401         timeout: slow_qtests.get(test, 60),
402         priority: slow_qtests.get(test, 60),
403         suite: ['qtest', 'qtest-' + target_base])
404  endforeach
405endforeach
406