xref: /openbmc/pldm/meson.build (revision b69d8bf8) 
1project('pldm', ['c', 'cpp'],
2        version: '0.1', meson_version: '>=0.57.0',
3        default_options: [
4          'warning_level=3',
5          'default_library=shared',
6          'werror=true',
7          'cpp_std=c++20',
8          'buildtype=debugoptimized'
9        ])
10
11# Wno-psabi reduces the number of "Note:" messages when cross-compiling some STL
12# stuff for ARM. See https://stackoverflow.com/questions/48149323/strange-gcc-warning-when-compiling-qt-project
13# Basically, gcc 6 and gcc 7 are not ABI compatible, but since the whole OpenBMC
14# project uses the same compiler, we can safely ignmore these info notes.
15add_project_arguments('-Wno-psabi', language: 'cpp')
16
17
18# Disable FORTIFY_SOURCE when compiling with no optimization
19if(get_option('optimization') == '0')
20  add_project_arguments('-U_FORTIFY_SOURCE',language:['cpp','c'])
21  message('Disabling FORTIFY_SOURCE as optimization is set to 0')
22endif
23
24package_datadir = join_paths(get_option('prefix'), get_option('datadir'), meson.project_name())
25package_localstatedir = join_paths(get_option('prefix'), get_option('localstatedir'), meson.project_name())
26
27conf_data = configuration_data()
28if get_option('libpldmresponder').enabled()
29conf_data.set_quoted('BIOS_JSONS_DIR', join_paths(package_datadir, 'bios'))
30conf_data.set_quoted('BIOS_TABLES_DIR', join_paths(package_localstatedir, 'bios'))
31conf_data.set_quoted('PDR_JSONS_DIR', join_paths(package_datadir, 'pdr'))
32conf_data.set_quoted('FRU_JSONS_DIR', join_paths(package_datadir, 'fru'))
33conf_data.set_quoted('FRU_MASTER_JSON', join_paths(package_datadir, 'fru_master.json'))
34conf_data.set_quoted('HOST_JSONS_DIR', join_paths(package_datadir, 'host'))
35conf_data.set_quoted('EVENTS_JSONS_DIR', join_paths(package_datadir, 'events'))
36conf_data.set('HEARTBEAT_TIMEOUT', get_option('heartbeat-timeout-seconds'))
37conf_data.set('TERMINUS_ID', get_option('terminus-id'))
38conf_data.set('TERMINUS_HANDLE',get_option('terminus-handle'))
39add_project_arguments('-DLIBPLDMRESPONDER', language : ['c','cpp'])
40endif
41if get_option('softoff').enabled()
42  conf_data.set('SOFTOFF_TIMEOUT_SECONDS', get_option('softoff-timeout-seconds'))
43endif
44if get_option('oem-ibm').enabled()
45  conf_data.set_quoted('FILE_TABLE_JSON', join_paths(package_datadir, 'fileTable.json'))
46  conf_data.set_quoted('LID_RUNNING_DIR', '/var/lib/phosphor-software-manager/hostfw/running')
47  conf_data.set_quoted('LID_ALTERNATE_DIR', '/var/lib/phosphor-software-manager/hostfw/alternate')
48  conf_data.set_quoted('LID_STAGING_DIR', '/var/lib/phosphor-software-manager/hostfw/staging')
49  conf_data.set_quoted('LID_RUNNING_PATCH_DIR', '/usr/local/share/hostfw/running')
50  conf_data.set_quoted('LID_ALTERNATE_PATCH_DIR', '/usr/local/share/hostfw/alternate')
51  conf_data.set('DMA_MAXSIZE', get_option('oem-ibm-dma-maxsize'))
52  add_project_arguments('-DOEM_IBM', language : 'c')
53  add_project_arguments('-DOEM_IBM', language : 'cpp')
54endif
55conf_data.set('NUMBER_OF_REQUEST_RETRIES', get_option('number-of-request-retries'))
56conf_data.set('INSTANCE_ID_EXPIRATION_INTERVAL',get_option('instance-id-expiration-interval'))
57conf_data.set('RESPONSE_TIME_OUT',get_option('response-time-out'))
58conf_data.set('FLIGHT_RECORDER_MAX_ENTRIES',get_option('flightrecorder-max-entries'))
59conf_data.set_quoted('HOST_EID_PATH', join_paths(package_datadir, 'host_eid'))
60conf_data.set('MAXIMUM_TRANSFER_SIZE', get_option('maximum-transfer-size'))
61configure_file(output: 'config.h',
62  configuration: conf_data
63)
64
65cpp = meson.get_compiler('cpp')
66
67phosphor_dbus_interfaces = dependency('phosphor-dbus-interfaces')
68sdbusplus = dependency('sdbusplus')
69sdeventplus = dependency('sdeventplus')
70stdplus = dependency('stdplus')
71
72if cpp.has_header('nlohmann/json.hpp')
73  nlohmann_json = declare_dependency()
74else
75  nlohmann_json = dependency('nlohmann_json')
76endif
77
78if cpp.has_header('CLI/CLI.hpp')
79  CLI11_dep = declare_dependency()
80else
81  CLI11_dep = dependency('CLI11')
82endif
83
84if cpp.has_header_symbol('function2/function2.hpp', 'fu2::unique_function')
85  function2_dep = declare_dependency()
86else
87  subproject('function2')
88  function2_dep = declare_dependency(
89    include_directories: [
90      'subprojects/function2/include/function2'
91    ]
92  )
93endif
94
95if get_option('oe-sdk').enabled()
96  # Setup OE SYSROOT
97  OECORE_TARGET_SYSROOT = run_command('sh', '-c', 'echo $OECORE_TARGET_SYSROOT').stdout().strip()
98  if OECORE_TARGET_SYSROOT == ''
99      error('Unable to get $OECORE_TARGET_SYSROOT, check your environment.')
100  endif
101  message('OE_SYSROOT: ' + OECORE_TARGET_SYSROOT)
102  rpath = ':'.join([OECORE_TARGET_SYSROOT + '/lib', OECORE_TARGET_SYSROOT + '/usr/lib'])
103  ld_so = run_command('sh', '-c', 'find ' + OECORE_TARGET_SYSROOT + '/lib/ld-*.so | sort -r -n | head -n1').stdout().strip()
104  dynamic_linker = ['-Wl,-dynamic-linker,' + ld_so]
105else
106  dynamic_linker = []
107endif
108
109if get_option('tests').enabled()
110    gtest = dependency('gtest', main: true, disabler: true, required: false)
111    gmock = dependency('gmock', disabler: true, required: false)
112    if not gtest.found() or not gmock.found()
113        gtest_proj = import('cmake').subproject('googletest', required: false)
114        if gtest_proj.found()
115            gtest = declare_dependency(
116                dependencies: [
117                    dependency('threads'),
118                    gtest_proj.dependency('gtest'),
119                    gtest_proj.dependency('gtest_main'),
120                ]
121            )
122            gmock = gtest_proj.dependency('gmock')
123        else
124            assert(
125                not get_option('tests').enabled(),
126                'Googletest is required if tests are enabled'
127            )
128        endif
129    endif
130endif
131
132libpldm_dep = dependency('libpldm', fallback:['libpldm','libpldm_dep'])
133
134
135libpldmutils_headers = ['.']
136libpldmutils = library(
137  'pldmutils',
138  'common/utils.cpp',
139  version: meson.project_version(),
140  dependencies: [
141      libpldm_dep,
142      phosphor_dbus_interfaces,
143      nlohmann_json,
144      sdbusplus,
145  ],
146  install: true,
147  include_directories: include_directories(libpldmutils_headers),
148)
149
150libpldmutils = declare_dependency(
151  include_directories: include_directories(libpldmutils_headers),
152  link_with: libpldmutils)
153
154deps = [
155  function2_dep,
156  libpldm_dep,
157  libpldmutils,
158  nlohmann_json,
159  phosphor_dbus_interfaces,
160  sdbusplus,
161  sdeventplus,
162  stdplus,
163]
164
165if get_option('libpldmresponder').enabled()
166subdir('libpldmresponder')
167deps += [
168  libpldmresponder_dep
169]
170endif
171
172executable(
173  'pldmd',
174  'pldmd/pldmd.cpp',
175  'pldmd/dbus_impl_requester.cpp',
176  'pldmd/instance_id.cpp',
177  'pldmd/dbus_impl_pdr.cpp',
178  'fw-update/inventory_manager.cpp',
179  'fw-update/package_parser.cpp',
180  'fw-update/device_updater.cpp',
181  'fw-update/watch.cpp',
182  'fw-update/update_manager.cpp',
183  'requester/mctp_endpoint_discovery.cpp',
184  implicit_include_directories: false,
185  dependencies: deps,
186  install: true,
187  install_dir: get_option('bindir'))
188
189if get_option('systemd').enabled()
190  systemd_system_unit_dir = dependency('systemd').get_variable(
191          pkgconfig: 'systemdsystemunitdir')
192
193  configure_file(
194    copy: true,
195    input: 'pldmd/service_files/pldmd.service',
196    install: true,
197    install_dir: systemd_system_unit_dir,
198    output: 'pldmd.service',
199  )
200
201  if get_option('oem-ibm').enabled()
202    subdir('oem/ibm/service_files')
203  endif
204endif
205
206subdir('pldmtool')
207
208subdir('configurations')
209
210if get_option('utilities').enabled()
211  subdir('utilities')
212endif
213
214if get_option('softoff').enabled()
215  subdir('softoff')
216endif
217
218if get_option('tests').enabled()
219  subdir('common/test')
220  subdir('fw-update/test')
221  subdir('host-bmc/test')
222  subdir('requester/test')
223  subdir('test')
224endif
225