xref: /openbmc/phosphor-power/meson.build (revision bd1c4ffa) 
1project(
2    'phosphor-power',
3    'cpp',
4    default_options: [
5        'warning_level=3',
6        'werror=true',
7        'cpp_std=c++17'
8    ],
9    license: 'Apache-2.0',
10    version: '1.0',
11)
12
13build_tests = get_option('tests')
14
15cppfs = meson.get_compiler('cpp').find_library('stdc++fs')
16gmock = dependency('gmock', disabler: true, required: build_tests)
17gtest = dependency('gtest', main: true, disabler: true, required: build_tests)
18phosphor_dbus_interfaces = dependency('phosphor-dbus-interfaces')
19phosphor_logging = dependency('phosphor-logging')
20prog_python = import('python').find_installation('python')
21sdbusplus = dependency('sdbusplus')
22sdbuspp = find_program('sdbus++')
23sdeventplus = dependency('sdeventplus')
24pthread = dependency('threads')
25
26systemd = dependency('systemd')
27servicedir = systemd.get_pkgconfig_variable('systemdsystemunitdir')
28
29services = [
30    'power-supply-monitor@.service',
31    'pseq-monitor-pgood.service',
32    'pseq-monitor.service',
33    'phosphor-psu-monitor.service'
34]
35
36foreach service : services
37  configure_file(input: 'services/' + service,
38                 output: service,
39                 copy: true,
40                 install_dir: servicedir)
41endforeach
42
43conf = configuration_data()
44conf.set_quoted(
45    'INPUT_HISTORY_BUSNAME_ROOT', get_option('input-history-busname-root'))
46conf.set_quoted(
47    'INPUT_HISTORY_SENSOR_ROOT', get_option('input-history-sensor-root'))
48conf.set_quoted(
49    'PSU_JSON_PATH', '/usr/share/phosphor-power/psu.json')
50conf.set10(
51    'UCD90160_DEVICE_ACCESS', get_option('ucd90160-access'))
52
53configure_file(output: 'config.h', configuration: conf)
54
55# Ensure the generated header here winds up in the correct path in the build
56# tree such that it actually get used and doesn't get found in the sysroot
57# somewhere.  Meson doesn't allow path elements (rightfully so) when specifying
58# the output filename of a target definition so the target must be defined in
59# the directory where the artifacts need to be placed.  Do that now, because
60# the generated source (cpp) is needed to define the library target.
61subdir('org/open_power/Witherspoon/Fault')
62
63libpower = static_library(
64    'power',
65    error_cpp,
66    error_hpp,
67    'gpio.cpp',
68    'pmbus.cpp',
69    'utility.cpp',
70    dependencies: [
71        cppfs,
72        phosphor_dbus_interfaces,
73        phosphor_logging,
74        sdbusplus,
75        sdeventplus,
76    ],
77)
78
79libpower_inc = include_directories('.')
80
81# Build the tools/i2c sub-directory first.  Other sub-directories depend on
82# Meson variables defined there.
83subdir('tools/i2c')
84
85subdir('phosphor-regulators')
86subdir('power-sequencer')
87subdir('power-supply')
88subdir('phosphor-power-supply')
89subdir('tools/power-utils')
90subdir('test')
91subdir('cold-redundancy')
92