xref: /openbmc/phosphor-power/meson.build (revision fa2734d6) 
1project(
2    'phosphor-power',
3    'cpp',
4    default_options: [
5        'warning_level=3',
6        'werror=true',
7        'cpp_std=c++20',
8        'buildtype=debugoptimized',
9        'prefix=/usr'
10    ],
11    license: 'Apache-2.0',
12    version: '1.0',
13    meson_version: '>=0.57.0',
14)
15
16build_tests = get_option('tests')
17
18if get_option('oe-sdk').enabled()
19  # Setup OE SYSROOT
20  OECORE_TARGET_SYSROOT = run_command('sh', '-c', 'echo $OECORE_TARGET_SYSROOT').stdout().strip()
21  if OECORE_TARGET_SYSROOT == ''
22    error('Unable to get $OECORE_TARGET_SYSROOT, check your environment.')
23  endif
24  message('OE_SYSROOT: ' + OECORE_TARGET_SYSROOT)
25  rpath = ':'.join([OECORE_TARGET_SYSROOT + '/lib', OECORE_TARGET_SYSROOT + '/usr/lib'])
26  ld_so = run_command('sh', '-c', 'find ' + OECORE_TARGET_SYSROOT + '/lib/ld-*.so | sort -r -n | head -n1').stdout().strip()
27  dynamic_linker = ['-Wl,-dynamic-linker,' + ld_so]
28else
29  dynamic_linker = []
30endif
31
32
33cppfs = meson.get_compiler('cpp').find_library('stdc++fs')
34gmock = dependency('gmock', disabler: true, required: build_tests)
35gtest = dependency('gtest', main: true, disabler: true, required: build_tests)
36phosphor_dbus_interfaces = dependency('phosphor-dbus-interfaces')
37phosphor_logging = dependency('phosphor-logging')
38prog_python = import('python').find_installation('python3')
39sdbusplus = dependency('sdbusplus')
40sdbuspp = find_program('sdbus++')
41sdeventplus = dependency('sdeventplus')
42pthread = dependency('threads')
43stdplus = dependency('stdplus')
44boost = dependency('boost')
45fmt = dependency('fmt')
46libgpiodcxx = dependency('libgpiodcxx')
47
48systemd = dependency('systemd')
49servicedir = systemd.get_pkgconfig_variable('systemdsystemunitdir')
50
51services = [
52    ['supply-monitor', 'power-supply-monitor@.service'],
53    ['sequencer-monitor', 'pseq-monitor-pgood.service'],
54    ['sequencer-monitor', 'pseq-monitor.service'],
55    ['supply-monitor-ng', 'phosphor-psu-monitor.service'],
56    ['regulators', 'phosphor-regulators.service'],
57    ['regulators', 'phosphor-regulators-config.service'],
58    ['regulators', 'phosphor-regulators-monitor-enable.service'],
59    ['regulators', 'phosphor-regulators-monitor-disable.service'],
60    ['power-control', 'phosphor-power-control.service'],
61]
62
63foreach service : services
64    if get_option(service[0])
65        configure_file(input: 'services/' + service[1],
66                 output: service[1],
67                 copy: true,
68                 install_dir: servicedir)
69    endif
70endforeach
71
72# Get the power sequencer class name
73sequencer = get_option('power_sequencer')
74if sequencer == 'ucd90160'
75    sequencer_class = 'UCD90160'
76elif sequencer == 'mihawk-cpld'
77    sequencer_class = 'MihawkCPLD'
78else
79    # power sequencer is incorrect
80    error('power sequencer is incorrect')
81endif
82
83conf = configuration_data()
84conf.set_quoted(
85    'INPUT_HISTORY_BUSNAME_ROOT', get_option('input-history-busname-root'))
86conf.set_quoted(
87    'INPUT_HISTORY_SENSOR_ROOT', get_option('input-history-sensor-root'))
88conf.set_quoted(
89    'PSU_JSON_PATH', '/usr/share/phosphor-power/psu.json')
90conf.set(
91    'SEQUENCER', sequencer_class)
92conf.set10(
93    'DEVICE_ACCESS', get_option('device-access'))
94conf.set10('IBM_VPD', get_option('ibm-vpd'))
95
96configure_file(output: 'config.h', configuration: conf)
97
98# Ensure the generated header here winds up in the correct path in the build
99# tree such that it actually get used and doesn't get found in the sysroot
100# somewhere.  Meson doesn't allow path elements (rightfully so) when specifying
101# the output filename of a target definition so the target must be defined in
102# the directory where the artifacts need to be placed.  Do that now, because
103# the generated source (cpp) is needed to define the library target.
104subdir('org/open_power/Witherspoon/Fault')
105
106libpower = static_library(
107    'power',
108    error_cpp,
109    error_hpp,
110    'gpio.cpp',
111    'pmbus.cpp',
112    'utility.cpp',
113    dependencies: [
114        cppfs,
115        phosphor_dbus_interfaces,
116        phosphor_logging,
117        sdbusplus,
118        sdeventplus,
119    ],
120)
121
122libpower_inc = include_directories('.')
123
124# Build the tools/i2c sub-directory first.  Other sub-directories depend on
125# Meson variables defined there.
126subdir('tools/i2c')
127
128if get_option('regulators')
129    subdir('phosphor-regulators')
130endif
131if get_option('sequencer-monitor')
132    subdir('power-sequencer')
133endif
134if get_option('power-control')
135    subdir('phosphor-power-sequencer')
136endif
137if get_option('supply-monitor')
138    subdir('power-supply')
139endif
140if get_option('supply-monitor-ng')
141    subdir('phosphor-power-supply')
142endif
143if get_option('utils')
144    subdir('tools/power-utils')
145endif
146if get_option('tests').enabled()
147    subdir('test')
148endif
149if get_option('cold-redundancy')
150    subdir('cold-redundancy')
151endif
152