xref: /openbmc/phosphor-power/meson.build (revision 770de580) 
1project(
2    'phosphor-power',
3    'cpp',
4    default_options: [
5        'warning_level=3',
6        'werror=true',
7        'cpp_std=c++20',
8        'buildtype=debugoptimized',
9        'prefix=/usr'
10    ],
11    license: 'Apache-2.0',
12    version: '1.0',
13    meson_version: '>=0.57.0',
14)
15
16build_tests = get_option('tests')
17
18if get_option('oe-sdk').enabled()
19  # Setup OE SYSROOT
20  OECORE_TARGET_SYSROOT = run_command('sh', '-c', 'echo $OECORE_TARGET_SYSROOT').stdout().strip()
21  if OECORE_TARGET_SYSROOT == ''
22    error('Unable to get $OECORE_TARGET_SYSROOT, check your environment.')
23  endif
24  message('OE_SYSROOT: ' + OECORE_TARGET_SYSROOT)
25  rpath = ':'.join([OECORE_TARGET_SYSROOT + '/lib', OECORE_TARGET_SYSROOT + '/usr/lib'])
26  ld_so = run_command('sh', '-c', 'find ' + OECORE_TARGET_SYSROOT + '/lib/ld-*.so | sort -r -n | head -n1').stdout().strip()
27  dynamic_linker = ['-Wl,-dynamic-linker,' + ld_so]
28else
29  dynamic_linker = []
30endif
31
32
33cppfs = meson.get_compiler('cpp').find_library('stdc++fs')
34gmock = dependency('gmock', disabler: true, required: build_tests)
35gtest = dependency('gtest', main: true, disabler: true, required: build_tests)
36phosphor_dbus_interfaces = dependency('phosphor-dbus-interfaces')
37phosphor_logging = dependency('phosphor-logging')
38prog_python = import('python').find_installation('python3')
39sdbusplus = dependency('sdbusplus')
40sdbuspp = find_program('sdbus++')
41sdeventplus = dependency('sdeventplus')
42pthread = dependency('threads')
43stdplus = dependency('stdplus')
44boost = dependency('boost')
45fmt = dependency('fmt')
46libgpiodcxx = dependency('libgpiodcxx')
47
48systemd = dependency('systemd')
49servicedir = systemd.get_pkgconfig_variable('systemdsystemunitdir')
50
51services = [
52    ['supply-monitor', 'power-supply-monitor@.service'],
53    ['sequencer-monitor', 'pseq-monitor-pgood.service'],
54    ['sequencer-monitor', 'pseq-monitor.service'],
55    ['supply-monitor-ng', 'phosphor-psu-monitor.service'],
56    ['regulators', 'phosphor-regulators.service'],
57    ['regulators', 'phosphor-regulators-config.service'],
58    ['regulators', 'phosphor-regulators-monitor-enable.service'],
59    ['regulators', 'phosphor-regulators-monitor-disable.service'],
60]
61
62foreach service : services
63    if get_option(service[0])
64        configure_file(input: 'services/' + service[1],
65                 output: service[1],
66                 copy: true,
67                 install_dir: servicedir)
68    endif
69endforeach
70
71# Get the power sequencer class name
72sequencer = get_option('power_sequencer')
73if sequencer == 'ucd90160'
74    sequencer_class = 'UCD90160'
75elif sequencer == 'mihawk-cpld'
76    sequencer_class = 'MihawkCPLD'
77else
78    # power sequencer is incorrect
79    error('power sequencer is incorrect')
80endif
81
82conf = configuration_data()
83conf.set_quoted(
84    'INPUT_HISTORY_BUSNAME_ROOT', get_option('input-history-busname-root'))
85conf.set_quoted(
86    'INPUT_HISTORY_SENSOR_ROOT', get_option('input-history-sensor-root'))
87conf.set_quoted(
88    'PSU_JSON_PATH', '/usr/share/phosphor-power/psu.json')
89conf.set(
90    'SEQUENCER', sequencer_class)
91conf.set10(
92    'DEVICE_ACCESS', get_option('device-access'))
93conf.set10('IBM_VPD', get_option('ibm-vpd'))
94
95configure_file(output: 'config.h', configuration: conf)
96
97# Ensure the generated header here winds up in the correct path in the build
98# tree such that it actually get used and doesn't get found in the sysroot
99# somewhere.  Meson doesn't allow path elements (rightfully so) when specifying
100# the output filename of a target definition so the target must be defined in
101# the directory where the artifacts need to be placed.  Do that now, because
102# the generated source (cpp) is needed to define the library target.
103subdir('org/open_power/Witherspoon/Fault')
104
105libpower = static_library(
106    'power',
107    error_cpp,
108    error_hpp,
109    'gpio.cpp',
110    'pmbus.cpp',
111    'utility.cpp',
112    dependencies: [
113        cppfs,
114        phosphor_dbus_interfaces,
115        phosphor_logging,
116        sdbusplus,
117        sdeventplus,
118    ],
119)
120
121libpower_inc = include_directories('.')
122
123# Build the tools/i2c sub-directory first.  Other sub-directories depend on
124# Meson variables defined there.
125subdir('tools/i2c')
126
127if get_option('regulators')
128    subdir('phosphor-regulators')
129endif
130if get_option('sequencer-monitor')
131    subdir('power-sequencer')
132endif
133if get_option('sequencer-monitor-ng')
134    subdir('phosphor-power-sequencer')
135endif
136if get_option('supply-monitor')
137    subdir('power-supply')
138endif
139if get_option('supply-monitor-ng')
140    subdir('phosphor-power-supply')
141endif
142if get_option('utils')
143    subdir('tools/power-utils')
144endif
145if get_option('tests').enabled()
146    subdir('test')
147endif
148if get_option('cold-redundancy')
149    subdir('cold-redundancy')
150endif
151