xref: /openbmc/pldm/meson.build (revision 7927f90c) 
1project('pldm', ['c', 'cpp'],
2        version: '0.1', meson_version: '>=1.1.1',
3        default_options: [
4          'warning_level=3',
5          'default_library=shared',
6          'werror=true',
7          'cpp_std=c++23',
8          'buildtype=debugoptimized'
9        ])
10
11# Wno-psabi reduces the number of "Note:" messages when cross-compiling some STL
12# stuff for ARM. See https://stackoverflow.com/questions/48149323/strange-gcc-warning-when-compiling-qt-project
13# Basically, gcc 6 and gcc 7 are not ABI compatible, but since the whole OpenBMC
14# project uses the same compiler, we can safely ignmore these info notes.
15add_project_arguments('-Wno-psabi', language: 'cpp')
16
17
18# Disable FORTIFY_SOURCE when compiling with no optimization
19if(get_option('optimization') == '0')
20  add_project_arguments('-U_FORTIFY_SOURCE',language:['cpp','c'])
21  message('Disabling FORTIFY_SOURCE as optimization is set to 0')
22endif
23
24package_datadir = join_paths(get_option('prefix'), get_option('datadir'), meson.project_name())
25package_localstatedir = join_paths(get_option('prefix'), get_option('localstatedir'), meson.project_name())
26
27conf_data = configuration_data()
28cpp = meson.get_compiler('cpp')
29
30# Enable POSIX poll APIs in libpldm
31if cpp.has_header('poll.h')
32    conf_data.set('PLDM_HAS_POLL', 1)
33endif
34if get_option('libpldmresponder').allowed()
35conf_data.set_quoted('BIOS_JSONS_DIR', join_paths(package_datadir, 'bios'))
36conf_data.set_quoted('BIOS_TABLES_DIR', join_paths(package_localstatedir, 'bios'))
37conf_data.set_quoted('PDR_JSONS_DIR', join_paths(package_datadir, 'pdr'))
38conf_data.set_quoted('FRU_JSONS_DIR', join_paths(package_datadir, 'fru'))
39conf_data.set_quoted('FRU_MASTER_JSON', join_paths(package_datadir, 'fru_master.json'))
40conf_data.set_quoted('HOST_JSONS_DIR', join_paths(package_datadir, 'host'))
41conf_data.set_quoted('EVENTS_JSONS_DIR', join_paths(package_datadir, 'events'))
42conf_data.set('HEARTBEAT_TIMEOUT', get_option('heartbeat-timeout-seconds'))
43conf_data.set('TERMINUS_ID', get_option('terminus-id'))
44conf_data.set('TERMINUS_HANDLE',get_option('terminus-handle'))
45conf_data.set('DBUS_TIMEOUT', get_option('dbus-timeout-value'))
46add_project_arguments('-DLIBPLDMRESPONDER', language : ['c','cpp'])
47endif
48if get_option('softoff').allowed()
49  conf_data.set('SOFTOFF_TIMEOUT_SECONDS', get_option('softoff-timeout-seconds'))
50endif
51if get_option('oem-ibm').allowed()
52  conf_data.set_quoted('FILE_TABLE_JSON', join_paths(package_datadir, 'fileTable.json'))
53  conf_data.set_quoted('LID_RUNNING_DIR', '/var/lib/phosphor-software-manager/hostfw/running')
54  conf_data.set_quoted('LID_ALTERNATE_DIR', '/var/lib/phosphor-software-manager/hostfw/alternate')
55  conf_data.set_quoted('LID_STAGING_DIR', '/var/lib/phosphor-software-manager/hostfw/staging')
56  conf_data.set_quoted('LID_RUNNING_PATCH_DIR', '/usr/local/share/hostfw/running')
57  conf_data.set_quoted('LID_ALTERNATE_PATCH_DIR', '/usr/local/share/hostfw/alternate')
58  conf_data.set('DMA_MAXSIZE', get_option('oem-ibm-dma-maxsize'))
59  add_project_arguments('-DOEM_IBM', language : ['c', 'cpp'])
60endif
61conf_data.set('NUMBER_OF_REQUEST_RETRIES', get_option('number-of-request-retries'))
62conf_data.set('INSTANCE_ID_EXPIRATION_INTERVAL',get_option('instance-id-expiration-interval'))
63conf_data.set('RESPONSE_TIME_OUT',get_option('response-time-out'))
64conf_data.set('FLIGHT_RECORDER_MAX_ENTRIES',get_option('flightrecorder-max-entries'))
65conf_data.set_quoted('HOST_EID_PATH', join_paths(package_datadir, 'host_eid'))
66conf_data.set('MAXIMUM_TRANSFER_SIZE', get_option('maximum-transfer-size'))
67if get_option('transport-implementation') == 'mctp-demux'
68  conf_data.set('PLDM_TRANSPORT_WITH_MCTP_DEMUX', 1)
69elif get_option('transport-implementation') == 'af-mctp'
70  conf_data.set('PLDM_TRANSPORT_WITH_AF_MCTP', 1)
71endif
72config = configure_file(output: 'config.h',
73  configuration: conf_data
74)
75
76add_project_arguments('-include', '@0@'.format(config), language: 'cpp')
77
78filesystem = import('fs')
79
80phosphor_dbus_interfaces = dependency('phosphor-dbus-interfaces')
81sdbusplus = dependency('sdbusplus')
82sdeventplus = dependency('sdeventplus')
83stdplus = dependency('stdplus')
84phosphor_logging_dep = dependency('phosphor-logging')
85
86nlohmann_json_dep = dependency('nlohmann_json', include_type: 'system')
87
88if cpp.has_header('CLI/CLI.hpp')
89  CLI11_dep = declare_dependency()
90else
91  CLI11_dep = dependency('CLI11')
92endif
93
94if get_option('oe-sdk').allowed()
95  # Setup OE SYSROOT
96  OECORE_TARGET_SYSROOT = run_command('sh', '-c', 'echo $OECORE_TARGET_SYSROOT').stdout().strip()
97  if OECORE_TARGET_SYSROOT == ''
98      error('Unable to get $OECORE_TARGET_SYSROOT, check your environment.')
99  endif
100  message('OE_SYSROOT: ' + OECORE_TARGET_SYSROOT)
101  rpath = ':'.join([OECORE_TARGET_SYSROOT + '/lib', OECORE_TARGET_SYSROOT + '/usr/lib'])
102  ld_so = run_command('sh', '-c', 'find ' + OECORE_TARGET_SYSROOT + '/lib/ld-*.so | sort -r -n | head -n1').stdout().strip()
103  dynamic_linker = ['-Wl,-dynamic-linker,' + ld_so]
104else
105  dynamic_linker = []
106endif
107
108if get_option('tests').allowed()
109    gtest = dependency('gtest', main: true, disabler: true, required: false)
110    gmock = dependency('gmock', disabler: true, required: false)
111    if not gtest.found() or not gmock.found()
112        gtest_proj = import('cmake').subproject('googletest', required: false)
113        if gtest_proj.found()
114            gtest = declare_dependency(
115                dependencies: [
116                    dependency('threads'),
117                    gtest_proj.dependency('gtest'),
118                    gtest_proj.dependency('gtest_main'),
119                ]
120            )
121            gmock = gtest_proj.dependency('gmock')
122        else
123            assert(
124                not get_option('tests').allowed(),
125                'Googletest is required if tests are enabled'
126            )
127        endif
128    endif
129endif
130
131libpldm_dep = dependency('libpldm', fallback:['libpldm','libpldm_dep'], include_type: 'system')
132
133
134libpldmutils_headers = ['.']
135libpldmutils = library(
136  'pldmutils',
137  'common/transport.cpp',
138  'common/utils.cpp',
139  version: meson.project_version(),
140  dependencies: [
141      libpldm_dep,
142      phosphor_dbus_interfaces,
143      phosphor_logging_dep,
144      nlohmann_json_dep,
145      sdbusplus,
146  ],
147  install: true,
148  include_directories: include_directories(libpldmutils_headers),
149)
150
151libpldmutils = declare_dependency(
152  include_directories: include_directories(libpldmutils_headers),
153  link_with: libpldmutils)
154
155deps = [
156  libpldm_dep,
157  libpldmutils,
158  nlohmann_json_dep,
159  phosphor_dbus_interfaces,
160  phosphor_logging_dep,
161  sdbusplus,
162  sdeventplus,
163  stdplus,
164]
165
166if get_option('libpldmresponder').allowed()
167subdir('libpldmresponder')
168deps += [
169  libpldmresponder_dep
170]
171endif
172
173executable(
174  'pldmd',
175  'pldmd/pldmd.cpp',
176  'pldmd/dbus_impl_pdr.cpp',
177  'fw-update/inventory_manager.cpp',
178  'fw-update/package_parser.cpp',
179  'fw-update/device_updater.cpp',
180  'fw-update/watch.cpp',
181  'fw-update/update_manager.cpp',
182  'requester/mctp_endpoint_discovery.cpp',
183  implicit_include_directories: false,
184  dependencies: deps,
185  install: true,
186  install_dir: get_option('bindir'))
187
188if get_option('systemd').allowed()
189  systemd_system_unit_dir = dependency('systemd').get_variable(
190          'systemdsystemunitdir')
191  filesystem.copyfile(
192    'pldmd/service_files/pldmd.service',
193    'pldmd.service',
194    install: true,
195    install_dir: systemd_system_unit_dir
196  )
197
198  if get_option('oem-ibm').allowed()
199    subdir('oem/ibm/service_files')
200  endif
201endif
202
203subdir('pldmtool')
204
205subdir('configurations')
206
207if get_option('utilities').allowed()
208  subdir('utilities')
209endif
210
211if get_option('softoff').allowed()
212  subdir('softoff')
213endif
214
215if get_option('tests').allowed()
216  subdir('common/test')
217  subdir('fw-update/test')
218  subdir('host-bmc/test')
219  subdir('requester/test')
220  subdir('test')
221endif
222