xref: /openbmc/pldm/meson.build (revision fa084700) 
1project('pldm', ['c', 'cpp'],
2        version: '0.1', meson_version: '>=1.1.1',
3        default_options: [
4          'warning_level=3',
5          'default_library=shared',
6          'werror=true',
7          'cpp_std=c++23',
8          'buildtype=debugoptimized'
9        ])
10
11# Wno-psabi reduces the number of "Note:" messages when cross-compiling some STL
12# stuff for ARM. See https://stackoverflow.com/questions/48149323/strange-gcc-warning-when-compiling-qt-project
13# Basically, gcc 6 and gcc 7 are not ABI compatible, but since the whole OpenBMC
14# project uses the same compiler, we can safely ignmore these info notes.
15add_project_arguments('-Wno-psabi', language: 'cpp')
16
17
18# Disable FORTIFY_SOURCE when compiling with no optimization
19if(get_option('optimization') == '0')
20  add_project_arguments('-U_FORTIFY_SOURCE',language:['cpp','c'])
21  message('Disabling FORTIFY_SOURCE as optimization is set to 0')
22endif
23
24package_datadir = join_paths(get_option('prefix'), get_option('datadir'), meson.project_name())
25package_localstatedir = join_paths(get_option('prefix'), get_option('localstatedir'), meson.project_name())
26
27conf_data = configuration_data()
28cpp = meson.get_compiler('cpp')
29
30# Enable POSIX poll APIs in libpldm
31if cpp.has_header('poll.h')
32    conf_data.set('PLDM_HAS_POLL', 1)
33endif
34if get_option('libpldmresponder').allowed()
35conf_data.set_quoted('BIOS_JSONS_DIR', join_paths(package_datadir, 'bios'))
36conf_data.set('SYSTEM_SPECIFIC_BIOS_JSON', get_option('system-specific-bios-json').allowed())
37conf_data.set_quoted('BIOS_TABLES_DIR', join_paths(package_localstatedir, 'bios'))
38conf_data.set_quoted('PDR_JSONS_DIR', join_paths(package_datadir, 'pdr'))
39conf_data.set_quoted('FRU_JSONS_DIR', join_paths(package_datadir, 'fru'))
40conf_data.set_quoted('FRU_MASTER_JSON', join_paths(package_datadir, 'fru_master.json'))
41conf_data.set_quoted('ENTITY_MAP_JSON', join_paths(package_datadir, 'entityMap.json'))
42conf_data.set_quoted('HOST_JSONS_DIR', join_paths(package_datadir, 'host'))
43conf_data.set_quoted('EVENTS_JSONS_DIR', join_paths(package_datadir, 'events'))
44conf_data.set('HEARTBEAT_TIMEOUT', get_option('heartbeat-timeout-seconds'))
45conf_data.set('TERMINUS_ID', get_option('terminus-id'))
46conf_data.set('TERMINUS_HANDLE',get_option('terminus-handle'))
47conf_data.set('DBUS_TIMEOUT', get_option('dbus-timeout-value'))
48add_project_arguments('-DLIBPLDMRESPONDER', language : ['c','cpp'])
49endif
50if get_option('softoff').allowed()
51  conf_data.set('SOFTOFF_TIMEOUT_SECONDS', get_option('softoff-timeout-seconds'))
52  conf_data.set_quoted('SOFTOFF_CONFIG_JSON', join_paths(package_datadir, 'softoff'))
53endif
54if get_option('oem-ibm').allowed()
55  conf_data.set_quoted('FILE_TABLE_JSON', join_paths(package_datadir, 'fileTable.json'))
56  conf_data.set_quoted('LID_RUNNING_DIR', '/var/lib/phosphor-software-manager/hostfw/running')
57  conf_data.set_quoted('LID_ALTERNATE_DIR', '/var/lib/phosphor-software-manager/hostfw/alternate')
58  conf_data.set_quoted('LID_STAGING_DIR', '/var/lib/phosphor-software-manager/hostfw/staging')
59  conf_data.set_quoted('LID_RUNNING_PATCH_DIR', '/usr/local/share/hostfw/running')
60  conf_data.set_quoted('LID_ALTERNATE_PATCH_DIR', '/usr/local/share/hostfw/alternate')
61  conf_data.set('DMA_MAXSIZE', get_option('oem-ibm-dma-maxsize'))
62  add_project_arguments('-DOEM_IBM', language : ['c', 'cpp'])
63endif
64conf_data.set('NUMBER_OF_REQUEST_RETRIES', get_option('number-of-request-retries'))
65conf_data.set('INSTANCE_ID_EXPIRATION_INTERVAL',get_option('instance-id-expiration-interval'))
66conf_data.set('RESPONSE_TIME_OUT',get_option('response-time-out'))
67conf_data.set('FLIGHT_RECORDER_MAX_ENTRIES',get_option('flightrecorder-max-entries'))
68conf_data.set_quoted('HOST_EID_PATH', join_paths(package_datadir, 'host_eid'))
69conf_data.set('MAXIMUM_TRANSFER_SIZE', get_option('maximum-transfer-size'))
70if get_option('transport-implementation') == 'mctp-demux'
71  conf_data.set('PLDM_TRANSPORT_WITH_MCTP_DEMUX', 1)
72elif get_option('transport-implementation') == 'af-mctp'
73  conf_data.set('PLDM_TRANSPORT_WITH_AF_MCTP', 1)
74endif
75
76configure_file(output: 'config.h',
77  configuration: conf_data
78)
79
80add_project_arguments('-include', '@0@'.format(meson.current_build_dir() /'config.h'), language: 'cpp')
81
82filesystem = import('fs')
83
84phosphor_dbus_interfaces = dependency('phosphor-dbus-interfaces')
85sdbusplus = dependency('sdbusplus')
86sdeventplus = dependency('sdeventplus')
87stdplus = dependency('stdplus')
88phosphor_logging_dep = dependency('phosphor-logging')
89
90nlohmann_json_dep = dependency('nlohmann_json', include_type: 'system')
91
92if cpp.has_header('CLI/CLI.hpp')
93  CLI11_dep = declare_dependency()
94else
95  CLI11_dep = dependency('CLI11')
96endif
97
98if get_option('tests').allowed()
99    gtest = dependency('gtest', main: true, disabler: true, required: false)
100    gmock = dependency('gmock', disabler: true, required: false)
101    if not gtest.found() or not gmock.found()
102        gtest_proj = import('cmake').subproject('googletest', required: false)
103        if gtest_proj.found()
104            gtest = declare_dependency(
105                dependencies: [
106                    dependency('threads'),
107                    gtest_proj.dependency('gtest'),
108                    gtest_proj.dependency('gtest_main'),
109                ]
110            )
111            gmock = gtest_proj.dependency('gmock')
112        else
113            assert(
114                not get_option('tests').allowed(),
115                'Googletest is required if tests are enabled'
116            )
117        endif
118    endif
119endif
120
121libpldm_dep = dependency('libpldm', fallback:['libpldm','libpldm_dep'], include_type: 'system')
122
123
124libpldmutils_headers = ['.']
125libpldmutils = library(
126  'pldmutils',
127  'common/transport.cpp',
128  'common/utils.cpp',
129  version: meson.project_version(),
130  dependencies: [
131      libpldm_dep,
132      phosphor_dbus_interfaces,
133      phosphor_logging_dep,
134      nlohmann_json_dep,
135      sdbusplus,
136  ],
137  install: true,
138  include_directories: include_directories(libpldmutils_headers),
139)
140
141libpldmutils = declare_dependency(
142  include_directories: include_directories(libpldmutils_headers),
143  link_with: libpldmutils)
144
145deps = [
146  libpldm_dep,
147  libpldmutils,
148  nlohmann_json_dep,
149  phosphor_dbus_interfaces,
150  phosphor_logging_dep,
151  sdbusplus,
152  sdeventplus,
153  stdplus,
154]
155
156if get_option('libpldmresponder').allowed()
157subdir('libpldmresponder')
158deps += [
159  libpldmresponder_dep
160]
161endif
162
163executable(
164  'pldmd',
165  'pldmd/pldmd.cpp',
166  'pldmd/dbus_impl_pdr.cpp',
167  'fw-update/inventory_manager.cpp',
168  'fw-update/package_parser.cpp',
169  'fw-update/device_updater.cpp',
170  'fw-update/watch.cpp',
171  'fw-update/update_manager.cpp',
172  'requester/mctp_endpoint_discovery.cpp',
173  implicit_include_directories: false,
174  dependencies: deps,
175  install: true,
176  install_dir: get_option('bindir'))
177
178if get_option('systemd').allowed()
179  systemd_system_unit_dir = dependency('systemd').get_variable(
180          'systemdsystemunitdir')
181  filesystem.copyfile(
182    'pldmd/service_files/pldmd.service',
183    'pldmd.service',
184    install: true,
185    install_dir: systemd_system_unit_dir
186  )
187
188  if get_option('oem-ibm').allowed()
189    subdir('oem/ibm/service_files')
190  endif
191endif
192
193subdir('pldmtool')
194
195subdir('configurations')
196
197if get_option('utilities').allowed()
198  subdir('utilities')
199endif
200
201if get_option('softoff').allowed()
202  subdir('softoff')
203endif
204
205if get_option('tests').allowed()
206  subdir('common/test')
207  subdir('fw-update/test')
208  subdir('host-bmc/test')
209  subdir('requester/test')
210  subdir('test')
211endif
212