xref: /openbmc/qemu/qga/vss-win32/meson.build (revision 6c187695) 
1link_args = cc.get_supported_link_arguments([
2  '-fstack-protector-all',
3  '-fstack-protector-strong',
4  '-Wl,--add-stdcall-alias',
5  '-Wl,--enable-stdcall-fixup'
6])
7
8qga_vss = shared_module(
9  'qga-vss',
10  ['requester.cpp', 'provider.cpp', 'install.cpp', genh],
11  name_prefix: '',
12  cpp_args: ['-Wno-unknown-pragmas', '-Wno-delete-non-virtual-dtor', '-Wno-non-virtual-dtor'],
13  link_args: link_args,
14  vs_module_defs: 'qga-vss.def',
15  dependencies: [
16    glib,
17    socket,
18    cc.find_library('ole32'),
19    cc.find_library('oleaut32'),
20    cc.find_library('shlwapi'),
21    cc.find_library('uuid'),
22    cc.find_library('intl')
23  ]
24)
25
26if midl.found()
27  gen_tlb = custom_target('gen-tlb',
28                          input: 'qga-vss.idl',
29                          output: 'qga-vss.tlb',
30                          command: [midl, '@INPUT@', '/tlb', '@OUTPUT@'])
31else
32  gen_tlb = custom_target('gen-tlb',
33                          input: 'qga-vss.idl',
34                          output: 'qga-vss.tlb',
35                          command: [widl, '-t', '@INPUT@', '-o', '@OUTPUT@'])
36endif
37
38all_qga += [ qga_vss, gen_tlb ]
39