xref: /openbmc/phosphor-power/meson.build (revision c60b9751) 
1project(
2    'phosphor-power',
3    'cpp',
4    default_options: [
5        'warning_level=3',
6        'werror=true',
7        'cpp_std=c++17',
8        'prefix=/usr'
9    ],
10    license: 'Apache-2.0',
11    version: '1.0',
12)
13
14build_tests = get_option('tests')
15
16if get_option('oe-sdk').enabled()
17  # Setup OE SYSROOT
18  OECORE_TARGET_SYSROOT = run_command('sh', '-c', 'echo $OECORE_TARGET_SYSROOT').stdout().strip()
19  if OECORE_TARGET_SYSROOT == ''
20    error('Unable to get $OECORE_TARGET_SYSROOT, check your environment.')
21  endif
22  message('OE_SYSROOT: ' + OECORE_TARGET_SYSROOT)
23  rpath = ':'.join([OECORE_TARGET_SYSROOT + '/lib', OECORE_TARGET_SYSROOT + '/usr/lib'])
24  ld_so = run_command('sh', '-c', 'find ' + OECORE_TARGET_SYSROOT + '/lib/ld-*.so | sort -r -n | head -n1').stdout().strip()
25  dynamic_linker = ['-Wl,-dynamic-linker,' + ld_so]
26else
27  dynamic_linker = []
28endif
29
30
31cppfs = meson.get_compiler('cpp').find_library('stdc++fs')
32gmock = dependency('gmock', disabler: true, required: build_tests)
33gtest = dependency('gtest', main: true, disabler: true, required: build_tests)
34phosphor_dbus_interfaces = dependency('phosphor-dbus-interfaces')
35phosphor_logging = dependency('phosphor-logging')
36prog_python = import('python').find_installation('python3')
37sdbusplus = dependency('sdbusplus')
38sdbuspp = find_program('sdbus++')
39sdeventplus = dependency('sdeventplus')
40pthread = dependency('threads')
41stdplus = dependency('stdplus')
42
43systemd = dependency('systemd')
44servicedir = systemd.get_pkgconfig_variable('systemdsystemunitdir')
45
46services = [
47    ['supply-monitor', 'power-supply-monitor@.service'],
48    ['sequencer-monitor', 'pseq-monitor-pgood.service'],
49    ['sequencer-monitor', 'pseq-monitor.service'],
50    ['supply-monitor-ng', 'phosphor-psu-monitor.service'],
51    ['regulators', 'phosphor-regulators.service'],
52    ['regulators', 'phosphor-regulators-config.service'],
53    ['regulators', 'phosphor-regulators-monitor-enable.service'],
54    ['regulators', 'phosphor-regulators-monitor-disable.service'],
55]
56
57foreach service : services
58    if get_option(service[0])
59        configure_file(input: 'services/' + service[1],
60                 output: service[1],
61                 copy: true,
62                 install_dir: servicedir)
63    endif
64endforeach
65
66# Get the power sequencer class name
67sequencer = get_option('power_sequencer')
68if sequencer == 'ucd90160'
69    sequencer_class = 'UCD90160'
70elif sequencer == 'mihawk-cpld'
71    sequencer_class = 'MihawkCPLD'
72else
73    # power sequencer is incorrect
74    error('power sequencer is incorrect')
75endif
76
77conf = configuration_data()
78conf.set_quoted(
79    'INPUT_HISTORY_BUSNAME_ROOT', get_option('input-history-busname-root'))
80conf.set_quoted(
81    'INPUT_HISTORY_SENSOR_ROOT', get_option('input-history-sensor-root'))
82conf.set_quoted(
83    'PSU_JSON_PATH', '/usr/share/phosphor-power/psu.json')
84conf.set(
85    'SEQUENCER', sequencer_class)
86conf.set10(
87    'DEVICE_ACCESS', get_option('device-access'))
88
89configure_file(output: 'config.h', configuration: conf)
90
91# Ensure the generated header here winds up in the correct path in the build
92# tree such that it actually get used and doesn't get found in the sysroot
93# somewhere.  Meson doesn't allow path elements (rightfully so) when specifying
94# the output filename of a target definition so the target must be defined in
95# the directory where the artifacts need to be placed.  Do that now, because
96# the generated source (cpp) is needed to define the library target.
97subdir('org/open_power/Witherspoon/Fault')
98
99libpower = static_library(
100    'power',
101    error_cpp,
102    error_hpp,
103    'gpio.cpp',
104    'pmbus.cpp',
105    'utility.cpp',
106    dependencies: [
107        cppfs,
108        phosphor_dbus_interfaces,
109        phosphor_logging,
110        sdbusplus,
111        sdeventplus,
112    ],
113)
114
115libpower_inc = include_directories('.')
116
117# Build the tools/i2c sub-directory first.  Other sub-directories depend on
118# Meson variables defined there.
119subdir('tools/i2c')
120
121if get_option('regulators')
122    subdir('phosphor-regulators')
123endif
124if get_option('sequencer-monitor')
125    subdir('power-sequencer')
126endif
127if get_option('supply-monitor')
128    subdir('power-supply')
129endif
130if get_option('supply-monitor-ng')
131    subdir('phosphor-power-supply')
132endif
133if get_option('utils')
134    subdir('tools/power-utils')
135endif
136if get_option('tests').enabled()
137    subdir('test')
138endif
139if get_option('cold-redundancy')
140    subdir('cold-redundancy')
141endif
142