xref: /openbmc/phosphor-power/meson.build (revision 860d51af) 
1project(
2    'phosphor-power',
3    'cpp',
4    default_options: [
5        'warning_level=3',
6        'werror=true',
7        'cpp_std=c++17',
8        'prefix=/usr'
9    ],
10    license: 'Apache-2.0',
11    version: '1.0',
12)
13
14build_tests = get_option('tests')
15
16if get_option('oe-sdk').enabled()
17  # Setup OE SYSROOT
18  OECORE_TARGET_SYSROOT = run_command('sh', '-c', 'echo $OECORE_TARGET_SYSROOT').stdout().strip()
19  if OECORE_TARGET_SYSROOT == ''
20    error('Unable to get $OECORE_TARGET_SYSROOT, check your environment.')
21  endif
22  message('OE_SYSROOT: ' + OECORE_TARGET_SYSROOT)
23  rpath = ':'.join([OECORE_TARGET_SYSROOT + '/lib', OECORE_TARGET_SYSROOT + '/usr/lib'])
24  ld_so = run_command('sh', '-c', 'find ' + OECORE_TARGET_SYSROOT + '/lib/ld-*.so | sort -r -n | head -n1').stdout().strip()
25  dynamic_linker = ['-Wl,-dynamic-linker,' + ld_so]
26else
27  dynamic_linker = []
28endif
29
30
31cppfs = meson.get_compiler('cpp').find_library('stdc++fs')
32gmock = dependency('gmock', disabler: true, required: build_tests)
33gtest = dependency('gtest', main: true, disabler: true, required: build_tests)
34phosphor_dbus_interfaces = dependency('phosphor-dbus-interfaces')
35phosphor_logging = dependency('phosphor-logging')
36prog_python = import('python').find_installation('python3')
37sdbusplus = dependency('sdbusplus')
38sdbuspp = find_program('sdbus++')
39sdeventplus = dependency('sdeventplus')
40pthread = dependency('threads')
41stdplus = dependency('stdplus')
42boost = dependency('boost')
43fmt = dependency('fmt')
44
45systemd = dependency('systemd')
46servicedir = systemd.get_pkgconfig_variable('systemdsystemunitdir')
47
48services = [
49    ['supply-monitor', 'power-supply-monitor@.service'],
50    ['sequencer-monitor', 'pseq-monitor-pgood.service'],
51    ['sequencer-monitor', 'pseq-monitor.service'],
52    ['supply-monitor-ng', 'phosphor-psu-monitor.service'],
53    ['regulators', 'phosphor-regulators.service'],
54    ['regulators', 'phosphor-regulators-config.service'],
55    ['regulators', 'phosphor-regulators-monitor-enable.service'],
56    ['regulators', 'phosphor-regulators-monitor-disable.service'],
57]
58
59foreach service : services
60    if get_option(service[0])
61        configure_file(input: 'services/' + service[1],
62                 output: service[1],
63                 copy: true,
64                 install_dir: servicedir)
65    endif
66endforeach
67
68# Get the power sequencer class name
69sequencer = get_option('power_sequencer')
70if sequencer == 'ucd90160'
71    sequencer_class = 'UCD90160'
72elif sequencer == 'mihawk-cpld'
73    sequencer_class = 'MihawkCPLD'
74else
75    # power sequencer is incorrect
76    error('power sequencer is incorrect')
77endif
78
79conf = configuration_data()
80conf.set_quoted(
81    'INPUT_HISTORY_BUSNAME_ROOT', get_option('input-history-busname-root'))
82conf.set_quoted(
83    'INPUT_HISTORY_SENSOR_ROOT', get_option('input-history-sensor-root'))
84conf.set_quoted(
85    'PSU_JSON_PATH', '/usr/share/phosphor-power/psu.json')
86conf.set(
87    'SEQUENCER', sequencer_class)
88conf.set10(
89    'DEVICE_ACCESS', get_option('device-access'))
90conf.set10('IBM_VPD', get_option('ibm-vpd'))
91
92configure_file(output: 'config.h', configuration: conf)
93
94# Ensure the generated header here winds up in the correct path in the build
95# tree such that it actually get used and doesn't get found in the sysroot
96# somewhere.  Meson doesn't allow path elements (rightfully so) when specifying
97# the output filename of a target definition so the target must be defined in
98# the directory where the artifacts need to be placed.  Do that now, because
99# the generated source (cpp) is needed to define the library target.
100subdir('org/open_power/Witherspoon/Fault')
101
102libpower = static_library(
103    'power',
104    error_cpp,
105    error_hpp,
106    'gpio.cpp',
107    'pmbus.cpp',
108    'utility.cpp',
109    dependencies: [
110        cppfs,
111        phosphor_dbus_interfaces,
112        phosphor_logging,
113        sdbusplus,
114        sdeventplus,
115    ],
116)
117
118libpower_inc = include_directories('.')
119
120# Build the tools/i2c sub-directory first.  Other sub-directories depend on
121# Meson variables defined there.
122subdir('tools/i2c')
123
124if get_option('regulators')
125    subdir('phosphor-regulators')
126endif
127if get_option('sequencer-monitor')
128    subdir('power-sequencer')
129endif
130if get_option('supply-monitor')
131    subdir('power-supply')
132endif
133if get_option('supply-monitor-ng')
134    subdir('phosphor-power-supply')
135endif
136if get_option('utils')
137    subdir('tools/power-utils')
138endif
139if get_option('tests').enabled()
140    subdir('test')
141endif
142if get_option('cold-redundancy')
143    subdir('cold-redundancy')
144endif
145