xref: /openbmc/qemu/block/meson.build (revision b8116f4c) 
1block_ss.add(genh)
2block_ss.add(files(
3  'accounting.c',
4  'aio_task.c',
5  'amend.c',
6  'backup.c',
7  'blkdebug.c',
8  'blklogwrites.c',
9  'blkverify.c',
10  'block-backend.c',
11  'block-copy.c',
12  'commit.c',
13  'copy-before-write.c',
14  'copy-on-read.c',
15  'create.c',
16  'crypto.c',
17  'dirty-bitmap.c',
18  'filter-compress.c',
19  'graph-lock.c',
20  'io.c',
21  'mirror.c',
22  'nbd.c',
23  'null.c',
24  'preallocate.c',
25  'progress_meter.c',
26  'qapi.c',
27  'qcow2.c',
28  'qcow2-bitmap.c',
29  'qcow2-cache.c',
30  'qcow2-cluster.c',
31  'qcow2-refcount.c',
32  'qcow2-snapshot.c',
33  'qcow2-threads.c',
34  'quorum.c',
35  'raw-format.c',
36  'reqlist.c',
37  'snapshot.c',
38  'snapshot-access.c',
39  'throttle.c',
40  'throttle-groups.c',
41  'write-threshold.c',
42), zstd, zlib, gnutls)
43
44system_ss.add(when: 'CONFIG_TCG', if_true: files('blkreplay.c'))
45system_ss.add(files('block-ram-registrar.c'))
46
47if get_option('qcow1').allowed()
48  block_ss.add(files('qcow.c'))
49endif
50if get_option('vdi').allowed()
51  block_ss.add(files('vdi.c'))
52endif
53if get_option('vhdx').allowed()
54  block_ss.add(files(
55    'vhdx-endian.c',
56    'vhdx-log.c',
57    'vhdx.c'
58  ))
59endif
60if get_option('vmdk').allowed()
61  block_ss.add(files('vmdk.c'))
62endif
63if get_option('vpc').allowed()
64  block_ss.add(files('vpc.c'))
65endif
66if get_option('cloop').allowed()
67  block_ss.add(files('cloop.c'))
68endif
69if get_option('bochs').allowed()
70  block_ss.add(files('bochs.c'))
71endif
72if get_option('vvfat').allowed()
73  block_ss.add(files('vvfat.c'))
74endif
75if get_option('dmg').allowed()
76  block_ss.add(files('dmg.c'))
77endif
78if get_option('qed').allowed()
79  block_ss.add(files(
80    'qed-check.c',
81    'qed-cluster.c',
82    'qed-l2-cache.c',
83    'qed-table.c',
84    'qed.c',
85  ))
86endif
87if get_option('parallels').allowed()
88  block_ss.add(files('parallels.c', 'parallels-ext.c'))
89endif
90
91if host_os == 'windows'
92  block_ss.add(files('file-win32.c', 'win32-aio.c'))
93else
94  block_ss.add(files('file-posix.c'), coref, iokit)
95endif
96block_ss.add(when: libiscsi, if_true: files('iscsi-opts.c'))
97if host_os == 'linux'
98  block_ss.add(files('nvme.c'))
99endif
100if get_option('replication').allowed()
101  block_ss.add(files('replication.c'))
102endif
103block_ss.add(when: libaio, if_true: files('linux-aio.c'))
104block_ss.add(when: linux_io_uring, if_true: files('io_uring.c'))
105
106block_modules = {}
107
108modsrc = []
109foreach m : [
110  [blkio, 'blkio', files('blkio.c')],
111  [curl, 'curl', files('curl.c')],
112  [glusterfs, 'gluster', files('gluster.c')],
113  [libiscsi, 'iscsi', files('iscsi.c')],
114  [libnfs, 'nfs', files('nfs.c')],
115  [libssh, 'ssh', files('ssh.c')],
116  [rbd, 'rbd', files('rbd.c')],
117]
118  if m[0].found()
119    module_ss = ss.source_set()
120    module_ss.add(when: m[0], if_true: m[2])
121    if enable_modules
122      modsrc += m[2]
123    endif
124    block_modules += {m[1] : module_ss}
125  endif
126endforeach
127
128# those are not exactly regular block modules, so treat them apart
129if get_option('dmg').allowed()
130  foreach m : [
131    [liblzfse, 'dmg-lzfse', liblzfse, 'dmg-lzfse.c'],
132    [libbzip2, 'dmg-bz2', [glib, libbzip2], 'dmg-bz2.c']
133  ]
134    if m[0].found()
135      module_ss = ss.source_set()
136      module_ss.add(when: m[2], if_true: files(m[3]))
137      block_modules += {m[1] : module_ss}
138    endif
139  endforeach
140endif
141
142module_block_py = find_program('../scripts/modules/module_block.py')
143module_block_h = custom_target('module_block.h',
144                               output: 'module_block.h',
145                               input: modsrc,
146                               command: [module_block_py, '@OUTPUT0@', modsrc])
147block_ss.add(module_block_h)
148
149wrapper_py = find_program('../scripts/block-coroutine-wrapper.py')
150block_gen_c = custom_target('block-gen.c',
151                            output: 'block-gen.c',
152                            input: files(
153                                      '../include/block/block-io.h',
154                                      '../include/block/dirty-bitmap.h',
155                                      '../include/block/block_int-io.h',
156                                      '../include/block/block-global-state.h',
157                                      '../include/sysemu/block-backend-global-state.h',
158                                      '../include/sysemu/block-backend-io.h',
159                                      'coroutines.h'
160                                      ),
161                            command: [wrapper_py, '@OUTPUT@', '@INPUT@'])
162block_ss.add(block_gen_c)
163
164block_ss.add(files('stream.c'))
165
166system_ss.add(files('qapi-sysemu.c'))
167
168subdir('export')
169subdir('monitor')
170
171modules += {'block': block_modules}
172