xref: /openbmc/pldm/meson.build (revision 5a945bd1) 
1project('pldm', ['c', 'cpp'],
2        version: '0.1', meson_version: '>=1.1.1',
3        default_options: [
4          'warning_level=3',
5          'default_library=shared',
6          'werror=true',
7          'cpp_std=c++23',
8          'buildtype=debugoptimized'
9        ])
10
11# Wno-psabi reduces the number of "Note:" messages when cross-compiling some STL
12# stuff for ARM. See https://stackoverflow.com/questions/48149323/strange-gcc-warning-when-compiling-qt-project
13# Basically, gcc 6 and gcc 7 are not ABI compatible, but since the whole OpenBMC
14# project uses the same compiler, we can safely ignmore these info notes.
15add_project_arguments('-Wno-psabi', language: 'cpp')
16
17
18# Disable FORTIFY_SOURCE when compiling with no optimization
19if(get_option('optimization') == '0')
20  add_project_arguments('-U_FORTIFY_SOURCE',language:['cpp','c'])
21  message('Disabling FORTIFY_SOURCE as optimization is set to 0')
22endif
23
24package_datadir = join_paths(get_option('prefix'), get_option('datadir'), meson.project_name())
25package_localstatedir = join_paths(get_option('prefix'), get_option('localstatedir'), meson.project_name())
26
27conf_data = configuration_data()
28cpp = meson.get_compiler('cpp')
29
30# Enable POSIX poll APIs in libpldm
31if cpp.has_header('poll.h')
32    conf_data.set('PLDM_HAS_POLL', 1)
33endif
34if get_option('libpldmresponder').allowed()
35conf_data.set_quoted('BIOS_JSONS_DIR', join_paths(package_datadir, 'bios'))
36conf_data.set('SYSTEM_SPECIFIC_BIOS_JSON', get_option('system-specific-bios-json').allowed())
37conf_data.set_quoted('BIOS_TABLES_DIR', join_paths(package_localstatedir, 'bios'))
38conf_data.set_quoted('PDR_JSONS_DIR', join_paths(package_datadir, 'pdr'))
39conf_data.set_quoted('FRU_JSONS_DIR', join_paths(package_datadir, 'fru'))
40conf_data.set_quoted('FRU_MASTER_JSON', join_paths(package_datadir, 'fru_master.json'))
41conf_data.set_quoted('ENTITY_MAP_JSON', join_paths(package_datadir, 'entityMap.json'))
42conf_data.set_quoted('HOST_JSONS_DIR', join_paths(package_datadir, 'host'))
43conf_data.set_quoted('EVENTS_JSONS_DIR', join_paths(package_datadir, 'events'))
44conf_data.set('HEARTBEAT_TIMEOUT', get_option('heartbeat-timeout-seconds'))
45conf_data.set('TERMINUS_ID', get_option('terminus-id'))
46conf_data.set('TERMINUS_HANDLE',get_option('terminus-handle'))
47conf_data.set('DBUS_TIMEOUT', get_option('dbus-timeout-value'))
48add_project_arguments('-DLIBPLDMRESPONDER', language : ['c','cpp'])
49endif
50if get_option('softoff').allowed()
51  conf_data.set('SOFTOFF_TIMEOUT_SECONDS', get_option('softoff-timeout-seconds'))
52  conf_data.set_quoted('SOFTOFF_CONFIG_JSON', join_paths(package_datadir, 'softoff'))
53endif
54if get_option('oem-ibm').allowed()
55  conf_data.set_quoted('FILE_TABLE_JSON', join_paths(package_datadir, 'fileTable.json'))
56  conf_data.set_quoted('LID_RUNNING_DIR', '/var/lib/phosphor-software-manager/hostfw/running')
57  conf_data.set_quoted('LID_ALTERNATE_DIR', '/var/lib/phosphor-software-manager/hostfw/alternate')
58  conf_data.set_quoted('LID_STAGING_DIR', '/var/lib/phosphor-software-manager/hostfw/staging')
59  conf_data.set_quoted('LID_RUNNING_PATCH_DIR', '/usr/local/share/hostfw/running')
60  conf_data.set_quoted('LID_ALTERNATE_PATCH_DIR', '/usr/local/share/hostfw/alternate')
61  conf_data.set('DMA_MAXSIZE', get_option('oem-ibm-dma-maxsize'))
62  add_project_arguments('-DOEM_IBM', language : ['c', 'cpp'])
63endif
64conf_data.set('NUMBER_OF_REQUEST_RETRIES', get_option('number-of-request-retries'))
65conf_data.set('INSTANCE_ID_EXPIRATION_INTERVAL',get_option('instance-id-expiration-interval'))
66conf_data.set('RESPONSE_TIME_OUT',get_option('response-time-out'))
67conf_data.set('FLIGHT_RECORDER_MAX_ENTRIES',get_option('flightrecorder-max-entries'))
68conf_data.set_quoted('HOST_EID_PATH', join_paths(package_datadir, 'host_eid'))
69conf_data.set('MAXIMUM_TRANSFER_SIZE', get_option('maximum-transfer-size'))
70if get_option('transport-implementation') == 'mctp-demux'
71  conf_data.set('PLDM_TRANSPORT_WITH_MCTP_DEMUX', 1)
72elif get_option('transport-implementation') == 'af-mctp'
73  conf_data.set('PLDM_TRANSPORT_WITH_AF_MCTP', 1)
74endif
75conf_data.set('DEFAULT_SENSOR_UPDATER_INTERVAL', get_option('default-sensor-update-interval'))
76
77configure_file(output: 'config.h',
78  configuration: conf_data
79)
80
81add_project_arguments('-include', '@0@'.format(meson.current_build_dir() /'config.h'), language: 'cpp')
82
83filesystem = import('fs')
84
85phosphor_dbus_interfaces = dependency('phosphor-dbus-interfaces')
86sdbusplus = dependency('sdbusplus')
87sdeventplus = dependency('sdeventplus')
88stdplus = dependency('stdplus')
89phosphor_logging_dep = dependency('phosphor-logging')
90
91nlohmann_json_dep = dependency('nlohmann_json', include_type: 'system')
92
93if cpp.has_header('CLI/CLI.hpp')
94  CLI11_dep = declare_dependency()
95else
96  CLI11_dep = dependency('CLI11')
97endif
98
99if get_option('tests').allowed()
100    gtest = dependency('gtest', main: true, disabler: true, required: false)
101    gmock = dependency('gmock', disabler: true, required: false)
102    if not gtest.found() or not gmock.found()
103        gtest_proj = import('cmake').subproject('googletest', required: false)
104        if gtest_proj.found()
105            gtest = declare_dependency(
106                dependencies: [
107                    dependency('threads'),
108                    gtest_proj.dependency('gtest'),
109                    gtest_proj.dependency('gtest_main'),
110                ]
111            )
112            gmock = gtest_proj.dependency('gmock')
113        else
114            assert(
115                not get_option('tests').allowed(),
116                'Googletest is required if tests are enabled'
117            )
118        endif
119    endif
120endif
121
122libpldm_dep = dependency('libpldm', fallback:['libpldm','libpldm_dep'], include_type: 'system')
123
124
125libpldmutils_headers = ['.']
126libpldmutils = library(
127  'pldmutils',
128  'common/transport.cpp',
129  'common/utils.cpp',
130  version: meson.project_version(),
131  dependencies: [
132      libpldm_dep,
133      phosphor_dbus_interfaces,
134      phosphor_logging_dep,
135      nlohmann_json_dep,
136      sdbusplus,
137  ],
138  install: true,
139  include_directories: include_directories(libpldmutils_headers),
140)
141
142libpldmutils = declare_dependency(
143  include_directories: include_directories(libpldmutils_headers),
144  link_with: libpldmutils)
145
146deps = [
147  libpldm_dep,
148  libpldmutils,
149  nlohmann_json_dep,
150  phosphor_dbus_interfaces,
151  phosphor_logging_dep,
152  sdbusplus,
153  sdeventplus,
154  stdplus,
155]
156
157if get_option('libpldmresponder').allowed()
158subdir('libpldmresponder')
159deps += [
160  libpldmresponder_dep
161]
162endif
163
164executable(
165  'pldmd',
166  'pldmd/pldmd.cpp',
167  'pldmd/dbus_impl_pdr.cpp',
168  'fw-update/activation.cpp',
169  'fw-update/inventory_manager.cpp',
170  'fw-update/package_parser.cpp',
171  'fw-update/device_updater.cpp',
172  'fw-update/watch.cpp',
173  'fw-update/update_manager.cpp',
174  'platform-mc/terminus_manager.cpp',
175  'platform-mc/terminus.cpp',
176  'platform-mc/platform_manager.cpp',
177  'platform-mc/manager.cpp',
178  'platform-mc/numeric_sensor.cpp',
179  'requester/mctp_endpoint_discovery.cpp',
180  implicit_include_directories: false,
181  dependencies: deps,
182  install: true,
183  install_dir: get_option('bindir'))
184
185if get_option('systemd').allowed()
186  systemd_system_unit_dir = dependency('systemd').get_variable(
187          'systemdsystemunitdir')
188  filesystem.copyfile(
189    'pldmd/service_files/pldmd.service',
190    'pldmd.service',
191    install: true,
192    install_dir: systemd_system_unit_dir
193  )
194
195  if get_option('oem-ibm').allowed()
196    subdir('oem/ibm/service_files')
197  endif
198endif
199
200subdir('pldmtool')
201
202subdir('configurations')
203
204if get_option('utilities').allowed()
205  subdir('utilities')
206endif
207
208if get_option('softoff').allowed()
209  subdir('softoff')
210endif
211
212if get_option('tests').allowed()
213  subdir('common/test')
214  subdir('fw-update/test')
215  subdir('host-bmc/test')
216  subdir('requester/test')
217  subdir('platform-mc/test')
218  subdir('test')
219endif
220