xref: /openbmc/qemu/chardev/meson.build (revision 49e56287) 
1chardev_ss.add(files(
2  'char-fe.c',
3  'char-file.c',
4  'char-io.c',
5  'char-mux.c',
6  'char-null.c',
7  'char-pipe.c',
8  'char-ringbuf.c',
9  'char-serial.c',
10  'char-socket.c',
11  'char-stdio.c',
12  'char-udp.c',
13  'char.c',
14))
15chardev_ss.add(when: 'CONFIG_POSIX', if_true: [files(
16  'char-fd.c',
17  'char-pty.c',
18), util])
19if targetos in ['linux', 'gnu/kfreebsd', 'freebsd', 'dragonfly']
20  chardev_ss.add(files('char-parallel.c'))
21endif
22
23chardev_ss.add(when: 'CONFIG_WIN32', if_true: files(
24  'char-console.c',
25  'char-win-stdio.c',
26  'char-win.c',
27))
28
29chardev_ss = chardev_ss.apply(config_host, strict: false)
30
31softmmu_ss.add(files('msmouse.c', 'wctablet.c', 'testdev.c'))
32
33chardev_modules = {}
34
35if brlapi.found()
36  module_ss = ss.source_set()
37  module_ss.add(when: [brlapi], if_true: [files('baum.c'), pixman])
38  chardev_modules += { 'baum': module_ss }
39endif
40
41if spice.found()
42  module_ss = ss.source_set()
43  module_ss.add(when: [spice], if_true: files('spice.c'))
44  chardev_modules += { 'spice': module_ss }
45endif
46
47modules += { 'chardev': chardev_modules }
48