xref: /openbmc/pldm/meson.build (revision f47694ff) 
1project('pldm', ['c', 'cpp'],
2        version: '0.1', meson_version: '>=0.57.0',
3        default_options: [
4          'warning_level=3',
5          'default_library=shared',
6          'werror=true',
7          'cpp_std=c++20',
8          'buildtype=debugoptimized'
9        ])
10
11# Wno-psabi reduces the number of "Note:" messages when cross-compiling some STL
12# stuff for ARM. See https://stackoverflow.com/questions/48149323/strange-gcc-warning-when-compiling-qt-project
13# Basically, gcc 6 and gcc 7 are not ABI compatible, but since the whole OpenBMC
14# project uses the same compiler, we can safely ignmore these info notes.
15add_project_arguments('-Wno-psabi', language: 'cpp')
16
17
18# Disable FORTIFY_SOURCE when compiling with no optimization
19if(get_option('optimization') == '0')
20  add_project_arguments('-U_FORTIFY_SOURCE',language:['cpp','c'])
21  message('Disabling FORTIFY_SOURCE as optimization is set to 0')
22endif
23
24package_datadir = join_paths(get_option('prefix'), get_option('datadir'), meson.project_name())
25package_localstatedir = join_paths(get_option('prefix'), get_option('localstatedir'), meson.project_name())
26
27conf_data = configuration_data()
28if get_option('libpldmresponder').enabled()
29conf_data.set_quoted('BIOS_JSONS_DIR', join_paths(package_datadir, 'bios'))
30conf_data.set_quoted('BIOS_TABLES_DIR', join_paths(package_localstatedir, 'bios'))
31conf_data.set_quoted('PDR_JSONS_DIR', join_paths(package_datadir, 'pdr'))
32conf_data.set_quoted('FRU_JSONS_DIR', join_paths(package_datadir, 'fru'))
33conf_data.set_quoted('FRU_MASTER_JSON', join_paths(package_datadir, 'fru_master.json'))
34conf_data.set_quoted('HOST_JSONS_DIR', join_paths(package_datadir, 'host'))
35conf_data.set_quoted('EVENTS_JSONS_DIR', join_paths(package_datadir, 'events'))
36conf_data.set('HEARTBEAT_TIMEOUT', get_option('heartbeat-timeout-seconds'))
37conf_data.set('TERMINUS_ID', get_option('terminus-id'))
38conf_data.set('TERMINUS_HANDLE',get_option('terminus-handle'))
39add_project_arguments('-DLIBPLDMRESPONDER', language : ['c','cpp'])
40endif
41if get_option('softoff').enabled()
42  conf_data.set('SOFTOFF_TIMEOUT_SECONDS', get_option('softoff-timeout-seconds'))
43endif
44if get_option('oem-ibm').enabled()
45  conf_data.set_quoted('FILE_TABLE_JSON', join_paths(package_datadir, 'fileTable.json'))
46  conf_data.set_quoted('LID_RUNNING_DIR', '/var/lib/phosphor-software-manager/hostfw/running')
47  conf_data.set_quoted('LID_ALTERNATE_DIR', '/var/lib/phosphor-software-manager/hostfw/alternate')
48  conf_data.set_quoted('LID_STAGING_DIR', '/var/lib/phosphor-software-manager/hostfw/staging')
49  conf_data.set_quoted('LID_RUNNING_PATCH_DIR', '/usr/local/share/hostfw/running')
50  conf_data.set_quoted('LID_ALTERNATE_PATCH_DIR', '/usr/local/share/hostfw/alternate')
51  conf_data.set('DMA_MAXSIZE', get_option('oem-ibm-dma-maxsize'))
52  add_project_arguments('-DOEM_IBM', language : 'c')
53  add_project_arguments('-DOEM_IBM', language : 'cpp')
54endif
55conf_data.set('PLDM_VERBOSITY',get_option('verbosity'))
56conf_data.set('NUMBER_OF_REQUEST_RETRIES', get_option('number-of-request-retries'))
57conf_data.set('INSTANCE_ID_EXPIRATION_INTERVAL',get_option('instance-id-expiration-interval'))
58conf_data.set('RESPONSE_TIME_OUT',get_option('response-time-out'))
59conf_data.set('FLIGHT_RECORDER_MAX_ENTRIES',get_option('flightrecorder-max-entries'))
60if get_option('libpldm-only').disabled()
61  conf_data.set_quoted('HOST_EID_PATH', join_paths(package_datadir, 'host_eid'))
62endif
63conf_data.set('MAXIMUM_TRANSFER_SIZE', get_option('maximum-transfer-size'))
64configure_file(output: 'config.h',
65  configuration: conf_data
66)
67
68cpp = meson.get_compiler('cpp')
69
70if get_option('libpldm-only').disabled()
71  phosphor_dbus_interfaces = dependency('phosphor-dbus-interfaces')
72  sdbusplus = dependency('sdbusplus')
73  sdeventplus = dependency('sdeventplus')
74  stdplus = dependency('stdplus')
75
76  if cpp.has_header('nlohmann/json.hpp')
77    nlohmann_json = declare_dependency()
78  else
79    nlohmann_json = dependency('nlohmann_json')
80  endif
81
82  if cpp.has_header('CLI/CLI.hpp')
83    CLI11_dep = declare_dependency()
84  else
85    CLI11_dep = dependency('CLI11')
86  endif
87
88  if cpp.has_header_symbol('function2/function2.hpp', 'fu2::unique_function')
89    function2_dep = declare_dependency()
90  else
91    subproject('function2')
92    function2_dep = declare_dependency(
93      include_directories: [
94        'subprojects/function2/include/function2'
95      ]
96    )
97  endif
98endif
99
100if get_option('oe-sdk').enabled()
101  # Setup OE SYSROOT
102  OECORE_TARGET_SYSROOT = run_command('sh', '-c', 'echo $OECORE_TARGET_SYSROOT').stdout().strip()
103  if OECORE_TARGET_SYSROOT == ''
104      error('Unable to get $OECORE_TARGET_SYSROOT, check your environment.')
105  endif
106  message('OE_SYSROOT: ' + OECORE_TARGET_SYSROOT)
107  rpath = ':'.join([OECORE_TARGET_SYSROOT + '/lib', OECORE_TARGET_SYSROOT + '/usr/lib'])
108  ld_so = run_command('sh', '-c', 'find ' + OECORE_TARGET_SYSROOT + '/lib/ld-*.so | sort -r -n | head -n1').stdout().strip()
109  dynamic_linker = ['-Wl,-dynamic-linker,' + ld_so]
110else
111  dynamic_linker = []
112endif
113
114if get_option('tests').enabled()
115    gtest = dependency('gtest', main: true, disabler: true, required: false)
116    gmock = dependency('gmock', disabler: true, required: false)
117    if not gtest.found() or not gmock.found()
118        gtest_proj = import('cmake').subproject('googletest', required: false)
119        if gtest_proj.found()
120            gtest = declare_dependency(
121                dependencies: [
122                    dependency('threads'),
123                    gtest_proj.dependency('gtest'),
124                    gtest_proj.dependency('gtest_main'),
125                ]
126            )
127            gmock = gtest_proj.dependency('gmock')
128        else
129            assert(
130                not get_option('tests').enabled(),
131                'Googletest is required if tests are enabled'
132            )
133        endif
134    endif
135endif
136
137subdir('libpldm')
138
139if get_option('libpldm-only').disabled()
140
141libpldmutils_headers = ['.']
142libpldmutils = library(
143  'pldmutils',
144  'common/utils.cpp',
145  version: meson.project_version(),
146  dependencies: [
147      libpldm_dep,
148      phosphor_dbus_interfaces,
149      nlohmann_json,
150      sdbusplus,
151  ],
152  install: true,
153  include_directories: include_directories(libpldmutils_headers),
154)
155
156libpldmutils = declare_dependency(
157  include_directories: include_directories(libpldmutils_headers),
158  link_with: libpldmutils)
159
160deps = [
161  function2_dep,
162  libpldm_dep,
163  libpldmutils,
164  nlohmann_json,
165  phosphor_dbus_interfaces,
166  sdbusplus,
167  sdeventplus,
168  stdplus,
169]
170
171if get_option('libpldmresponder').enabled()
172subdir('libpldmresponder')
173deps += [
174  libpldmresponder
175]
176endif
177
178executable(
179  'pldmd',
180  'pldmd/pldmd.cpp',
181  'pldmd/dbus_impl_requester.cpp',
182  'pldmd/instance_id.cpp',
183  'pldmd/dbus_impl_pdr.cpp',
184  'fw-update/inventory_manager.cpp',
185  'fw-update/package_parser.cpp',
186  'fw-update/device_updater.cpp',
187  'fw-update/watch.cpp',
188  'fw-update/update_manager.cpp',
189  'requester/mctp_endpoint_discovery.cpp',
190  implicit_include_directories: false,
191  dependencies: deps,
192  install: true,
193  install_dir: get_option('bindir'))
194
195if get_option('systemd').enabled()
196  systemd_system_unit_dir = dependency('systemd').get_variable(
197          pkgconfig: 'systemdsystemunitdir')
198
199  configure_file(
200    copy: true,
201    input: 'pldmd/service_files/pldmd.service',
202    install: true,
203    install_dir: systemd_system_unit_dir,
204    output: 'pldmd.service',
205  )
206
207  configure_file(
208    input: 'pldmd/verbosity/verbosity',
209    output: 'pldm_verbosity',
210    configuration: conf_data,
211    install: true,
212    install_dir: join_paths(get_option('sysconfdir'), 'default'))
213
214  if get_option('oem-ibm').enabled()
215    subdir('oem/ibm/service_files')
216  endif
217endif
218
219subdir('pldmtool')
220
221subdir('configurations')
222
223if get_option('utilities').enabled()
224  subdir('utilities')
225endif
226
227if get_option('softoff').enabled()
228  subdir('softoff')
229endif
230
231if get_option('tests').enabled()
232  subdir('common/test')
233  subdir('fw-update/test')
234  subdir('host-bmc/test')
235  subdir('requester/test')
236  subdir('test')
237endif
238
239endif # pldm-only
240