xref: /openbmc/pldm/meson.build (revision df2fa47b) 
1project('pldm', ['c', 'cpp'],
2        version: '0.1', meson_version: '>=0.57.0',
3        default_options: [
4          'warning_level=3',
5          'default_library=shared',
6          'werror=true',
7          'cpp_std=c++20',
8          'buildtype=debugoptimized'
9        ])
10
11# Wno-psabi reduces the number of "Note:" messages when cross-compiling some STL
12# stuff for ARM. See https://stackoverflow.com/questions/48149323/strange-gcc-warning-when-compiling-qt-project
13# Basically, gcc 6 and gcc 7 are not ABI compatible, but since the whole OpenBMC
14# project uses the same compiler, we can safely ignmore these info notes.
15add_project_arguments('-Wno-psabi', language: 'cpp')
16
17
18# Disable FORTIFY_SOURCE when compiling with no optimization
19if(get_option('optimization') == '0')
20  add_project_arguments('-U_FORTIFY_SOURCE',language:['cpp','c'])
21  message('Disabling FORTIFY_SOURCE as optimization is set to 0')
22endif
23
24conf_data = configuration_data()
25if get_option('libpldmresponder').enabled()
26conf_data.set_quoted('BIOS_JSONS_DIR', '/usr/share/pldm/bios')
27conf_data.set_quoted('BIOS_TABLES_DIR', '/var/lib/pldm/bios')
28conf_data.set_quoted('PDR_JSONS_DIR', '/usr/share/pldm/pdr')
29conf_data.set_quoted('FRU_JSONS_DIR', '/usr/share/pldm/fru')
30conf_data.set_quoted('HOST_JSONS_DIR', '/usr/share/pldm/host')
31conf_data.set_quoted('EVENTS_JSONS_DIR', '/usr/share/pldm/events')
32add_project_arguments('-DLIBPLDMRESPONDER', language : ['c','cpp'])
33endif
34if get_option('softoff').enabled()
35  conf_data.set('SOFTOFF_TIMEOUT_SECONDS', get_option('softoff-timeout-seconds'))
36endif
37if get_option('oem-ibm').enabled()
38  conf_data.set_quoted('FILE_TABLE_JSON', '/usr/share/pldm/fileTable.json')
39  conf_data.set_quoted('LID_RUNNING_DIR', '/var/lib/phosphor-software-manager/hostfw/running')
40  conf_data.set_quoted('LID_ALTERNATE_DIR', '/var/lib/phosphor-software-manager/hostfw/alternate')
41  conf_data.set_quoted('LID_STAGING_DIR', '/var/lib/phosphor-software-manager/hostfw/staging')
42  conf_data.set_quoted('LID_RUNNING_PATCH_DIR', '/usr/local/share/hostfw/running')
43  conf_data.set_quoted('LID_ALTERNATE_PATCH_DIR', '/usr/local/share/hostfw/alternate')
44  conf_data.set_quoted('LID_STAGING_DIR', '/var/lib/phosphor-software-manager/hostfw/staging')
45  conf_data.set('DMA_MAXSIZE', get_option('oem-ibm-dma-maxsize'))
46  add_project_arguments('-DOEM_IBM', language : 'c')
47  add_project_arguments('-DOEM_IBM', language : 'cpp')
48endif
49conf_data.set('PLDM_VERBOSITY',get_option('verbosity'))
50configure_file(output: 'config.h',
51  configuration: conf_data
52)
53
54phosphor_dbus_interfaces = dependency(
55  'phosphor-dbus-interfaces',
56  fallback: ['phosphor-dbus-interfaces', 'phosphor_dbus_interfaces_dep'],
57)
58sdbusplus = dependency(
59  'sdbusplus',
60  fallback: ['sdbusplus', 'sdbusplus_dep'],
61)
62sdeventplus = dependency(
63  'sdeventplus',
64  fallback: ['sdeventplus', 'sdeventplus_dep'],
65)
66systemd = dependency('systemd')
67
68cpp = meson.get_compiler('cpp')
69
70if cpp.has_header('nlohmann/json.hpp')
71  nlohmann_json = declare_dependency()
72else
73  subproject('nlohmann-json')
74  nlohmann_json = declare_dependency(
75    include_directories: [
76      'subprojects/nlohmann-json/single_include',
77      'subprojects/nlohmann-json/single_include/nlohmann',
78    ]
79  )
80endif
81
82if cpp.has_header('CLI/CLI.hpp')
83  CLI11_dep = declare_dependency()
84else
85  CLI11_dep = dependency(
86    'CLI11',
87    fallback: [ 'CLI11', 'CLI11_dep' ],
88  )
89endif
90
91if get_option('oe-sdk').enabled()
92  # Setup OE SYSROOT
93  OECORE_TARGET_SYSROOT = run_command('sh', '-c', 'echo $OECORE_TARGET_SYSROOT').stdout().strip()
94  if OECORE_TARGET_SYSROOT == ''
95      error('Unable to get $OECORE_TARGET_SYSROOT, check your environment.')
96  endif
97  message('OE_SYSROOT: ' + OECORE_TARGET_SYSROOT)
98  rpath = ':'.join([OECORE_TARGET_SYSROOT + '/lib', OECORE_TARGET_SYSROOT + '/usr/lib'])
99  ld_so = run_command('sh', '-c', 'find ' + OECORE_TARGET_SYSROOT + '/lib/ld-*.so | sort -r -n | head -n1').stdout().strip()
100  dynamic_linker = ['-Wl,-dynamic-linker,' + ld_so]
101else
102  dynamic_linker = []
103endif
104
105if get_option('tests').enabled()
106    gtest = dependency('gtest', main: true, disabler: true, required: false)
107    gmock = dependency('gmock', disabler: true, required: false)
108    if not gtest.found() or not gmock.found()
109        gtest_proj = import('cmake').subproject('googletest', required: false)
110        if gtest_proj.found()
111            gtest = declare_dependency(
112                dependencies: [
113                    dependency('threads'),
114                    gtest_proj.dependency('gtest'),
115                    gtest_proj.dependency('gtest_main'),
116                ]
117            )
118            gmock = gtest_proj.dependency('gmock')
119        else
120            assert(
121                not get_option('tests').enabled(),
122                'Googletest is required if tests are enabled'
123            )
124        endif
125    endif
126endif
127
128subdir('libpldm')
129
130if get_option('libpldm-only').disabled()
131
132libpldmutils_headers = ['.']
133libpldmutils = library(
134  'pldmutils',
135  'common/utils.cpp',
136  version: meson.project_version(),
137  dependencies: [
138      libpldm_dep,
139      phosphor_dbus_interfaces,
140      nlohmann_json,
141      sdbusplus,
142  ],
143  install: true,
144  include_directories: include_directories(libpldmutils_headers),
145)
146
147libpldmutils = declare_dependency(
148  include_directories: include_directories(libpldmutils_headers),
149  link_with: libpldmutils)
150
151deps = [
152  libpldm_dep,
153  libpldmutils,
154  nlohmann_json,
155  sdbusplus,
156  sdeventplus,
157  phosphor_dbus_interfaces,
158]
159
160if get_option('libpldmresponder').enabled()
161subdir('libpldmresponder')
162deps += [
163  libpldmresponder
164]
165endif
166
167executable(
168  'pldmd',
169  'pldmd/pldmd.cpp',
170  'pldmd/dbus_impl_requester.cpp',
171  'pldmd/instance_id.cpp',
172  'pldmd/dbus_impl_pdr.cpp',
173  implicit_include_directories: false,
174  dependencies: deps,
175  install: true,
176  install_dir: get_option('bindir'))
177
178systemd_system_unit_dir = systemd.get_variable(
179        pkgconfig: 'systemdsystemunitdir',
180        pkgconfig_define: ['prefix', get_option('prefix')])
181
182configure_file(
183  copy: true,
184  input: 'pldmd/service_files/pldmd.service',
185  install: true,
186  install_dir: systemd_system_unit_dir,
187  output: 'pldmd.service',
188)
189
190configure_file(
191  input: 'pldmd/verbosity/verbosity',
192  output: 'pldm_verbosity',
193  configuration: conf_data,
194  install: true,
195  install_dir: '/etc/default')
196
197if get_option('oem-ibm').enabled()
198  subdir('oem/ibm/service_files')
199endif
200
201subdir('pldmtool')
202
203subdir('configurations')
204
205if get_option('utilities').enabled()
206  subdir('utilities')
207endif
208
209if get_option('softoff').enabled()
210  subdir('softoff')
211endif
212
213if get_option('tests').enabled()
214  subdir('common/test')
215  subdir('host-bmc/test')
216  subdir('test')
217endif
218
219endif # pldm-only
220