xref: /openbmc/pldm/meson.build (revision a7dbca53) 
1project('pldm', ['c', 'cpp'],
2        version: '0.1', meson_version: '>=1.1.1',
3        default_options: [
4          'warning_level=3',
5          'default_library=shared',
6          'werror=true',
7          'cpp_std=c++23',
8          'buildtype=debugoptimized'
9        ])
10
11# Wno-psabi reduces the number of "Note:" messages when cross-compiling some STL
12# stuff for ARM. See https://stackoverflow.com/questions/48149323/strange-gcc-warning-when-compiling-qt-project
13# Basically, gcc 6 and gcc 7 are not ABI compatible, but since the whole OpenBMC
14# project uses the same compiler, we can safely ignmore these info notes.
15add_project_arguments('-Wno-psabi', language: 'cpp')
16
17
18# Disable FORTIFY_SOURCE when compiling with no optimization
19if(get_option('optimization') == '0')
20  add_project_arguments('-U_FORTIFY_SOURCE',language:['cpp','c'])
21  message('Disabling FORTIFY_SOURCE as optimization is set to 0')
22endif
23
24package_datadir = join_paths(get_option('prefix'), get_option('datadir'), meson.project_name())
25package_localstatedir = join_paths(get_option('prefix'), get_option('localstatedir'), meson.project_name())
26
27conf_data = configuration_data()
28if get_option('libpldmresponder').enabled()
29conf_data.set_quoted('BIOS_JSONS_DIR', join_paths(package_datadir, 'bios'))
30conf_data.set_quoted('BIOS_TABLES_DIR', join_paths(package_localstatedir, 'bios'))
31conf_data.set_quoted('PDR_JSONS_DIR', join_paths(package_datadir, 'pdr'))
32conf_data.set_quoted('FRU_JSONS_DIR', join_paths(package_datadir, 'fru'))
33conf_data.set_quoted('FRU_MASTER_JSON', join_paths(package_datadir, 'fru_master.json'))
34conf_data.set_quoted('HOST_JSONS_DIR', join_paths(package_datadir, 'host'))
35conf_data.set_quoted('EVENTS_JSONS_DIR', join_paths(package_datadir, 'events'))
36conf_data.set('HEARTBEAT_TIMEOUT', get_option('heartbeat-timeout-seconds'))
37conf_data.set('TERMINUS_ID', get_option('terminus-id'))
38conf_data.set('TERMINUS_HANDLE',get_option('terminus-handle'))
39conf_data.set('DBUS_TIMEOUT', get_option('dbus-timeout-value'))
40add_project_arguments('-DLIBPLDMRESPONDER', language : ['c','cpp'])
41endif
42if get_option('softoff').enabled()
43  conf_data.set('SOFTOFF_TIMEOUT_SECONDS', get_option('softoff-timeout-seconds'))
44endif
45if get_option('oem-ibm').enabled()
46  conf_data.set_quoted('FILE_TABLE_JSON', join_paths(package_datadir, 'fileTable.json'))
47  conf_data.set_quoted('LID_RUNNING_DIR', '/var/lib/phosphor-software-manager/hostfw/running')
48  conf_data.set_quoted('LID_ALTERNATE_DIR', '/var/lib/phosphor-software-manager/hostfw/alternate')
49  conf_data.set_quoted('LID_STAGING_DIR', '/var/lib/phosphor-software-manager/hostfw/staging')
50  conf_data.set_quoted('LID_RUNNING_PATCH_DIR', '/usr/local/share/hostfw/running')
51  conf_data.set_quoted('LID_ALTERNATE_PATCH_DIR', '/usr/local/share/hostfw/alternate')
52  conf_data.set('DMA_MAXSIZE', get_option('oem-ibm-dma-maxsize'))
53  add_project_arguments('-DOEM_IBM', language : 'c')
54  add_project_arguments('-DOEM_IBM', language : 'cpp')
55endif
56conf_data.set('NUMBER_OF_REQUEST_RETRIES', get_option('number-of-request-retries'))
57conf_data.set('INSTANCE_ID_EXPIRATION_INTERVAL',get_option('instance-id-expiration-interval'))
58conf_data.set('RESPONSE_TIME_OUT',get_option('response-time-out'))
59conf_data.set('FLIGHT_RECORDER_MAX_ENTRIES',get_option('flightrecorder-max-entries'))
60conf_data.set_quoted('HOST_EID_PATH', join_paths(package_datadir, 'host_eid'))
61conf_data.set('MAXIMUM_TRANSFER_SIZE', get_option('maximum-transfer-size'))
62config = configure_file(output: 'config.h',
63  configuration: conf_data
64)
65
66add_project_arguments('-include', '@0@'.format(config), language: 'cpp')
67
68cpp = meson.get_compiler('cpp')
69
70phosphor_dbus_interfaces = dependency('phosphor-dbus-interfaces')
71sdbusplus = dependency('sdbusplus')
72sdeventplus = dependency('sdeventplus')
73stdplus = dependency('stdplus')
74phosphor_logging_dep = dependency('phosphor-logging')
75
76if cpp.has_header('nlohmann/json.hpp')
77  nlohmann_json = declare_dependency()
78else
79  nlohmann_json = dependency('nlohmann_json')
80endif
81
82if cpp.has_header('CLI/CLI.hpp')
83  CLI11_dep = declare_dependency()
84else
85  CLI11_dep = dependency('CLI11')
86endif
87
88if cpp.has_header_symbol('function2/function2.hpp', 'fu2::unique_function')
89  function2_dep = declare_dependency()
90else
91  subproject('function2')
92  function2_dep = declare_dependency(
93    include_directories: [
94      'subprojects/function2/include/function2'
95    ]
96  )
97endif
98
99if get_option('oe-sdk').enabled()
100  # Setup OE SYSROOT
101  OECORE_TARGET_SYSROOT = run_command('sh', '-c', 'echo $OECORE_TARGET_SYSROOT').stdout().strip()
102  if OECORE_TARGET_SYSROOT == ''
103      error('Unable to get $OECORE_TARGET_SYSROOT, check your environment.')
104  endif
105  message('OE_SYSROOT: ' + OECORE_TARGET_SYSROOT)
106  rpath = ':'.join([OECORE_TARGET_SYSROOT + '/lib', OECORE_TARGET_SYSROOT + '/usr/lib'])
107  ld_so = run_command('sh', '-c', 'find ' + OECORE_TARGET_SYSROOT + '/lib/ld-*.so | sort -r -n | head -n1').stdout().strip()
108  dynamic_linker = ['-Wl,-dynamic-linker,' + ld_so]
109else
110  dynamic_linker = []
111endif
112
113if get_option('tests').enabled()
114    gtest = dependency('gtest', main: true, disabler: true, required: false)
115    gmock = dependency('gmock', disabler: true, required: false)
116    if not gtest.found() or not gmock.found()
117        gtest_proj = import('cmake').subproject('googletest', required: false)
118        if gtest_proj.found()
119            gtest = declare_dependency(
120                dependencies: [
121                    dependency('threads'),
122                    gtest_proj.dependency('gtest'),
123                    gtest_proj.dependency('gtest_main'),
124                ]
125            )
126            gmock = gtest_proj.dependency('gmock')
127        else
128            assert(
129                not get_option('tests').enabled(),
130                'Googletest is required if tests are enabled'
131            )
132        endif
133    endif
134endif
135
136libpldm_dep = dependency('libpldm', fallback:['libpldm','libpldm_dep'])
137
138
139libpldmutils_headers = ['.']
140libpldmutils = library(
141  'pldmutils',
142  'common/utils.cpp',
143  version: meson.project_version(),
144  dependencies: [
145      libpldm_dep,
146      phosphor_dbus_interfaces,
147      phosphor_logging_dep,
148      nlohmann_json,
149      sdbusplus,
150  ],
151  install: true,
152  include_directories: include_directories(libpldmutils_headers),
153)
154
155libpldmutils = declare_dependency(
156  include_directories: include_directories(libpldmutils_headers),
157  link_with: libpldmutils)
158
159deps = [
160  function2_dep,
161  libpldm_dep,
162  libpldmutils,
163  nlohmann_json,
164  phosphor_dbus_interfaces,
165  phosphor_logging_dep,
166  sdbusplus,
167  sdeventplus,
168  stdplus,
169]
170
171if get_option('libpldmresponder').enabled()
172subdir('libpldmresponder')
173deps += [
174  libpldmresponder_dep
175]
176endif
177
178executable(
179  'pldmd',
180  'pldmd/pldmd.cpp',
181  'pldmd/dbus_impl_pdr.cpp',
182  'fw-update/inventory_manager.cpp',
183  'fw-update/package_parser.cpp',
184  'fw-update/device_updater.cpp',
185  'fw-update/watch.cpp',
186  'fw-update/update_manager.cpp',
187  'requester/mctp_endpoint_discovery.cpp',
188  implicit_include_directories: false,
189  dependencies: deps,
190  install: true,
191  install_dir: get_option('bindir'))
192
193if get_option('systemd').enabled()
194  systemd_system_unit_dir = dependency('systemd').get_variable(
195          'systemdsystemunitdir')
196
197  configure_file(
198    copy: true,
199    input: 'pldmd/service_files/pldmd.service',
200    install: true,
201    install_dir: systemd_system_unit_dir,
202    output: 'pldmd.service',
203  )
204
205  if get_option('oem-ibm').enabled()
206    subdir('oem/ibm/service_files')
207  endif
208endif
209
210subdir('pldmtool')
211
212subdir('configurations')
213
214if get_option('utilities').enabled()
215  subdir('utilities')
216endif
217
218if get_option('softoff').enabled()
219  subdir('softoff')
220endif
221
222if get_option('tests').enabled()
223  subdir('common/test')
224  subdir('fw-update/test')
225  subdir('host-bmc/test')
226  subdir('requester/test')
227  subdir('test')
228endif
229