xref: /openbmc/qemu/tests/qtest/meson.build (revision 0f130d9e) 
1slow_qtests = {
2  'aspeed_smc-test': 360,
3  'bios-tables-test' : 610,
4  'cdrom-test' : 610,
5  'device-introspect-test' : 720,
6  'migration-test' : 480,
7  'npcm7xx_pwm-test': 300,
8  'npcm7xx_watchdog_timer-test': 120,
9  'qom-test' : 900,
10  'stm32l4x5_usart-test' : 600,
11  'test-hmp' : 240,
12  'pxe-test': 610,
13  'prom-env-test': 360,
14  'boot-serial-test': 360,
15  'qos-test': 120,
16  'vmgenid-test': 610,
17}
18
19qtests_generic = [
20  'cdrom-test',
21  'device-introspect-test',
22  'machine-none-test',
23  'qmp-test',
24  'qmp-cmd-test',
25  'qom-test',
26  'test-hmp',
27  'qos-test',
28  'readconfig-test',
29  'netdev-socket',
30]
31if enable_modules
32  qtests_generic += [ 'modules-test' ]
33endif
34
35qtests_pci = \
36  (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : []) +                  \
37  (config_all_devices.has_key('CONFIG_IVSHMEM_DEVICE') ? ['ivshmem-test'] : [])
38
39qtests_cxl = \
40  (config_all_devices.has_key('CONFIG_CXL') ? ['cxl-test'] : [])
41
42# FIXME: Get rid of get_option('default_devices') here and check
43#        for the availability of the default NICs in the tests
44qtests_filter = \
45  (get_option('default_devices') and slirp.found() ? ['test-netfilter'] : []) + \
46  (get_option('default_devices') and host_os != 'windows' ? ['test-filter-mirror'] : []) + \
47  (get_option('default_devices') and host_os != 'windows' ? ['test-filter-redirector'] : [])
48
49qtests_i386 = \
50  (slirp.found() ? ['pxe-test'] : []) + \
51  qtests_filter + \
52  (have_tools ? ['ahci-test'] : []) +                                                       \
53  (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +           \
54  (config_all_devices.has_key('CONFIG_SGA') ? ['boot-serial-test'] : []) +                  \
55  (config_all_devices.has_key('CONFIG_ISA_IPMI_KCS') ? ['ipmi-kcs-test'] : []) +            \
56  (host_os == 'linux' and                                                                  \
57   config_all_devices.has_key('CONFIG_ISA_IPMI_BT') and
58   config_all_devices.has_key('CONFIG_IPMI_EXTERN') ? ['ipmi-bt-test'] : []) +              \
59  (config_all_devices.has_key('CONFIG_WDT_IB700') ? ['wdt_ib700-test'] : []) +              \
60  (config_all_devices.has_key('CONFIG_PVPANIC_ISA') ? ['pvpanic-test'] : []) +              \
61  (config_all_devices.has_key('CONFIG_PVPANIC_PCI') ? ['pvpanic-pci-test'] : []) +          \
62  (config_all_devices.has_key('CONFIG_HDA') ? ['intel-hda-test'] : []) +                    \
63  (config_all_devices.has_key('CONFIG_I82801B11') ? ['i82801b11-test'] : []) +             \
64  (config_all_devices.has_key('CONFIG_IOH3420') ? ['ioh3420-test'] : []) +                  \
65  (config_all_devices.has_key('CONFIG_LPC_ICH9') ? ['lpc-ich9-test'] : []) +              \
66  (config_all_devices.has_key('CONFIG_USB_UHCI') ? ['usb-hcd-uhci-test'] : []) +            \
67  (config_all_devices.has_key('CONFIG_USB_UHCI') and                                        \
68   config_all_devices.has_key('CONFIG_USB_EHCI') ? ['usb-hcd-ehci-test'] : []) +            \
69  (config_all_devices.has_key('CONFIG_USB_XHCI_NEC') ? ['usb-hcd-xhci-test'] : []) +        \
70  (config_all_devices.has_key('CONFIG_TPM_CRB') ? ['tpm-crb-test'] : []) +                  \
71  (config_all_devices.has_key('CONFIG_TPM_CRB') ? ['tpm-crb-swtpm-test'] : []) +            \
72  (config_all_devices.has_key('CONFIG_TPM_TIS_ISA') ? ['tpm-tis-test'] : []) +              \
73  (config_all_devices.has_key('CONFIG_TPM_TIS_ISA') ? ['tpm-tis-swtpm-test'] : []) +        \
74  (config_all_devices.has_key('CONFIG_RTL8139_PCI') ? ['rtl8139-test'] : []) +              \
75  (config_all_devices.has_key('CONFIG_E1000E_PCI_EXPRESS') ? ['fuzz-e1000e-test'] : []) +   \
76  (config_all_devices.has_key('CONFIG_MEGASAS_SCSI_PCI') ? ['fuzz-megasas-test'] : []) +    \
77  (config_all_devices.has_key('CONFIG_LSI_SCSI_PCI') ? ['fuzz-lsi53c895a-test'] : []) +     \
78  (config_all_devices.has_key('CONFIG_VIRTIO_SCSI') ? ['fuzz-virtio-scsi-test'] : []) +     \
79  (config_all_devices.has_key('CONFIG_SB16') ? ['fuzz-sb16-test'] : []) +                   \
80  (config_all_devices.has_key('CONFIG_SDHCI_PCI') ? ['fuzz-sdcard-test'] : []) +            \
81  (config_all_devices.has_key('CONFIG_ESP_PCI') ? ['am53c974-test'] : []) +                 \
82  (host_os != 'windows' and                                                                \
83   config_all_devices.has_key('CONFIG_ACPI_ERST') ? ['erst-test'] : []) +                   \
84  (config_all_devices.has_key('CONFIG_PCIE_PORT') and                                       \
85   config_all_devices.has_key('CONFIG_VIRTIO_NET') and                                      \
86   config_all_devices.has_key('CONFIG_Q35') and                                             \
87   config_all_devices.has_key('CONFIG_VIRTIO_PCI') and                                      \
88   slirp.found() ? ['virtio-net-failover'] : []) +                                          \
89  (unpack_edk2_blobs and                                                                    \
90   config_all_devices.has_key('CONFIG_HPET') and                                            \
91   config_all_devices.has_key('CONFIG_PARALLEL') ? ['bios-tables-test'] : []) +             \
92  qtests_pci +                                                                              \
93  qtests_cxl +                                                                              \
94  ['fdc-test',
95   'ide-test',
96   'hd-geo-test',
97   'boot-order-test',
98   'rtc-test',
99   'i440fx-test',
100   'fw_cfg-test',
101   'device-plug-test',
102   'drive_del-test',
103   'tco-test',
104   'cpu-plug-test',
105   'q35-test',
106   'vmgenid-test',
107   'migration-test',
108   'test-x86-cpuid-compat',
109   'numa-test'
110  ]
111
112if dbus_display
113  qtests_i386 += ['dbus-display-test']
114endif
115
116dbus_daemon = find_program('dbus-daemon', required: false)
117if dbus_daemon.found() and gdbus_codegen.found()
118  # Temporarily disabled due to Patchew failures:
119  #qtests_i386 += ['dbus-vmstate-test']
120  dbus_vmstate1 = custom_target('dbus-vmstate description',
121                                output: ['dbus-vmstate1.h', 'dbus-vmstate1.c'],
122                                input: meson.project_source_root() / 'backends/dbus-vmstate1.xml',
123                                command: [gdbus_codegen, '@INPUT@',
124                                          '--interface-prefix', 'org.qemu',
125                                          '--generate-c-code', '@BASENAME@']).to_list()
126else
127  dbus_vmstate1 = []
128endif
129
130qtests_x86_64 = qtests_i386
131
132qtests_alpha = ['boot-serial-test'] + \
133  qtests_filter + \
134  (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
135
136qtests_avr = [ 'boot-serial-test' ]
137
138qtests_hppa = ['boot-serial-test'] + \
139  qtests_filter + \
140  (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
141
142qtests_loongarch64 = qtests_filter + \
143  ['boot-serial-test', 'numa-test']
144
145qtests_m68k = ['boot-serial-test'] + \
146  qtests_filter
147
148qtests_microblaze = ['boot-serial-test'] + \
149  qtests_filter
150
151qtests_microblazeel = qtests_microblaze
152
153qtests_mips = \
154  qtests_filter + \
155  (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
156  (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
157
158qtests_mipsel = qtests_mips
159qtests_mips64 = qtests_mips
160qtests_mips64el = qtests_mips
161
162qtests_ppc = \
163  qtests_filter + \
164  (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
165  (config_all_devices.has_key('CONFIG_M48T59') ? ['m48t59-test'] : []) +                     \
166  (config_all_accel.has_key('CONFIG_TCG') ? ['prom-env-test'] : []) +                              \
167  (config_all_accel.has_key('CONFIG_TCG') ? ['boot-serial-test'] : []) +                           \
168  ['boot-order-test']
169
170qtests_ppc64 = \
171  qtests_ppc + \
172  (config_all_devices.has_key('CONFIG_PSERIES') ? ['device-plug-test'] : []) +               \
173  (config_all_devices.has_key('CONFIG_POWERNV') ? ['pnv-xscom-test'] : []) +                 \
174  (config_all_devices.has_key('CONFIG_POWERNV') ? ['pnv-host-i2c-test'] : []) +              \
175  (config_all_devices.has_key('CONFIG_PSERIES') ? ['rtas-test'] : []) +                      \
176  (slirp.found() ? ['pxe-test'] : []) +              \
177  (config_all_devices.has_key('CONFIG_USB_UHCI') ? ['usb-hcd-uhci-test'] : []) +             \
178  (config_all_devices.has_key('CONFIG_USB_XHCI_NEC') ? ['usb-hcd-xhci-test'] : []) +         \
179  qtests_pci + ['migration-test', 'numa-test', 'cpu-plug-test', 'drive_del-test']
180
181qtests_sh4 = (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : [])
182qtests_sh4eb = (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : [])
183
184qtests_sparc = ['prom-env-test', 'm48t59-test', 'boot-serial-test'] + \
185  qtests_filter
186
187qtests_sparc64 = \
188  (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
189  qtests_filter + \
190  ['prom-env-test', 'boot-serial-test']
191
192qtests_npcm7xx = \
193  ['npcm7xx_adc-test',
194   'npcm7xx_gpio-test',
195   'npcm7xx_pwm-test',
196   'npcm7xx_rng-test',
197   'npcm7xx_sdhci-test',
198   'npcm7xx_smbus-test',
199   'npcm7xx_timer-test',
200   'npcm7xx_watchdog_timer-test',
201   'npcm_gmac-test'] + \
202   (slirp.found() ? ['npcm7xx_emc-test'] : [])
203qtests_aspeed = \
204  ['aspeed_hace-test',
205   'aspeed_smc-test',
206   'aspeed_gpio-test']
207
208qtests_stm32l4x5 = \
209  ['stm32l4x5_exti-test',
210   'stm32l4x5_syscfg-test',
211   'stm32l4x5_rcc-test',
212   'stm32l4x5_gpio-test',
213   'stm32l4x5_usart-test']
214
215qtests_arm = \
216  (config_all_devices.has_key('CONFIG_MPS2') ? ['sse-timer-test'] : []) + \
217  (config_all_devices.has_key('CONFIG_CMSDK_APB_DUALTIMER') ? ['cmsdk-apb-dualtimer-test'] : []) + \
218  (config_all_devices.has_key('CONFIG_CMSDK_APB_TIMER') ? ['cmsdk-apb-timer-test'] : []) + \
219  (config_all_devices.has_key('CONFIG_CMSDK_APB_WATCHDOG') ? ['cmsdk-apb-watchdog-test'] : []) + \
220  (config_all_devices.has_key('CONFIG_PFLASH_CFI02') and
221   config_all_devices.has_key('CONFIG_MUSICPAL') ? ['pflash-cfi02-test'] : []) + \
222  (config_all_devices.has_key('CONFIG_ASPEED_SOC') ? qtests_aspeed : []) + \
223  (config_all_devices.has_key('CONFIG_NPCM7XX') ? qtests_npcm7xx : []) + \
224  (config_all_devices.has_key('CONFIG_GENERIC_LOADER') ? ['hexloader-test'] : []) + \
225  (config_all_devices.has_key('CONFIG_TPM_TIS_I2C') ? ['tpm-tis-i2c-test'] : []) + \
226  (config_all_devices.has_key('CONFIG_VEXPRESS') ? ['test-arm-mptimer'] : []) + \
227  (config_all_devices.has_key('CONFIG_MICROBIT') ? ['microbit-test'] : []) + \
228  (config_all_devices.has_key('CONFIG_STM32L4X5_SOC') ? qtests_stm32l4x5 : []) + \
229  (config_all_devices.has_key('CONFIG_FSI_APB2OPB_ASPEED') ? ['aspeed_fsi-test'] : []) + \
230  (config_all_devices.has_key('CONFIG_STM32L4X5_SOC') and
231   config_all_devices.has_key('CONFIG_DM163')? ['dm163-test'] : []) + \
232  ['arm-cpu-features',
233   'boot-serial-test']
234
235# TODO: once aarch64 TCG is fixed on ARM 32 bit host, make bios-tables-test unconditional
236qtests_aarch64 = \
237  (cpu != 'arm' and unpack_edk2_blobs ? ['bios-tables-test'] : []) +                            \
238  (config_all_accel.has_key('CONFIG_TCG') and config_all_devices.has_key('CONFIG_TPM_TIS_SYSBUS') ?            \
239    ['tpm-tis-device-test', 'tpm-tis-device-swtpm-test'] : []) +                                         \
240  (config_all_devices.has_key('CONFIG_XLNX_ZYNQMP_ARM') ? ['xlnx-can-test', 'fuzz-xlnx-dp-test'] : []) + \
241  (config_all_devices.has_key('CONFIG_XLNX_VERSAL') ? ['xlnx-canfd-test', 'xlnx-versal-trng-test'] : []) + \
242  (config_all_devices.has_key('CONFIG_RASPI') ? ['bcm2835-dma-test', 'bcm2835-i2c-test'] : []) +  \
243  (config_all_accel.has_key('CONFIG_TCG') and                                            \
244   config_all_devices.has_key('CONFIG_TPM_TIS_I2C') ? ['tpm-tis-i2c-test'] : []) + \
245  ['arm-cpu-features',
246   'numa-test',
247   'boot-serial-test',
248   'migration-test']
249
250qtests_s390x = \
251  qtests_filter + \
252  ['boot-serial-test',
253   'drive_del-test',
254   'device-plug-test',
255   'virtio-ccw-test',
256   'cpu-plug-test',
257   'migration-test']
258
259qtests_riscv32 = \
260  (config_all_devices.has_key('CONFIG_SIFIVE_E_AON') ? ['sifive-e-aon-watchdog-test'] : [])
261
262qtests_riscv64 = \
263  (unpack_edk2_blobs ? ['bios-tables-test'] : [])
264
265qos_test_ss = ss.source_set()
266qos_test_ss.add(
267  'ac97-test.c',
268  'adm1272-test.c',
269  'adm1266-test.c',
270  'ds1338-test.c',
271  'e1000-test.c',
272  'eepro100-test.c',
273  'es1370-test.c',
274  'ipoctal232-test.c',
275  'lsm303dlhc-mag-test.c',
276  'isl_pmbus_vr-test.c',
277  'max34451-test.c',
278  'megasas-test.c',
279  'ne2000-test.c',
280  'tulip-test.c',
281  'nvme-test.c',
282  'pca9552-test.c',
283  'pci-test.c',
284  'pcnet-test.c',
285  'sdhci-test.c',
286  'spapr-phb-test.c',
287  'tmp105-test.c',
288  'emc141x-test.c',
289  'usb-hcd-ohci-test.c',
290  'virtio-test.c',
291  'virtio-blk-test.c',
292  'virtio-net-test.c',
293  'virtio-rng-test.c',
294  'virtio-scsi-test.c',
295  'virtio-iommu-test.c',
296  'vmxnet3-test.c',
297  'igb-test.c',
298  'ufs-test.c',
299)
300
301if config_all_devices.has_key('CONFIG_VIRTIO_SERIAL')
302  qos_test_ss.add(files('virtio-serial-test.c'))
303endif
304
305if host_os != 'windows'
306  qos_test_ss.add(files('e1000e-test.c'))
307endif
308if have_virtfs
309  qos_test_ss.add(files('virtio-9p-test.c'))
310endif
311if have_vhost_user
312  qos_test_ss.add(files('vhost-user-test.c'))
313endif
314if have_tools and have_vhost_user_blk_server
315  qos_test_ss.add(files('vhost-user-blk-test.c'))
316endif
317
318tpmemu_files = ['tpm-emu.c', 'tpm-util.c', 'tpm-tests.c']
319
320migration_files = [files('migration-helpers.c')]
321if gnutls.found()
322  migration_files += [files('../unit/crypto-tls-psk-helpers.c'), gnutls]
323
324  if tasn1.found()
325    migration_files += [files('../unit/crypto-tls-x509-helpers.c',
326                              '../unit/pkix_asn1_tab.c'), tasn1]
327  endif
328endif
329
330qtests = {
331  'bios-tables-test': [io, 'boot-sector.c', 'acpi-utils.c', 'tpm-emu.c'],
332  'cdrom-test': files('boot-sector.c'),
333  'dbus-vmstate-test': files('migration-helpers.c') + dbus_vmstate1,
334  'erst-test': files('erst-test.c'),
335  'ivshmem-test': [rt, '../../contrib/ivshmem-server/ivshmem-server.c'],
336  'migration-test': migration_files,
337  'pxe-test': files('boot-sector.c'),
338  'qos-test': [chardev, io, qos_test_ss.apply({}).sources()],
339  'tpm-crb-swtpm-test': [io, tpmemu_files],
340  'tpm-crb-test': [io, tpmemu_files],
341  'tpm-tis-swtpm-test': [io, tpmemu_files, 'tpm-tis-util.c'],
342  'tpm-tis-test': [io, tpmemu_files, 'tpm-tis-util.c'],
343  'tpm-tis-i2c-test': [io, tpmemu_files, 'qtest_aspeed.c'],
344  'tpm-tis-device-swtpm-test': [io, tpmemu_files, 'tpm-tis-util.c'],
345  'tpm-tis-device-test': [io, tpmemu_files, 'tpm-tis-util.c'],
346  'virtio-net-failover': files('migration-helpers.c'),
347  'vmgenid-test': files('boot-sector.c', 'acpi-utils.c'),
348  'netdev-socket': files('netdev-socket.c', '../unit/socket-helpers.c'),
349}
350
351if vnc.found()
352  gvnc = dependency('gvnc-1.0', method: 'pkg-config', required: false)
353  if gvnc.found()
354    qtests += {'vnc-display-test': [gvnc]}
355    qtests_generic += [ 'vnc-display-test' ]
356  endif
357endif
358
359if dbus_display
360  qtests += {'dbus-display-test': [dbus_display1, gio]}
361endif
362
363qtest_executables = {}
364foreach dir : target_dirs
365  if not dir.endswith('-softmmu')
366    continue
367  endif
368
369  target_base = dir.split('-')[0]
370  qtest_emulator = emulators['qemu-system-' + target_base]
371  target_qtests = get_variable('qtests_' + target_base, []) + qtests_generic
372
373  test_deps = roms
374  qtest_env = environment()
375  if have_tools
376    qtest_env.set('QTEST_QEMU_IMG', './qemu-img')
377    test_deps += [qemu_img]
378  endif
379  qtest_env.set('G_TEST_DBUS_DAEMON', meson.project_source_root() / 'tests/dbus-vmstate-daemon.sh')
380  qtest_env.set('QTEST_QEMU_BINARY', './qemu-system-' + target_base)
381  if have_tools and have_vhost_user_blk_server
382    qtest_env.set('QTEST_QEMU_STORAGE_DAEMON_BINARY', './storage-daemon/qemu-storage-daemon')
383    test_deps += [qsd]
384  endif
385
386  qtest_env.set('PYTHON', python.full_path())
387
388  foreach test : target_qtests
389    # Executables are shared across targets, declare them only the first time we
390    # encounter them
391    if not qtest_executables.has_key(test)
392      src = [test + '.c']
393      deps = [qemuutil, qos]
394      if test in qtests
395        # use a sourceset to quickly separate sources and deps
396        test_ss = ss.source_set()
397        test_ss.add(qtests[test])
398        src += test_ss.all_sources()
399        deps += test_ss.all_dependencies()
400      endif
401      qtest_executables += {
402        test: executable(test, src, dependencies: deps)
403      }
404    endif
405    test('qtest-@0@/@1@'.format(target_base, test),
406         qtest_executables[test],
407         depends: [test_deps, qtest_emulator, emulator_modules],
408         env: qtest_env,
409         args: ['--tap', '-k'],
410         protocol: 'tap',
411         timeout: slow_qtests.get(test, 60),
412         priority: slow_qtests.get(test, 60),
413         suite: ['qtest', 'qtest-' + target_base])
414  endforeach
415endforeach
416