xref: /openbmc/pldm/meson.build (revision 4d8d5770) 
1project('pldm', ['c', 'cpp'],
2        version: '0.1', meson_version: '>=0.57.0',
3        default_options: [
4          'warning_level=3',
5          'default_library=shared',
6          'werror=true',
7          'cpp_std=c++20',
8          'buildtype=debugoptimized'
9        ])
10
11# Wno-psabi reduces the number of "Note:" messages when cross-compiling some STL
12# stuff for ARM. See https://stackoverflow.com/questions/48149323/strange-gcc-warning-when-compiling-qt-project
13# Basically, gcc 6 and gcc 7 are not ABI compatible, but since the whole OpenBMC
14# project uses the same compiler, we can safely ignmore these info notes.
15add_project_arguments('-Wno-psabi', language: 'cpp')
16
17
18# Disable FORTIFY_SOURCE when compiling with no optimization
19if(get_option('optimization') == '0')
20  add_project_arguments('-U_FORTIFY_SOURCE',language:['cpp','c'])
21  message('Disabling FORTIFY_SOURCE as optimization is set to 0')
22endif
23
24package_datadir = join_paths(get_option('prefix'), get_option('datadir'), meson.project_name())
25package_localstatedir = join_paths(get_option('prefix'), get_option('localstatedir'), meson.project_name())
26
27conf_data = configuration_data()
28if get_option('libpldmresponder').enabled()
29conf_data.set_quoted('BIOS_JSONS_DIR', join_paths(package_datadir, 'bios'))
30conf_data.set_quoted('BIOS_TABLES_DIR', join_paths(package_localstatedir, 'bios'))
31conf_data.set_quoted('PDR_JSONS_DIR', join_paths(package_datadir, 'pdr'))
32conf_data.set_quoted('FRU_JSONS_DIR', join_paths(package_datadir, 'fru'))
33conf_data.set_quoted('FRU_MASTER_JSON', join_paths(package_datadir, 'fru_master.json'))
34conf_data.set_quoted('HOST_JSONS_DIR', join_paths(package_datadir, 'host'))
35conf_data.set_quoted('EVENTS_JSONS_DIR', join_paths(package_datadir, 'events'))
36conf_data.set('HEARTBEAT_TIMEOUT', get_option('heartbeat-timeout-seconds'))
37conf_data.set('TERMINUS_ID', get_option('terminus-id'))
38conf_data.set('TERMINUS_HANDLE',get_option('terminus-handle'))
39add_project_arguments('-DLIBPLDMRESPONDER', language : ['c','cpp'])
40endif
41if get_option('softoff').enabled()
42  conf_data.set('SOFTOFF_TIMEOUT_SECONDS', get_option('softoff-timeout-seconds'))
43endif
44if get_option('oem-ibm').enabled()
45  conf_data.set_quoted('FILE_TABLE_JSON', join_paths(package_datadir, 'fileTable.json'))
46  conf_data.set_quoted('LID_RUNNING_DIR', '/var/lib/phosphor-software-manager/hostfw/running')
47  conf_data.set_quoted('LID_ALTERNATE_DIR', '/var/lib/phosphor-software-manager/hostfw/alternate')
48  conf_data.set_quoted('LID_STAGING_DIR', '/var/lib/phosphor-software-manager/hostfw/staging')
49  conf_data.set_quoted('LID_RUNNING_PATCH_DIR', '/usr/local/share/hostfw/running')
50  conf_data.set_quoted('LID_ALTERNATE_PATCH_DIR', '/usr/local/share/hostfw/alternate')
51  conf_data.set_quoted('LID_STAGING_DIR', '/var/lib/phosphor-software-manager/hostfw/staging')
52  conf_data.set('DMA_MAXSIZE', get_option('oem-ibm-dma-maxsize'))
53  add_project_arguments('-DOEM_IBM', language : 'c')
54  add_project_arguments('-DOEM_IBM', language : 'cpp')
55endif
56conf_data.set('PLDM_VERBOSITY',get_option('verbosity'))
57conf_data.set('NUMBER_OF_REQUEST_RETRIES', get_option('number-of-request-retries'))
58conf_data.set('INSTANCE_ID_EXPIRATION_INTERVAL',get_option('instance-id-expiration-interval'))
59conf_data.set('RESPONSE_TIME_OUT',get_option('response-time-out'))
60if get_option('libpldm-only').disabled()
61  conf_data.set_quoted('HOST_EID_PATH', join_paths(package_datadir, 'host_eid'))
62endif
63conf_data.set('MAXIMUM_TRANSFER_SIZE', get_option('maximum-transfer-size'))
64configure_file(output: 'config.h',
65  configuration: conf_data
66)
67
68phosphor_dbus_interfaces = dependency(
69  'phosphor-dbus-interfaces',
70  fallback: ['phosphor-dbus-interfaces', 'phosphor_dbus_interfaces_dep'],
71)
72sdbusplus = dependency(
73  'sdbusplus',
74  fallback: ['sdbusplus', 'sdbusplus_dep'],
75)
76sdeventplus = dependency(
77  'sdeventplus',
78  fallback: ['sdeventplus', 'sdeventplus_dep'],
79)
80
81cpp = meson.get_compiler('cpp')
82
83if cpp.has_header('nlohmann/json.hpp')
84  nlohmann_json = declare_dependency()
85else
86  subproject('nlohmann-json')
87  nlohmann_json = declare_dependency(
88    include_directories: [
89      'subprojects/nlohmann-json/single_include',
90      'subprojects/nlohmann-json/single_include/nlohmann',
91    ]
92  )
93endif
94
95if cpp.has_header('CLI/CLI.hpp')
96  CLI11_dep = declare_dependency()
97else
98  CLI11_dep = dependency(
99    'CLI11',
100    fallback: [ 'CLI11', 'CLI11_dep' ],
101  )
102endif
103
104if cpp.has_header_symbol('function2/function2.hpp', 'fu2::unique_function')
105  function2_dep = declare_dependency()
106else
107  subproject('function2')
108  function2_dep = declare_dependency(
109    include_directories: [
110      'subprojects/function2/include/function2'
111    ]
112  )
113endif
114
115if get_option('oe-sdk').enabled()
116  # Setup OE SYSROOT
117  OECORE_TARGET_SYSROOT = run_command('sh', '-c', 'echo $OECORE_TARGET_SYSROOT').stdout().strip()
118  if OECORE_TARGET_SYSROOT == ''
119      error('Unable to get $OECORE_TARGET_SYSROOT, check your environment.')
120  endif
121  message('OE_SYSROOT: ' + OECORE_TARGET_SYSROOT)
122  rpath = ':'.join([OECORE_TARGET_SYSROOT + '/lib', OECORE_TARGET_SYSROOT + '/usr/lib'])
123  ld_so = run_command('sh', '-c', 'find ' + OECORE_TARGET_SYSROOT + '/lib/ld-*.so | sort -r -n | head -n1').stdout().strip()
124  dynamic_linker = ['-Wl,-dynamic-linker,' + ld_so]
125else
126  dynamic_linker = []
127endif
128
129if get_option('tests').enabled()
130    gtest = dependency('gtest', main: true, disabler: true, required: false)
131    gmock = dependency('gmock', disabler: true, required: false)
132    if not gtest.found() or not gmock.found()
133        gtest_proj = import('cmake').subproject('googletest', required: false)
134        if gtest_proj.found()
135            gtest = declare_dependency(
136                dependencies: [
137                    dependency('threads'),
138                    gtest_proj.dependency('gtest'),
139                    gtest_proj.dependency('gtest_main'),
140                ]
141            )
142            gmock = gtest_proj.dependency('gmock')
143        else
144            assert(
145                not get_option('tests').enabled(),
146                'Googletest is required if tests are enabled'
147            )
148        endif
149    endif
150endif
151
152subdir('libpldm')
153
154if get_option('libpldm-only').disabled()
155
156libpldmutils_headers = ['.']
157libpldmutils = library(
158  'pldmutils',
159  'common/utils.cpp',
160  version: meson.project_version(),
161  dependencies: [
162      libpldm_dep,
163      phosphor_dbus_interfaces,
164      nlohmann_json,
165      sdbusplus,
166  ],
167  install: true,
168  include_directories: include_directories(libpldmutils_headers),
169)
170
171libpldmutils = declare_dependency(
172  include_directories: include_directories(libpldmutils_headers),
173  link_with: libpldmutils)
174
175deps = [
176  function2_dep,
177  libpldm_dep,
178  libpldmutils,
179  nlohmann_json,
180  sdbusplus,
181  sdeventplus,
182  phosphor_dbus_interfaces,
183]
184
185if get_option('libpldmresponder').enabled()
186subdir('libpldmresponder')
187deps += [
188  libpldmresponder
189]
190endif
191
192executable(
193  'pldmd',
194  'pldmd/pldmd.cpp',
195  'pldmd/dbus_impl_requester.cpp',
196  'pldmd/instance_id.cpp',
197  'pldmd/dbus_impl_pdr.cpp',
198  'fw-update/inventory_manager.cpp',
199  'fw-update/package_parser.cpp',
200  'fw-update/device_updater.cpp',
201  'fw-update/watch.cpp',
202  'fw-update/update_manager.cpp',
203  implicit_include_directories: false,
204  dependencies: deps,
205  install: true,
206  install_dir: get_option('bindir'))
207
208if get_option('systemd').enabled()
209  systemd_system_unit_dir = dependency('systemd').get_variable(
210          pkgconfig: 'systemdsystemunitdir')
211
212  configure_file(
213    copy: true,
214    input: 'pldmd/service_files/pldmd.service',
215    install: true,
216    install_dir: systemd_system_unit_dir,
217    output: 'pldmd.service',
218  )
219
220  configure_file(
221    input: 'pldmd/verbosity/verbosity',
222    output: 'pldm_verbosity',
223    configuration: conf_data,
224    install: true,
225    install_dir: join_paths(get_option('sysconfdir'), 'default'))
226
227  if get_option('oem-ibm').enabled()
228    subdir('oem/ibm/service_files')
229  endif
230endif
231
232subdir('pldmtool')
233
234subdir('configurations')
235
236if get_option('utilities').enabled()
237  subdir('utilities')
238endif
239
240if get_option('softoff').enabled()
241  subdir('softoff')
242endif
243
244if get_option('tests').enabled()
245  subdir('common/test')
246  subdir('fw-update/test')
247  subdir('host-bmc/test')
248  subdir('requester/test')
249  subdir('test')
250endif
251
252endif # pldm-only
253