xref: /openbmc/qemu/tests/meson.build (revision 8fa3b702) 
1py3 = import('python').find_installation()
2
3qht_bench = executable('qht-bench',
4                       sources: 'qht-bench.c',
5                       dependencies: [qemuutil])
6
7executable('atomic_add-bench',
8           sources: files('atomic_add-bench.c'),
9           dependencies: [qemuutil],
10           build_by_default: false)
11
12executable('atomic64-bench',
13           sources: files('atomic64-bench.c'),
14           dependencies: [qemuutil],
15           build_by_default: false)
16
17test_qapi_outputs = [
18  'qapi-builtin-types.c',
19  'qapi-builtin-types.h',
20  'qapi-builtin-visit.c',
21  'qapi-builtin-visit.h',
22  'test-qapi-commands-sub-sub-module.c',
23  'test-qapi-commands-sub-sub-module.h',
24  'test-qapi-commands.c',
25  'test-qapi-commands.h',
26  'test-qapi-emit-events.c',
27  'test-qapi-emit-events.h',
28  'test-qapi-events-sub-sub-module.c',
29  'test-qapi-events-sub-sub-module.h',
30  'test-qapi-events.c',
31  'test-qapi-events.h',
32  'test-qapi-init-commands.c',
33  'test-qapi-init-commands.h',
34  'test-qapi-introspect.c',
35  'test-qapi-introspect.h',
36  'test-qapi-types-sub-sub-module.c',
37  'test-qapi-types-sub-sub-module.h',
38  'test-qapi-types.c',
39  'test-qapi-types.h',
40  'test-qapi-visit-sub-sub-module.c',
41  'test-qapi-visit-sub-sub-module.h',
42  'test-qapi-visit.c',
43  'test-qapi-visit.h',
44]
45
46test_qapi_files = custom_target('Test QAPI files',
47                                output: test_qapi_outputs,
48                                input: files('qapi-schema/qapi-schema-test.json',
49                                             'qapi-schema/include/sub-module.json',
50                                             'qapi-schema/sub-sub-module.json'),
51                                command: [ qapi_gen, '-o', meson.current_build_dir(),
52                                           '-b', '-p', 'test-', '@INPUT0@' ],
53                                depend_files: qapi_gen_depends)
54
55# meson doesn't like generated output in other directories
56# perhaps change qapi_gen to replace / with _, like Meson itself does?
57subdir('include')
58
59libtestqapi = static_library('testqapi', sources: [test_qapi_files, test_qapi_outputs_extra])
60testqapi = declare_dependency(link_with: libtestqapi)
61
62testblock = declare_dependency(dependencies: [block], sources: 'iothread.c')
63
64tests = {
65  'check-block-qdict': [],
66  'check-qdict': [],
67  'check-qnum': [],
68  'check-qstring': [],
69  'check-qlist': [],
70  'check-qnull': [],
71  'check-qobject': [],
72  'check-qjson': [],
73  'check-qlit': [],
74  'test-qobject-output-visitor': [testqapi],
75  'test-clone-visitor': [testqapi],
76  'test-qobject-input-visitor': [testqapi],
77  'test-string-input-visitor': [testqapi],
78  'test-string-output-visitor': [testqapi],
79  'test-qmp-event': [testqapi],
80  'test-opts-visitor': [testqapi],
81  'test-visitor-serialization': [testqapi],
82  'test-bitmap': [],
83  # all code tested by test-x86-cpuid is inside topology.h
84  'test-x86-cpuid': [],
85  'test-cutils': [],
86  'test-shift128': [],
87  'test-mul64': [],
88  # all code tested by test-int128 is inside int128.h
89  'test-int128': [],
90  'rcutorture': [],
91  'test-rcu-list': [],
92  'test-rcu-simpleq': [],
93  'test-rcu-tailq': [],
94  'test-rcu-slist': [],
95  'test-qdist': [],
96  'test-qht': [],
97  'test-bitops': [],
98  'test-bitcnt': [],
99  'test-qgraph': ['qtest/libqos/qgraph.c'],
100  'check-qom-interface': [qom],
101  'check-qom-proplist': [qom],
102  'test-qemu-opts': [],
103  'test-keyval': [testqapi],
104  'test-logging': [],
105  'test-uuid': [],
106  'ptimer-test': ['ptimer-test-stubs.c', meson.source_root() / 'hw/core/ptimer.c'],
107  'test-qapi-util': [],
108}
109
110test_deps = {
111  'test-qht-par': qht_bench,
112}
113
114benchs = {}
115
116if have_block
117  tests += {
118    'test-coroutine': [testblock],
119    'test-aio': [testblock],
120    'test-aio-multithread': [testblock],
121    'test-throttle': [testblock],
122    'test-thread-pool': [testblock],
123    'test-hbitmap': [testblock],
124    'test-bdrv-drain': [testblock],
125    'test-bdrv-graph-mod': [testblock],
126    'test-blockjob': [testblock],
127    'test-blockjob-txn': [testblock],
128    'test-block-backend': [testblock],
129    'test-block-iothread': [testblock],
130    'test-write-threshold': [testblock],
131    'test-crypto-hash': [crypto],
132    'test-crypto-hmac': [crypto],
133    'test-crypto-cipher': [crypto],
134    'test-crypto-secret': [crypto, keyutils],
135    'test-authz-simple': [authz],
136    'test-authz-list': [authz],
137    'test-authz-listfile': [authz],
138    'test-io-task': [testblock],
139    'test-io-channel-socket': ['socket-helpers.c', 'io-channel-helpers.c', io],
140    'test-io-channel-file': ['io-channel-helpers.c', io],
141    'test-io-channel-command': ['io-channel-helpers.c', io],
142    'test-io-channel-buffer': ['io-channel-helpers.c', io],
143    'test-crypto-ivgen': [io],
144    'test-crypto-afsplit': [io],
145    'test-crypto-block': [io],
146  }
147  if 'CONFIG_GNUTLS' in config_host and \
148     'CONFIG_TASN1' in config_host
149    tests += {
150      'test-crypto-tlscredsx509': ['crypto-tls-x509-helpers.c', 'pkix_asn1_tab.c',
151                                   tasn1, crypto],
152      'test-crypto-tlssession': ['crypto-tls-x509-helpers.c', 'pkix_asn1_tab.c', 'crypto-tls-psk-helpers.c',
153                                 tasn1, crypto],
154      'test-io-channel-tls': ['io-channel-helpers.c', 'crypto-tls-x509-helpers.c', 'pkix_asn1_tab.c',
155                              tasn1, io, crypto]}
156  endif
157  if 'CONFIG_AUTH_PAM' in config_host
158    tests += {'test-authz-pam': [authz]}
159  endif
160  if 'CONFIG_QEMU_PRIVATE_XTS' in config_host
161    tests += {'test-crypto-xts': [crypto, io]}
162  endif
163  if 'CONFIG_POSIX' in config_host
164    tests += {'test-image-locking': [testblock]}
165  endif
166  if 'CONFIG_REPLICATION' in config_host
167    tests += {'test-replication': [testblock]}
168  endif
169  if 'CONFIG_NETTLE' in config_host or 'CONFIG_GCRYPT' in config_host
170    tests += {'test-crypto-pbkdf': [io]}
171  endif
172  benchs += {
173     'benchmark-crypto-hash': [crypto],
174     'benchmark-crypto-hmac': [crypto],
175     'benchmark-crypto-cipher': [crypto],
176  }
177endif
178
179if have_system
180  tests += {
181    'test-iov': [],
182    'test-qmp-cmds': [testqapi],
183    'test-xbzrle': [migration],
184    'test-timed-average': [],
185    'test-util-sockets': ['socket-helpers.c'],
186    'test-base64': [],
187    'test-bufferiszero': [],
188    'test-vmstate': [migration, io]
189  }
190  if 'CONFIG_INOTIFY1' in config_host
191    tests += {'test-util-filemonitor': []}
192  endif
193
194  # Some tests: test-char, test-qdev-global-props, and test-qga,
195  # are not runnable under TSan due to a known issue.
196  # https://github.com/google/sanitizers/issues/1116
197  if 'CONFIG_TSAN' not in config_host
198    tests += {
199      'test-char': ['socket-helpers.c', qom, io, chardev],
200      'test-qdev-global-props': [qom, hwcore, testqapi]
201    }
202  endif
203endif
204
205if 'CONFIG_TSAN' not in config_host and \
206   'CONFIG_GUEST_AGENT' in config_host and \
207   'CONFIG_LINUX' in config_host
208  tests += {'test-qga': ['qtest/libqtest.c']}
209  test_deps += {'test-qga': qga}
210endif
211
212test_env = environment()
213test_env.set('G_TEST_SRCDIR', meson.current_source_dir())
214test_env.set('G_TEST_BUILDDIR', meson.current_build_dir())
215
216foreach test_name, extra: tests
217  src = [test_name + '.c']
218  deps = [qemuutil]
219  if extra.length() > 0
220    # use a sourceset to quickly separate sources and deps
221    test_ss = ss.source_set()
222    test_ss.add(extra)
223    src += test_ss.all_sources()
224    deps += test_ss.all_dependencies()
225  endif
226  exe = executable(test_name, src, dependencies: deps)
227
228  test(test_name, exe,
229       depends: test_deps.get(test_name, []),
230       env: test_env,
231       args: ['--tap', '-k'],
232       protocol: 'tap',
233       suite: ['unit'])
234endforeach
235
236foreach bench_name, deps: benchs
237  exe = executable(bench_name, bench_name + '.c',
238                   dependencies: [qemuutil] + deps)
239  benchmark(bench_name, exe,
240            args: ['--tap', '-k'],
241            protocol: 'tap',
242            suite: ['speed'])
243endforeach
244
245if have_tools and 'CONFIG_VHOST_USER' in config_host
246  executable('vhost-user-bridge',
247             sources: files('vhost-user-bridge.c'),
248             link_with: [libvhost_user],
249             dependencies: [qemuutil],
250             build_by_default: false)
251endif
252
253if have_system and 'CONFIG_POSIX' in config_host
254  subdir('qemu-iotests')
255endif
256
257test('decodetree', sh,
258     args: [ files('decode/check.sh'), config_host['PYTHON'], files('../scripts/decodetree.py') ],
259     workdir: meson.current_source_dir() / 'decode',
260     suite: 'decodetree')
261
262subdir('fp')
263
264if 'CONFIG_TCG' in config_host
265  if 'CONFIG_PLUGIN' in config_host
266    subdir('plugin')
267  endif
268endif
269
270subdir('qapi-schema')
271subdir('qtest')
272subdir('migration')
273