xref: /openbmc/qemu/tests/qtest/meson.build (revision 154fd4d1) 
1slow_qtests = {
2  'ahci-test': 150,
3  'aspeed_smc-test': 360,
4  'bios-tables-test' : 910,
5  'cdrom-test' : 610,
6  'device-introspect-test' : 720,
7  'migration-test' : 480,
8  'npcm7xx_pwm-test': 300,
9  'npcm7xx_watchdog_timer-test': 120,
10  'qom-test' : 900,
11  'stm32l4x5_usart-test' : 600,
12  'test-hmp' : 240,
13  'pxe-test': 610,
14  'prom-env-test': 360,
15  'boot-serial-test': 360,
16  'qos-test': 120,
17  'vmgenid-test': 610,
18}
19
20qtests_generic = [
21  'cdrom-test',
22  'device-introspect-test',
23  'machine-none-test',
24  'qmp-test',
25  'qmp-cmd-test',
26  'qom-test',
27  'test-hmp',
28  'qos-test',
29  'readconfig-test',
30  'netdev-socket',
31]
32if enable_modules
33  qtests_generic += [ 'modules-test' ]
34endif
35
36qtests_pci = \
37  (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : []) +                  \
38  (config_all_devices.has_key('CONFIG_IVSHMEM_DEVICE') ? ['ivshmem-test'] : [])
39
40qtests_cxl = \
41  (config_all_devices.has_key('CONFIG_CXL') ? ['cxl-test'] : [])
42
43# FIXME: Get rid of get_option('default_devices') here and check
44#        for the availability of the default NICs in the tests
45qtests_filter = \
46  (get_option('default_devices') and slirp.found() ? ['test-netfilter'] : []) + \
47  (get_option('default_devices') and host_os != 'windows' ? ['test-filter-mirror'] : []) + \
48  (get_option('default_devices') and host_os != 'windows' ? ['test-filter-redirector'] : [])
49
50qtests_i386 = \
51  (slirp.found() ? ['pxe-test'] : []) + \
52  qtests_filter + \
53  (have_tools ? ['ahci-test'] : []) +                                                       \
54  (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +           \
55  (config_all_devices.has_key('CONFIG_SGA') ? ['boot-serial-test'] : []) +                  \
56  (config_all_devices.has_key('CONFIG_ISA_IPMI_KCS') ? ['ipmi-kcs-test'] : []) +            \
57  (host_os == 'linux' and                                                                  \
58   config_all_devices.has_key('CONFIG_ISA_IPMI_BT') and
59   config_all_devices.has_key('CONFIG_IPMI_EXTERN') ? ['ipmi-bt-test'] : []) +              \
60  (config_all_devices.has_key('CONFIG_WDT_IB700') ? ['wdt_ib700-test'] : []) +              \
61  (config_all_devices.has_key('CONFIG_PVPANIC_ISA') ? ['pvpanic-test'] : []) +              \
62  (config_all_devices.has_key('CONFIG_PVPANIC_PCI') ? ['pvpanic-pci-test'] : []) +          \
63  (config_all_devices.has_key('CONFIG_HDA') ? ['intel-hda-test'] : []) +                    \
64  (config_all_devices.has_key('CONFIG_I82801B11') ? ['i82801b11-test'] : []) +             \
65  (config_all_devices.has_key('CONFIG_IOH3420') ? ['ioh3420-test'] : []) +                  \
66  (config_all_devices.has_key('CONFIG_LPC_ICH9') ? ['lpc-ich9-test'] : []) +              \
67  (config_all_devices.has_key('CONFIG_USB_UHCI') ? ['usb-hcd-uhci-test'] : []) +            \
68  (config_all_devices.has_key('CONFIG_USB_UHCI') and                                        \
69   config_all_devices.has_key('CONFIG_USB_EHCI') ? ['usb-hcd-ehci-test'] : []) +            \
70  (config_all_devices.has_key('CONFIG_USB_XHCI_NEC') ? ['usb-hcd-xhci-test'] : []) +        \
71  (config_all_devices.has_key('CONFIG_TPM_CRB') ? ['tpm-crb-test'] : []) +                  \
72  (config_all_devices.has_key('CONFIG_TPM_CRB') ? ['tpm-crb-swtpm-test'] : []) +            \
73  (config_all_devices.has_key('CONFIG_TPM_TIS_ISA') ? ['tpm-tis-test'] : []) +              \
74  (config_all_devices.has_key('CONFIG_TPM_TIS_ISA') ? ['tpm-tis-swtpm-test'] : []) +        \
75  (config_all_devices.has_key('CONFIG_RTL8139_PCI') ? ['rtl8139-test'] : []) +              \
76  (config_all_devices.has_key('CONFIG_E1000E_PCI_EXPRESS') ? ['fuzz-e1000e-test'] : []) +   \
77  (config_all_devices.has_key('CONFIG_MEGASAS_SCSI_PCI') ? ['fuzz-megasas-test'] : []) +    \
78  (config_all_devices.has_key('CONFIG_LSI_SCSI_PCI') ? ['fuzz-lsi53c895a-test'] : []) +     \
79  (config_all_devices.has_key('CONFIG_VIRTIO_SCSI') ? ['fuzz-virtio-scsi-test'] : []) +     \
80  (config_all_devices.has_key('CONFIG_SB16') ? ['fuzz-sb16-test'] : []) +                   \
81  (config_all_devices.has_key('CONFIG_SDHCI_PCI') ? ['fuzz-sdcard-test'] : []) +            \
82  (config_all_devices.has_key('CONFIG_ESP_PCI') ? ['am53c974-test'] : []) +                 \
83  (host_os != 'windows' and                                                                \
84   config_all_devices.has_key('CONFIG_ACPI_ERST') ? ['erst-test'] : []) +                   \
85  (config_all_devices.has_key('CONFIG_PCIE_PORT') and                                       \
86   config_all_devices.has_key('CONFIG_VIRTIO_NET') and                                      \
87   config_all_devices.has_key('CONFIG_Q35') and                                             \
88   config_all_devices.has_key('CONFIG_VIRTIO_PCI') and                                      \
89   slirp.found() ? ['virtio-net-failover'] : []) +                                          \
90  (unpack_edk2_blobs and                                                                    \
91   config_all_devices.has_key('CONFIG_HPET') and                                            \
92   config_all_devices.has_key('CONFIG_PARALLEL') ? ['bios-tables-test'] : []) +             \
93  qtests_pci +                                                                              \
94  qtests_cxl +                                                                              \
95  ['fdc-test',
96   'ide-test',
97   'hd-geo-test',
98   'boot-order-test',
99   'rtc-test',
100   'i440fx-test',
101   'fw_cfg-test',
102   'device-plug-test',
103   'drive_del-test',
104   'tco-test',
105   'cpu-plug-test',
106   'q35-test',
107   'vmgenid-test',
108   'migration-test',
109   'test-x86-cpuid-compat',
110   'numa-test'
111  ]
112
113if dbus_display
114  qtests_i386 += ['dbus-display-test']
115endif
116
117dbus_daemon = find_program('dbus-daemon', required: false)
118if dbus_daemon.found() and gdbus_codegen.found()
119  # Temporarily disabled due to Patchew failures:
120  #qtests_i386 += ['dbus-vmstate-test']
121  dbus_vmstate1 = custom_target('dbus-vmstate description',
122                                output: ['dbus-vmstate1.h', 'dbus-vmstate1.c'],
123                                input: meson.project_source_root() / 'backends/dbus-vmstate1.xml',
124                                command: [gdbus_codegen, '@INPUT@',
125                                          '--interface-prefix', 'org.qemu',
126                                          '--generate-c-code', '@BASENAME@']).to_list()
127else
128  dbus_vmstate1 = []
129endif
130
131qtests_x86_64 = qtests_i386
132
133qtests_alpha = ['boot-serial-test'] + \
134  qtests_filter + \
135  (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
136
137qtests_avr = [ 'boot-serial-test' ]
138
139qtests_hppa = ['boot-serial-test'] + \
140  qtests_filter + \
141  (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
142
143qtests_loongarch64 = qtests_filter + \
144  ['boot-serial-test', 'numa-test']
145
146qtests_m68k = ['boot-serial-test'] + \
147  qtests_filter
148
149qtests_microblaze = ['boot-serial-test'] + \
150  qtests_filter
151
152qtests_microblazeel = qtests_microblaze
153
154qtests_mips = \
155  qtests_filter + \
156  (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
157  (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
158
159qtests_mipsel = qtests_mips
160qtests_mips64 = qtests_mips
161qtests_mips64el = qtests_mips
162
163qtests_ppc = \
164  qtests_filter + \
165  (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
166  (config_all_devices.has_key('CONFIG_M48T59') ? ['m48t59-test'] : []) +                     \
167  (config_all_accel.has_key('CONFIG_TCG') ? ['prom-env-test'] : []) +                              \
168  (config_all_accel.has_key('CONFIG_TCG') ? ['boot-serial-test'] : []) +                           \
169  ['boot-order-test']
170
171qtests_ppc64 = \
172  qtests_ppc + \
173  (config_all_devices.has_key('CONFIG_PSERIES') ? ['device-plug-test'] : []) +               \
174  (config_all_devices.has_key('CONFIG_POWERNV') ? ['pnv-xscom-test'] : []) +                 \
175  (config_all_devices.has_key('CONFIG_POWERNV') ? ['pnv-spi-seeprom-test'] : []) +           \
176  (config_all_devices.has_key('CONFIG_POWERNV') ? ['pnv-host-i2c-test'] : []) +              \
177  (config_all_devices.has_key('CONFIG_PSERIES') ? ['rtas-test'] : []) +                      \
178  (slirp.found() ? ['pxe-test'] : []) +              \
179  (config_all_devices.has_key('CONFIG_USB_UHCI') ? ['usb-hcd-uhci-test'] : []) +             \
180  (config_all_devices.has_key('CONFIG_USB_XHCI_NEC') ? ['usb-hcd-xhci-test'] : []) +         \
181  qtests_pci + ['migration-test', 'numa-test', 'cpu-plug-test', 'drive_del-test']
182
183qtests_sh4 = (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : [])
184qtests_sh4eb = (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : [])
185
186qtests_sparc = ['prom-env-test', 'm48t59-test', 'boot-serial-test'] + \
187  qtests_filter
188
189qtests_sparc64 = \
190  (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
191  qtests_filter + \
192  ['prom-env-test', 'boot-serial-test']
193
194qtests_npcm7xx = \
195  ['npcm7xx_adc-test',
196   'npcm7xx_gpio-test',
197   'npcm7xx_pwm-test',
198   'npcm7xx_rng-test',
199   'npcm7xx_sdhci-test',
200   'npcm7xx_smbus-test',
201   'npcm7xx_timer-test',
202   'npcm7xx_watchdog_timer-test',
203   'npcm_gmac-test'] + \
204   (slirp.found() ? ['npcm7xx_emc-test'] : [])
205qtests_aspeed = \
206  ['aspeed_hace-test',
207   'aspeed_smc-test',
208   'aspeed_gpio-test']
209
210qtests_stm32l4x5 = \
211  ['stm32l4x5_exti-test',
212   'stm32l4x5_syscfg-test',
213   'stm32l4x5_rcc-test',
214   'stm32l4x5_gpio-test',
215   'stm32l4x5_usart-test']
216
217qtests_arm = \
218  (config_all_devices.has_key('CONFIG_MPS2') ? ['sse-timer-test'] : []) + \
219  (config_all_devices.has_key('CONFIG_CMSDK_APB_DUALTIMER') ? ['cmsdk-apb-dualtimer-test'] : []) + \
220  (config_all_devices.has_key('CONFIG_CMSDK_APB_TIMER') ? ['cmsdk-apb-timer-test'] : []) + \
221  (config_all_devices.has_key('CONFIG_CMSDK_APB_WATCHDOG') ? ['cmsdk-apb-watchdog-test'] : []) + \
222  (config_all_devices.has_key('CONFIG_PFLASH_CFI02') and
223   config_all_devices.has_key('CONFIG_MUSICPAL') ? ['pflash-cfi02-test'] : []) + \
224  (config_all_devices.has_key('CONFIG_ASPEED_SOC') ? qtests_aspeed : []) + \
225  (config_all_devices.has_key('CONFIG_NPCM7XX') ? qtests_npcm7xx : []) + \
226  (config_all_devices.has_key('CONFIG_GENERIC_LOADER') ? ['hexloader-test'] : []) + \
227  (config_all_devices.has_key('CONFIG_TPM_TIS_I2C') ? ['tpm-tis-i2c-test'] : []) + \
228  (config_all_devices.has_key('CONFIG_VEXPRESS') ? ['test-arm-mptimer'] : []) + \
229  (config_all_devices.has_key('CONFIG_MICROBIT') ? ['microbit-test'] : []) + \
230  (config_all_devices.has_key('CONFIG_STM32L4X5_SOC') ? qtests_stm32l4x5 : []) + \
231  (config_all_devices.has_key('CONFIG_FSI_APB2OPB_ASPEED') ? ['aspeed_fsi-test'] : []) + \
232  (config_all_devices.has_key('CONFIG_STM32L4X5_SOC') and
233   config_all_devices.has_key('CONFIG_DM163')? ['dm163-test'] : []) + \
234  ['arm-cpu-features',
235   'boot-serial-test']
236
237# TODO: once aarch64 TCG is fixed on ARM 32 bit host, make bios-tables-test unconditional
238qtests_aarch64 = \
239  (cpu != 'arm' and unpack_edk2_blobs ? ['bios-tables-test'] : []) +                            \
240  (config_all_accel.has_key('CONFIG_TCG') and config_all_devices.has_key('CONFIG_TPM_TIS_SYSBUS') ?            \
241    ['tpm-tis-device-test', 'tpm-tis-device-swtpm-test'] : []) +                                         \
242  (config_all_devices.has_key('CONFIG_XLNX_ZYNQMP_ARM') ? ['xlnx-can-test', 'fuzz-xlnx-dp-test'] : []) + \
243  (config_all_devices.has_key('CONFIG_XLNX_VERSAL') ? ['xlnx-canfd-test', 'xlnx-versal-trng-test'] : []) + \
244  (config_all_devices.has_key('CONFIG_RASPI') ? ['bcm2835-dma-test', 'bcm2835-i2c-test'] : []) +  \
245  (config_all_accel.has_key('CONFIG_TCG') and                                            \
246   config_all_devices.has_key('CONFIG_TPM_TIS_I2C') ? ['tpm-tis-i2c-test'] : []) + \
247  ['arm-cpu-features',
248   'numa-test',
249   'boot-serial-test',
250   'migration-test']
251
252qtests_s390x = \
253  qtests_filter + \
254  ['boot-serial-test',
255   'drive_del-test',
256   'device-plug-test',
257   'virtio-ccw-test',
258   'cpu-plug-test',
259   'migration-test']
260
261qtests_riscv32 = \
262  (config_all_devices.has_key('CONFIG_SIFIVE_E_AON') ? ['sifive-e-aon-watchdog-test'] : [])
263
264qtests_riscv64 = \
265  (unpack_edk2_blobs ? ['bios-tables-test'] : [])
266
267qos_test_ss = ss.source_set()
268qos_test_ss.add(
269  'ac97-test.c',
270  'adm1272-test.c',
271  'adm1266-test.c',
272  'ds1338-test.c',
273  'e1000-test.c',
274  'eepro100-test.c',
275  'es1370-test.c',
276  'ipoctal232-test.c',
277  'lsm303dlhc-mag-test.c',
278  'isl_pmbus_vr-test.c',
279  'max34451-test.c',
280  'megasas-test.c',
281  'ne2000-test.c',
282  'tulip-test.c',
283  'nvme-test.c',
284  'pca9552-test.c',
285  'pci-test.c',
286  'pcnet-test.c',
287  'sdhci-test.c',
288  'spapr-phb-test.c',
289  'tmp105-test.c',
290  'emc141x-test.c',
291  'usb-hcd-ohci-test.c',
292  'virtio-test.c',
293  'virtio-blk-test.c',
294  'virtio-net-test.c',
295  'virtio-rng-test.c',
296  'virtio-scsi-test.c',
297  'virtio-iommu-test.c',
298  'vmxnet3-test.c',
299  'igb-test.c',
300  'ufs-test.c',
301)
302
303if config_all_devices.has_key('CONFIG_VIRTIO_SERIAL')
304  qos_test_ss.add(files('virtio-serial-test.c'))
305endif
306
307if host_os != 'windows'
308  qos_test_ss.add(files('e1000e-test.c'))
309endif
310if have_virtfs
311  qos_test_ss.add(files('virtio-9p-test.c'))
312endif
313if have_vhost_user
314  qos_test_ss.add(files('vhost-user-test.c'))
315endif
316if have_tools and have_vhost_user_blk_server
317  qos_test_ss.add(files('vhost-user-blk-test.c'))
318endif
319
320tpmemu_files = ['tpm-emu.c', 'tpm-util.c', 'tpm-tests.c']
321
322migration_files = [files('migration-helpers.c')]
323if gnutls.found()
324  migration_files += [files('../unit/crypto-tls-psk-helpers.c'), gnutls]
325
326  if tasn1.found()
327    migration_files += [files('../unit/crypto-tls-x509-helpers.c'), tasn1]
328  endif
329endif
330
331qtests = {
332  'bios-tables-test': [io, 'boot-sector.c', 'acpi-utils.c', 'tpm-emu.c'],
333  'cdrom-test': files('boot-sector.c'),
334  'dbus-vmstate-test': files('migration-helpers.c') + dbus_vmstate1,
335  'erst-test': files('erst-test.c'),
336  'ivshmem-test': [rt, '../../contrib/ivshmem-server/ivshmem-server.c'],
337  'migration-test': migration_files,
338  'pxe-test': files('boot-sector.c'),
339  'qos-test': [chardev, io, qos_test_ss.apply({}).sources()],
340  'tpm-crb-swtpm-test': [io, tpmemu_files],
341  'tpm-crb-test': [io, tpmemu_files],
342  'tpm-tis-swtpm-test': [io, tpmemu_files, 'tpm-tis-util.c'],
343  'tpm-tis-test': [io, tpmemu_files, 'tpm-tis-util.c'],
344  'tpm-tis-i2c-test': [io, tpmemu_files, 'qtest_aspeed.c'],
345  'tpm-tis-device-swtpm-test': [io, tpmemu_files, 'tpm-tis-util.c'],
346  'tpm-tis-device-test': [io, tpmemu_files, 'tpm-tis-util.c'],
347  'virtio-net-failover': files('migration-helpers.c'),
348  'vmgenid-test': files('boot-sector.c', 'acpi-utils.c'),
349  'netdev-socket': files('netdev-socket.c', '../unit/socket-helpers.c'),
350}
351
352if vnc.found()
353  gvnc = dependency('gvnc-1.0', method: 'pkg-config', required: false)
354  if gvnc.found()
355    qtests += {'vnc-display-test': [gvnc]}
356    qtests_generic += [ 'vnc-display-test' ]
357  endif
358endif
359
360if dbus_display
361  qtests += {'dbus-display-test': [dbus_display1, gio]}
362endif
363
364qtest_executables = {}
365foreach dir : target_dirs
366  if not dir.endswith('-softmmu')
367    continue
368  endif
369
370  target_base = dir.split('-')[0]
371  qtest_emulator = emulators['qemu-system-' + target_base]
372  target_qtests = get_variable('qtests_' + target_base, []) + qtests_generic
373
374  test_deps = roms
375  qtest_env = environment()
376  if have_tools
377    qtest_env.set('QTEST_QEMU_IMG', './qemu-img')
378    test_deps += [qemu_img]
379  endif
380  qtest_env.set('G_TEST_DBUS_DAEMON', meson.project_source_root() / 'tests/dbus-vmstate-daemon.sh')
381  qtest_env.set('QTEST_QEMU_BINARY', './qemu-system-' + target_base)
382  if have_tools and have_vhost_user_blk_server
383    qtest_env.set('QTEST_QEMU_STORAGE_DAEMON_BINARY', './storage-daemon/qemu-storage-daemon')
384    test_deps += [qsd]
385  endif
386
387  qtest_env.set('PYTHON', python.full_path())
388
389  foreach test : target_qtests
390    # Executables are shared across targets, declare them only the first time we
391    # encounter them
392    if not qtest_executables.has_key(test)
393      src = [test + '.c']
394      deps = [qemuutil, qos]
395      if test in qtests
396        # use a sourceset to quickly separate sources and deps
397        test_ss = ss.source_set()
398        test_ss.add(qtests[test])
399        src += test_ss.all_sources()
400        deps += test_ss.all_dependencies()
401      endif
402      qtest_executables += {
403        test: executable(test, src, dependencies: deps)
404      }
405    endif
406    test('qtest-@0@/@1@'.format(target_base, test),
407         qtest_executables[test],
408         depends: [test_deps, qtest_emulator, emulator_modules],
409         env: qtest_env,
410         args: ['--tap', '-k'],
411         protocol: 'tap',
412         timeout: slow_qtests.get(test, 60),
413         priority: slow_qtests.get(test, 60),
414         suite: ['qtest', 'qtest-' + target_base])
415  endforeach
416endforeach
417